I_BankAccountElectronicMessage

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'EBAM message'
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #BASIC
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #S,
  dataClass: #MIXED
}
define view entity I_BankAccountElectronicMessage
  as select from    fclm_ebam_msg    as msg
    inner join      fclm_bam_req     as request     on msg.request_id = request.request_id
    inner join      fclm_bam_reqacnt as requestacct on request.request_id = requestacct.request_id
    left outer to many join  /bsnagt/file_inf as file        on msg.msg_guid = file.guid
{
  key msg.request_id          as BankAccountChangeRequest,
  key msg.msg_guid            as BkAcctMsgUUID,
      requestacct.acc_id      as BankAccountInternalID,
      requestacct.revision    as BankAccountRevision,
      request.request_status  as BankAccountChangeRequestStatus,
      request.account_action  as BankAccountAction,
//      request.request_process as BkAcctChgReqProc,

      request.title           as BankAcctChangeReqHeadingText,
      request.created_on      as CreationDate,
      request.created_by      as CreatedByUser,
      request.created_tm      as CreationTime,
      request.lastchged_on    as LastChangeDate,
      request.lastchged_by    as LastChangedByUser,
      request.lastchged_tm    as LastChangeTime,
      request.request_step    as BankAccountChangeRequestStep,
      request.duedate         as BankAcctChangeRequestDueDate,
      file.messagetype        as BankAccountMessageType,
      file.status             as BankAccountMessageStatus,
      file.filedirection      as BankAccountMessageDirection,
      file.messageid          as BkAcctMsgIdn

}