I_BldngForHzdsSubstInvtryItem

DDL: I_BLDNGFORHZDSSUBSTINVTRYITEM SQL: IHASSUBINVBLDNG Type: view COMPOSITE Package: EHHSS_BO_HSI

Building for hazardous substance inventory item

I_BldngForHzdsSubstInvtryItem is a Composite CDS View that provides data about "Building for hazardous substance inventory item" in SAP S/4HANA. It reads from 4 data sources (I_EHSLocationBuilding, I_EHSLocationRevision, I_EHSLocationRevision, I_HzdsSubstInventoryDraft) and exposes 9 fields with key fields HzdsSubstInventoryUUID, EHSLocationUUID. Part of development package EHHSS_BO_HSI.

4 data source(s) 9 fields

Data Sources (4)

SourceAliasJoin Type
I_EHSLocationBuilding _BuildingLocation inner
I_EHSLocationRevision _BuildingLocationRevision inner
I_EHSLocationRevision _HSILocationRevision inner
I_HzdsSubstInventoryDraft I_HzdsSubstInventoryDraft from

Annotations (10)

NameValueLevelField
EndUserText.label Building for hazardous substance inventory item view
AbapCatalog.sqlViewName IHASSUBINVBLDNG view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #CHECK view
VDM.viewType #COMPOSITE view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #M view
ObjectModel.usageType.dataClass #MIXED view

Fields (9)

KeyFieldSource TableSource FieldDescription
KEY HzdsSubstInventoryUUID HzdsSubstInventoryUUID
KEY EHSLocationUUID I_EHSLocationRevision EHSLocationUUID
EHSLocationType I_EHSLocationRevision EHSLocationType
EHSLocationStatus I_EHSLocationRevision EHSLocationStatus
EHSLocationAuthorizationGroup
Plant I_EHSLocationRevision Plant
CostCenter I_EHSLocationRevision CostCenter
CompanyCode I_EHSLocationRevision CompanyCode
BusinessArea I_EHSLocationRevision BusinessArea 
@EndUserText.label: 'Building for hazardous substance inventory item'

@AbapCatalog.sqlViewName: 'IHASSUBINVBLDNG'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK

@VDM.viewType: #COMPOSITE

// Client handling by session 

@ClientHandling.algorithm: #SESSION_VARIABLE

// used for customizing access

@ObjectModel.usageType:{ serviceQuality: #C,        // < 15 msec   

                         sizeCategory:  #M,         // < 1.000

                         dataClass: #MIXED } 

define view I_BldngForHzdsSubstInvtryItem as select from I_HzdsSubstInventoryDraft
   
   inner join I_EHSLocationRevision  as _HSILocationRevision on _HSILocationRevision.EHSLocationUUID = I_HzdsSubstInventoryDraft.EHSLocationUUID
                                                            and _HSILocationRevision.RevisionStartDate   <= $session.system_date
                                                            and _HSILocationRevision.RevisionEndDate     >= $session.system_date
   
   inner join I_EHSLocationBuilding as _BuildingLocation on _BuildingLocation.EHSLocationRevisionUUID = _HSILocationRevision.EHSLocationRevisionUUID 
                                                        and _BuildingLocation.EHSLocationUUID = I_HzdsSubstInventoryDraft.EHSLocationUUID
   
   
   inner join I_EHSLocationRevision  as _BuildingLocationRevision on _BuildingLocationRevision.EHSLocationUUID = _BuildingLocation.BuildingEHSLocationUUID
                                                                 and _BuildingLocationRevision.RevisionStartDate   <= $session.system_date
                                                                 and _BuildingLocationRevision.RevisionEndDate     >= $session.system_date
     
{
  key HzdsSubstInventoryUUID,
  key _BuildingLocationRevision.EHSLocationUUID,

      _BuildingLocationRevision.EHSLocationType,
      _BuildingLocationRevision.EHSLocationStatus,
       cast( _BuildingLocationRevision.EHSLocationAuthorizationGroup as ehfnd_loc_auth_group_nc preserving type )   as  EHSLocationAuthorizationGroup,
      _BuildingLocationRevision.Plant,   
      _BuildingLocationRevision.CostCenter,
      _BuildingLocationRevision.CompanyCode,
      _BuildingLocationRevision.BusinessArea  
}

Learn More