I_BillOfOperationsVersionType

@AbapCatalog.sqlViewName: 'IPPBOOVTYPE'
@AbapCatalog.buffering: { status: #ACTIVE, type: #GENERIC, numberOfKeyFields: 001 }
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataCategory: #DIMENSION
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations:true 
@ObjectModel.representativeKey: 'BillOfOperationsVersionType'
@ObjectModel.usageType: { serviceQuality: #A, sizeCategory: #S, dataClass: #CUSTOMIZING }
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Bill of Operations Version Type'

define view I_BillOfOperationsVersionType
  as select from tca01_subtype
  association [0..*] to I_BOOVersionTypeText     as _Text                   on $projection.BillOfOperationsVersionType = _Text.BillOfOperationsVersionType
  association [0..1] to I_BillOfOperationsUsage  as _BillOfOperationsUsage  on $projection.BillOfOperationsUsage       = _BillOfOperationsUsage.BillOfOperationsUsage
  association [0..1] to I_BillOfOperationsStatus as _BillOfOperationsStatus on $projection.BillOfOperationsStatus      = _BillOfOperationsStatus.BillOfOperationsStatus
{
      @ObjectModel.text.association: '_Text'
  key subtype as BillOfOperationsVersionType,
      default_subtype        as BOOVersionTypeIsDefault,
      successive_vers        as BOOVersionIsSuccessive,     
      numeric_version        as BOOVersionIsNumeric,
      change_record_required as BOOVersionChangeRecordIsRqd,
      upgrade_mbom           as BOOVersionIsMBOMUpgradeAllwd,
      single_mbom            as BOOVersionIsSingleMBOMRequired,
      @ObjectModel.foreignKey.association: '_BillOfOperationsUsage'
      default_verwe          as BillOfOperationsUsage,
      @ObjectModel.foreignKey.association: '_BillOfOperationsStatus'      
      default_statu          as BillOfOperationsStatus,
      workflow_scenario_id   as ScenarioID,
      // Associations

      _Text,
      _BillOfOperationsUsage,
      _BillOfOperationsStatus
};