I_BusPartRelationshipProcessTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'BP Relationship Process Data - TP'
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XL
@VDM.viewType: #TRANSACTIONAL
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define root view entity I_BusPartRelationshipProcessTP
  as select from I_BusPartRelationshipProcess as _Current

  composition [0..*] of I_BusPartRelshpTmeDpndcyProcTP as _BusPartRelshpTmeDpndcyProc
  composition [0..1] of I_BusPartContactPersonProcTP   as _BPRelContactPerson
  composition [0..*] of I_BPContactPersonAddressProcTP as _BPRelContactPersonAddress
  association [0..1] to I_MDChangeProcessRecordTarget  as _RecordTarget             on  $projection.MasterDataChangeProcess          = _RecordTarget.MasterDataChangeProcess
                                                                                    and $projection.MDChgProcessSrceSystem           = _RecordTarget.MDChgProcessSrceSystem
                                                                                    and $projection.MDChgProcessSrceObject           = _RecordTarget.MDChgProcessSrceObject
                                                                                    and _RecordTarget.MDChgProcessSrceObjectTypeCode = '1405'

  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_MDChgProcKPIFilterActvtnSts  as _RecordTargetText         on  $projection.MDChgProcessActivationTarget = _RecordTargetText.MDChangeProcKPIValueKey
  association [0..1] to I_MDChangeProcessKPIRowVH      as _KPIUpdateStatusText      on  $projection.MDChgProcKPIUpdateStatus = _KPIUpdateStatusText.MDChgProcKPIUpdateStatus
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_MDChgProcKPIFilterRecordSts  as _KPIRecordStatusText      on  $projection.MDChgProcessValidationStatus = _KPIRecordStatusText.MDChangeProcKPIValueKey
  association [0..*] to I_MDChgProcRecordMessages      as _RecordMessages           on  $projection.MasterDataChangeProcess = _RecordMessages.MasterDataChangeProcess
                                                                                    and $projection.MDChgProcessStep        = _RecordMessages.MDChgProcessStep
                                                                                    and $projection.MDChgProcessSrceSystem  = _RecordMessages.MDChgProcessSrceSystem
                                                                                    and $projection.MDChgProcessSrceObject  = _RecordMessages.MDChgProcessSrceObject
  association [0..1] to I_BPRelshpProcessKPIRecordType as _RecordType               on  $projection.MasterDataChangeProcess = _RecordType.MasterDataChangeProcess
                                                                                    and $projection.MDChgProcessStep        = _RecordType.MDChgProcessStep
                                                                                    and $projection.MDChgProcessSrceSystem  = _RecordType.MDChgProcessSrceSystem
                                                                                    and $projection.MDChgProcessSrceObject  = _RecordType.MDChgProcessSrceObject
  association [0..1] to I_BusPartRelshpCategoryDesc    as _RelationshipCategoryText on  $projection.RelationshipCategory                        = _RelationshipCategoryText.RelationshipCategory
                                                                                    and _Current.BPRelshpCatIsInFwdDirection                    = _RelationshipCategoryText.BPRelshpCatIsInFwdDirection
                                                                                    and _RelationshipCategoryText.BusPartRelshpIsRoleDefinition = ' '
{
  key _Current.MasterDataChangeProcess,
  key _Current.MDChgProcessStep,
  key _Current.MDChgProcessSrceSystem,
  key _Current.MDChgProcessSrceObject,
      _Current.MDChgProcessSrceBusPart1,
      _Current.MDChgProcessSrceBusPart2,
      _Current.RelationshipCategory,
      _Current.BusinessPartner1,
      _Current.BusinessPartner2,
      _Current.MDChgProcessSourceModified,
      _Current.MDChgProcessSourceModifBinary,
      _Current.MDChgProcessValidationStatus,
      concat_with_space(
        concat_with_space(
          case _Current._BusinessPartner1.BusinessPartnerCategory
            when '1' then concat_with_space(_Current._BusinessPartner1.FirstName, _Current._BusinessPartner1.LastName, 1)
            when '2' then _Current._BusinessPartner1.OrganizationBPName1
            when '3' then _Current._BusinessPartner1.GroupBusinessPartnerName1
            else case _Current._BusinessPartner1active.BusinessPartnerCategory
                   when '1' then concat_with_space(_Current._BusinessPartner1active.FirstName, _Current._BusinessPartner1active.LastName, 1)
                   when '2' then _Current._BusinessPartner1active.OrganizationBPName1
                   else _Current._BusinessPartner1active.GroupBusinessPartnerName1
                  end
          end ,_RelationshipCategoryText.BusPartRelshpCatDescription,1),
          case _Current._BusinessPartner2.BusinessPartnerCategory
            when '1' then concat_with_space(_Current._BusinessPartner2.FirstName, _Current._BusinessPartner2.LastName, 1)
            when '2' then _Current._BusinessPartner2.OrganizationBPName1
            when '3' then _Current._BusinessPartner2.GroupBusinessPartnerName1
            else case _Current._BusinessPartner2active.BusinessPartnerCategory
                   when '1' then concat_with_space(_Current._BusinessPartner2active.FirstName, _Current._BusinessPartner2active.LastName, 1)
                   when '2' then _Current._BusinessPartner2active.OrganizationBPName1
                   else _Current._BusinessPartner2active.GroupBusinessPartnerName1
                  end
          end,1)                                                                            as MDChgProcessRecordObjectText,
      cast( case
        when _Current.MDChgProcessSourceModified = '' then 'N'
        when _Current.MDChgProcessSourceModified = 'X' then 'M'
        else _Current.MDChgProcessSourceModified end as mdc_source_modified )               as MDChgProcKPIUpdateStatus,

      cast( case
        when _RecordTarget.MDChgProcessActivationTarget = '1' then 'D'
        else _RecordTarget.MDChgProcessActivationTarget end as mdc_activation_target_mult ) as MDChgProcessActivationTarget,
      _Current.BP1AuthorizationGroup,
      _Current.BP2AuthorizationGroup,
      _Current.BP1DataControllerSet,
      _Current.BP1DataController1,
      _Current.BP1DataController2,
      _Current.BP1DataController3,
      _Current.BP1DataController4,
      _Current.BP1DataController5,
      _Current.BP1DataController6,
      _Current.BP1DataController7,
      _Current.BP1DataController8,
      _Current.BP1DataController9,
      _Current.BP1DataController10,
      _Current.BP2DataControllerSet,
      _Current.BP2DataController1,
      _Current.BP2DataController2,
      _Current.BP2DataController3,
      _Current.BP2DataController4,
      _Current.BP2DataController5,
      _Current.BP2DataController6,
      _Current.BP2DataController7,
      _Current.BP2DataController8,
      _Current.BP2DataController9,
      _Current.BP2DataController10,
      /* Composition */
      _BusPartRelshpTmeDpndcyProc,
      _BPRelContactPerson,
      _BPRelContactPersonAddress,
      _Current._BusinessPartner1,
      _Current._BusinessPartner2,
      _RecordTarget,
      _RecordTargetText,
      _KPIRecordStatusText,
      _KPIUpdateStatusText,
      _RecordMessages,
      _RecordType

}