@AbapCatalog: {
sqlViewName: 'IBKACCTINTIDVH',
compiler.compareFilter: true
}
@ClientHandling: {
type: #CLIENT_DEPENDENT,
algorithm: #SESSION_VARIABLE
}
@ObjectModel: {
usageType: {
serviceQuality: #C,
sizeCategory: #S,
dataClass: #CUSTOMIZING
}
}
@ObjectModel.dataCategory:#VALUE_HELP
@AccessControl.authorizationCheck: #MANDATORY
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Technical ID'
@Search.searchable: true
@UI.headerInfo: {
typeName: 'Bank Account',
typeNamePlural: 'Bank Accounts',
typeImageUrl: 'sap-icon://appointment-2',
title: { value: 'BankAccountInternalID' }
}
@Consumption.ranked: true
@ObjectModel.representativeKey: 'BankAccountInternalID'
@AccessControl.personalData.blocking: true
@Metadata.ignorePropagatedAnnotations: true
/* Comment of Usage
There are several bank account value helps provided.
This cds view will return bank account with inactive bank accounts and all activated ones.
If it does not meet your requirment, you may check below value help CDS Views.
I_BankAccountVH
I_BankAccountStdVH
I_BankAcctIdVH
C_BankAcctIdVH
C_BankAccountVH
I_BankAcctNumberVH
*/
define view I_BkAcctIntIDVH
as select from I_BkAcctBscDtaForKeyValue as _BkAcctBscDta
{
@UI.lineItem: [
{ position: 1, importance: #HIGH }
]
@Search: {
defaultSearchElement: true,
ranking: #HIGH,
fuzzinessThreshold: 0.8
}
key _BkAcctBscDta.BankAccountInternalID,
@UI.lineItem: [
{ position: 2, importance: #HIGH }
]
@UI.fieldGroup: [
{ qualifier: 'Bank Account', position: 1, importance: #HIGH }
]
@Search: {
defaultSearchElement: true,
ranking: #LOW,
fuzzinessThreshold: 0.8
}
@Consumption.valueHelpDefinition: [
{ entity:{name: 'I_BankAcctNumberVH', element: 'BankAccountNumber' } } ]
_BkAcctBscDta.BankAccountNumber,
@UI.lineItem: [
{ position: 3, importance: #HIGH }
]
@UI.fieldGroup: [
{ qualifier: 'Bank Account', position: 2, importance: #HIGH }
]
@Search: {
defaultSearchElement: true,
ranking: #LOW,
fuzzinessThreshold: 0.8
}
_BkAcctBscDta.BankAccountDescription,
@UI.lineItem: [
{ position:4, importance: #HIGH }
]
@UI.fieldGroup: [
{ qualifier: 'Bank Account', position: 3, importance: #HIGH }
]
@Search: {
defaultSearchElement: true,
ranking: #LOW,
fuzzinessThreshold: 0.8
}
@Consumption.valueHelpDefinition: [
{ entity:{name: 'I_CurrencyStdVH', element: 'Currency' } } ]
_BkAcctBscDta.BankAccountCurrency,
@UI.lineItem: [
{ position: 5, importance: #HIGH }
]
@UI.fieldGroup: [
{ qualifier: 'Bank Account', position: 4, importance: #HIGH }
]
@Search: {
defaultSearchElement: true,
ranking: #LOW,
fuzzinessThreshold: 0.8
}
@Consumption.valueHelpDefinition: [
{ entity:{name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } } ]
@ObjectModel.text.element: [ 'CompanyCodeName' ]
@UI.textArrangement: #TEXT_LAST
_BkAcctBscDta.CompanyCode,
@Consumption.filter.hidden: true
_BkAcctBscDta._CompanyCode.CompanyCodeName,
@UI.lineItem: [
{ position: 6, importance: #HIGH }
]
@UI.fieldGroup: [
{ qualifier: 'Bank Account', position: 5, importance: #HIGH }
]
@Search: {
defaultSearchElement: true,
ranking: #LOW,
fuzzinessThreshold: 0.8
}
@Consumption.valueHelpDefinition: [
{ entity:{name: 'I_BankAccountTypeVH', element: 'BankAccountType' } } ]
@ObjectModel.text.element: [ 'BankAccountTypeText' ]
@UI.textArrangement: #TEXT_LAST
_BkAcctBscDta.BankAccountType,
@Consumption.filter.hidden: true
_BkAcctBscDta._BankAccountType.BankAccountTypeText,
@UI.lineItem:[{position:7}]
@UI.fieldGroup: [
{ qualifier: 'Bank Account', position: 6, importance: #HIGH }
]
@Consumption.valueHelpDefinition: [
{ entity:{name: 'I_ContractTypeValueHelp', element: 'BankAccountContractType' } } ]
@ObjectModel.text.element: [ 'BankAccountContractTypeName' ]
@UI.textArrangement: #TEXT_LAST
_BkAcctBscDta._BankAccountType.BankAccountContractType,
@Consumption.filter.hidden: true
_BkAcctBscDta._BankAccountType.BankAccountContractTypeName,
@UI.lineItem: [
{ position: 8, importance: #HIGH }
]
@UI.fieldGroup: [
{ qualifier: 'Bank Account', position: 7, importance: #HIGH }
]
@Search: {
defaultSearchElement: true,
ranking: #LOW,
fuzzinessThreshold: 0.8
}
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_BankVH', element: 'BankInternalID' } } ]
@ObjectModel.text.element: [ 'BankName' ]
@UI.textArrangement: #TEXT_LAST
_BkAcctBscDta.Bank,
@Consumption.filter.hidden: true
_BkAcctBscDta._BankKey.BankName,
@UI.lineItem: [
{ position: 9, importance: #HIGH }
]
@UI.fieldGroup: [
{ qualifier: 'Bank Account', position: 8, importance: #HIGH }
]
@Search: {
defaultSearchElement: true,
ranking: #LOW,
fuzzinessThreshold: 0.8
}
@Consumption.valueHelpDefinition: [
{ entity:{name: 'I_CountryVH', element: 'Country' } } ]
_BkAcctBscDta.BankCountry,
@UI.lineItem: [
{ position: 10, importance: #HIGH }
]
@UI.fieldGroup: [
{ qualifier: 'Bank Account', position: 9, importance: #HIGH }
]
@Search: {
defaultSearchElement: true,
ranking: #LOW,
fuzzinessThreshold: 0.8
}
// @Consumption.valueHelpDefinition: [
// { entity:{name: 'C_BankAccountIBANVH', element: 'IBAN' } } ]
_BkAcctBscDta.IBAN,
@UI.lineItem: [
{ position: 11, importance: #HIGH }
]
@UI.fieldGroup: [
{ qualifier: 'Bank Account', position: 10, importance: #HIGH }
]
@Search: {
defaultSearchElement: true,
ranking: #LOW,
fuzzinessThreshold: 0.8
}
@Consumption.valueHelpDefinition: [
{ entity:{name: 'C_BankSwiftCodeVH_2', element: 'SWIFTCode' } } ]
_BkAcctBscDta.SWIFTCode
}
where
(
_BkAcctBscDta.BankAccountRevision = '0000'
and _BkAcctBscDta.BankAccountStatus <> '99'
)
or(
_BkAcctBscDta.BankAccountRevision = '0000'
and _BkAcctBscDta.OpenNewBankAccountRequest is not initial
and _BkAcctBscDta.BankAccountStatus = '99'
)