I_BusPartRelationshipGovTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Business Partner Relationship Gov - TP'
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XL
@VDM.viewType: #TRANSACTIONAL
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ]  } */
define root view entity I_BusPartRelationshipGovTP
  as select from I_BusPartRelationshipGov as _Current

  composition [0..1] of I_BPRelshpChangeProcessGovTP   as _BusPartRelshpChangeProcess
  composition [0..*] of I_BusPartRelshpTmeDpndcyGovTP  as _BusPartRelshpTmeDpndcy
  composition [0..1] of I_BusPartContactPersonGovTP    as _BusPartRelContactPerson
  composition [0..*] of I_BPContactPersonAddressGovTP  as _BPRelContactPersonAddress

/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_MasterDataChangeProcess      as _MasterDataChangeProcess on  $projection.MasterDataChangeProcess = _MasterDataChangeProcess.MasterDataChangeProcess
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_BPRelshpChangeProcessGovTP   as _BPRelshpChangeProcess   on  $projection.MasterDataChangeProcess = _BPRelshpChangeProcess.MasterDataChangeProcess
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_BusPartRelshpCategoryWthDesc as _RelationshipCategory    on  $projection.RelationshipCategory                    = _RelationshipCategory.RelationshipCategory
                                                                                   and (
                                                                                      $projection.BPRelshpCatIsInFwdDrctnForEdit           = _RelationshipCategory.BPRelshpCatIsInFwdDirection
                                                                                      and _RelationshipCategory.BPRelshpCatIsBidirectional = 'X'
                                                                                      or _RelationshipCategory.BPRelshpCatIsBidirectional  = ''
                                                                                    )
  association [1..1] to I_BPRelshpRelatedPartnerName   as _RelatedBusinessPartner  on  $projection.BusinessPartner2        = _RelatedBusinessPartner.MDChgProcessSrceBusPart2
                                                                                   and $projection.MasterDataChangeProcess = _RelatedBusinessPartner.MasterDataChangeProcess

{
  key cast ( hextobin('00000000000000000000000000000000') as sysuuid_x preserving type ) as BPRelshpUUID,
  key _Current.MasterDataChangeProcess,
  key _Current.MDChgProcessSrceSystem,
  key _Current.MDChgProcessSrceObject,
  key _Current.BPRelshpCatIsInFwdDirection,
      @ObjectModel.editableFieldFor: 'MasterDataChangeProcess'
      _Current.MasterDataChangeProcess                                                   as MasterDataChangeProcessForEdit,
      @ObjectModel.editableFieldFor: 'BPRelshpCatIsInFwdDirection'
      _Current.BPRelshpCatIsInFwdDirection                                               as BPRelshpCatIsInFwdDrctnForEdit,
      _Current.MDChgProcessStep,
      _Current.BusinessPartner1,
      _Current.BusinessPartner2,
      @ObjectModel.editableFieldFor: 'BusinessPartner2'
      case
        when length(_Current.BusinessPartner2) > 10
          then ''
          else cast (_Current.BusinessPartner2 as bu_partner )
      end                                                                                as BusinessPartner2ForEdit,
      _RelatedBusinessPartner.BusinessPartnerName                                        as BusinessPartner2FullName,
      _Current.RelationshipCategory,
      _Current.BusinessPartnerCategory,
      _Current.BP1AuthorizationGroup,
      _Current.BP2AuthorizationGroup,
      _Current.BP1DataControllerSet,
      _Current.BP1DataController1,
      _Current.BP1DataController2,
      _Current.BP1DataController3,
      _Current.BP1DataController4,
      _Current.BP1DataController5,
      _Current.BP1DataController6,
      _Current.BP1DataController7,
      _Current.BP1DataController8,
      _Current.BP1DataController9,
      _Current.BP1DataController10,
      _Current.BP2DataControllerSet,
      _Current.BP2DataController1,
      _Current.BP2DataController2,
      _Current.BP2DataController3,
      _Current.BP2DataController4,
      _Current.BP2DataController5,
      _Current.BP2DataController6,
      _Current.BP2DataController7,
      _Current.BP2DataController8,
      _Current.BP2DataController9,
      _Current.BP2DataController10,

      cast( 1000 as mdc_process_update_token )                                           as ETag,
      cast( case  when _Current.RelationshipCategory <> 'BUR001'
                 then 'X'
      when _Current.RelationshipCategory = 'BUR001'
                 and _Current.BusinessPartner2 is not null and length(_Current.BusinessPartner2) > 0
                 and ( ( _Current.BusinessPartnerCategory = '2' and _RelatedBusinessPartner.BusinessPartnerCategory = '1' )
                  or ( _Current.BusinessPartnerCategory = '1' and _RelatedBusinessPartner.BusinessPartnerCategory = '2' ) )
                 then ''
                 else 'X'
           end as boole_d preserving type )                                              as BPContactPersonDetsAreHidden,

      _BusPartRelshpChangeProcess,
      _BusPartRelshpTmeDpndcy,
      _BusPartRelContactPerson,
      _BPRelContactPersonAddress,
      _MasterDataChangeProcess,
      _RelationshipCategory,
      _RelatedBusinessPartner
}
where
  _Current.MasterDataIsCurrent = 'X'