I_BusPartIdentificationGov

@AbapCatalog.sqlViewName: 'IBPIDNUMGOV'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'BP Identification Governance'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM.viewType: #COMPOSITE
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view I_BusPartIdentificationGov
  as select from I_BPIdentificationProcess
  association [1..1] to I_BusinessPartnerGov      as _BusinessPartnerGov      on  $projection.MasterDataChangeProcess = _BusinessPartnerGov.MasterDataChangeProcess
                                                                              and $projection.MDChgProcessStep        = _BusinessPartnerGov.MDChgProcessStep
                                                                              and $projection.MDChgProcessSrceSystem  = _BusinessPartnerGov.MDChgProcessSrceSystem
                                                                              and $projection.MDChgProcessSrceObject  = _BusinessPartnerGov.MDChgProcessSrceObject
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_MasterDataChangeProcess as _MasterDataChangeProcess on  $projection.MasterDataChangeProcess = _MasterDataChangeProcess.MasterDataChangeProcess

{
  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
  key BPIdentificationType,
  key BPIdentificationNumber,
      BusinessPartner,
      BPIdnNmbrIssuingInstitute,
      BPIdentificationEntryDate,
      ValidityStartDate,
      ValidityEndDate,
      Country,
      Region,

      cast(
        case when MDChgProcessStep = _MasterDataChangeProcess.MDChgProcessCurrentStepNumber and _MasterDataChangeProcess.MDChgProcessCurrentStepNumber <> '0000' or
                  MDChgProcessStep = '0001' and  _MasterDataChangeProcess.MDChgProcessCurrentStepNumber = '0000' then 'X'
             else ' '
        end as abap_boolean preserving type
      ) as MasterDataIsCurrent,

      _BusinessPartnerGov
}
where
  MDChgProcessSourceModified <> 'D'

union all

select from I_BuPaIdentification
association [1..1] to I_BusinessPartnerGov as _BusinessPartnerGov on  $projection.MasterDataChangeProcess = _BusinessPartnerGov.MasterDataChangeProcess
                                                                  and $projection.MDChgProcessStep        = _BusinessPartnerGov.MDChgProcessStep
                                                                  and $projection.MDChgProcessSrceSystem  = _BusinessPartnerGov.MDChgProcessSrceSystem
                                                                  and $projection.MDChgProcessSrceObject  = _BusinessPartnerGov.MDChgProcessSrceObject
{
  key '000000000000'                              as MasterDataChangeProcess,
  key '0000'                                      as MDChgProcessStep,
  key ''                                          as MDChgProcessSrceSystem,
  key BusinessPartner                             as MDChgProcessSrceObject,
  key BPIdentificationType,
  key BPIdentificationNumber,
      BusinessPartner,
      BPIdnNmbrIssuingInstitute,
      BPIdentificationEntryDate,
      ValidityStartDate,
      ValidityEndDate,
      Country,
      Region,

      cast( 'X' as abap_boolean preserving type ) as MasterDataIsCurrent,

      _BusinessPartnerGov
}