I_BusPartEmailAddressGov

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #BASIC
@EndUserText.label: 'BP Email Address'
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view entity I_BusPartEmailAddressGov
  as select from I_BPEmailAddressProcess
  association [1..1] to I_BusinessPartnerGov      as _BusinessPartner         on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                                              and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                                              and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                                              and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_MasterDataChangeProcess as _MasterDataChangeProcess on  $projection.MasterDataChangeProcess = _MasterDataChangeProcess.MasterDataChangeProcess
  association [0..1] to I_BPProtectedAddress      as _BPProtectedAddress      on  $projection.MDChgProcessSrceObject = _BPProtectedAddress.BusinessPartner
                                                                              and $projection.AddressNumber          = _BPProtectedAddress.AddressID
{

      //I_BPEmailAddressProcess

  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
  key AddressNumber,
  key OrdinalNumber,
      IsDefaultEmailAddress,
      EmailAddress,
      IsHomeEmailAddress,
//      ValidityStartDateTime,

//      CommNumberIsNotUsed,

//      ValidityEndDateTime,

      cast(
        case when MDChgProcessStep = _MasterDataChangeProcess.MDChgProcessCurrentStepNumber and _MasterDataChangeProcess.MDChgProcessCurrentStepNumber <> '0000' or
                  MDChgProcessStep = '0001' and  _MasterDataChangeProcess.MDChgProcessCurrentStepNumber = '0000' then 'X'
             else ' '
        end as abap_boolean preserving type
      ) as MasterDataIsCurrent,
      
      _BPProtectedAddress,
      _BusinessPartner
}
where
  MDChgProcessSourceModified <> 'D'
union all

select from I_BPEmailAddress

association [1..1] to I_BusinessPartnerGov as _BusinessPartner    on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                                  and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                                  and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                                  and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject
association [0..1] to I_BPProtectedAddress as _BPProtectedAddress on  $projection.MDChgProcessSrceObject = _BPProtectedAddress.BusinessPartner
                                                                  and $projection.AddressNumber          = _BPProtectedAddress.AddressID
{
      //I_BPEmailAddress

  key '000000000000'  as MasterDataChangeProcess,
  key '0000'          as MDChgProcessStep,
  key ''              as MDChgProcessSrceSystem,
  key BusinessPartner as MDChgProcessSrceObject,
  key AddressID       as AddressNumber,
  key OrdinalNumber,
      IsDefaultEmailAddress,
      EmailAddress,
      IsHomeEmailAddress,
      cast( 'X' as abap_boolean preserving type ) as MasterDataIsCurrent,
      /* Associations */
      //I_BPEmailAddress

      _BPProtectedAddress,
      _BusinessPartner
}