I_BankAccTextTP

DDL: I_BANKACCTEXTTP Type: view TRANSACTIONAL Package: FCLM_BAM

Bank Account Text BO active and draft

I_BankAccTextTP is a Transactional CDS View that provides data about "Bank Account Text BO active and draft" in SAP S/4HANA. It reads from 1 data source (fclm_bam_amd_t) and exposes 8 fields with key fields BankAccountInternalID, BankAccountRevision, Language. It has 2 associations to related views. Part of development package FCLM_BAM.

1 data source(s) 8 fields

Data Sources (1)

SourceAliasJoin Type
fclm_bam_amd_t AccountText from

Associations (2)

CardinalityTargetAliasCondition
[1..1] I_BankAccountTP _Account $projection.BankAccountInternalID = _Account.BankAccountInternalID and $projection.BankAccountRevision = _Account.BankAccountRevision -- overwrite _Language association: the base view
[0..1] I_Language _Language $projection.LanguageForEdit = _Language.Language

Annotations (17)

NameValueLevelField
AbapCatalog.sqlViewName IBANKACCTEXTTP view
AbapCatalog.compiler.compareFilter true view
EndUserText.label Bank Account Text BO active and draft view
VDM.viewType #TRANSACTIONAL view
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
ObjectModel.dataCategory #TEXT view
ObjectModel.writeDraftPersistence BANKACCTEXTWD view
ObjectModel.createEnabled true view
ObjectModel.updateEnabled true view
ObjectModel.deleteEnabled true view
ObjectModel.representativeKey BankAccountInternalID view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ClientHandling.algorithm #SESSION_VARIABLE view
AccessControl.authorizationCheck #NOT_REQUIRED view
Metadata.allowExtensions true view

Fields (8)

KeyFieldSource TableSource FieldDescription
KEY BankAccountInternalID fclm_bam_amd_t acc_id
KEY BankAccountRevision fclm_bam_amd_t revision
KEY Language fclm_bam_amd_t langu
LanguageForEdit fclm_bam_amd_t langu
BankAccountDescription fclm_bam_amd_t description
IsMarkedForDeletion fclm_bam_amd_t deleted_flag
_Language _Language
_Account _Account 
@AbapCatalog: {
    sqlViewName: 'IBANKACCTEXTTP',
    compiler.compareFilter: true
}

@EndUserText.label: 'Bank Account Text BO active and draft'

@VDM:{
    viewType: #TRANSACTIONAL,
    lifecycle.contract.type:#SAP_INTERNAL_API
}

@ObjectModel: {
    dataCategory: #TEXT,
    writeDraftPersistence: 'BANKACCTEXTWD',
    createEnabled: true,
    updateEnabled: true,
    deleteEnabled: true,
    semanticKey: [ 'BankAccountInternalID', 'BankAccountRevision', 'Language' ],
    representativeKey: 'BankAccountInternalID',
    usageType: {
        sizeCategory: #S,
        serviceQuality: #C,
        dataClass: #TRANSACTIONAL
    }
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@AccessControl.authorizationCheck: #NOT_REQUIRED

@Metadata.allowExtensions: true
define view I_BankAccTextTP
  as select from fclm_bam_amd_t as AccountText
  association [1..1] to I_BankAccountTP as _Account  on  $projection.BankAccountInternalID = _Account.BankAccountInternalID
                                                     and $projection.BankAccountRevision   = _Account.BankAccountRevision
  -- overwrite _Language association: the base view association related on field Language, but we need it on the editable
  -- language field (LanguageForEdit)
  association [0..1] to I_Language      as _Language on  $projection.LanguageForEdit = _Language.Language
{
      @ObjectModel: {
        readOnly: true
      }
  key AccountText.acc_id         as BankAccountInternalID,
      @ObjectModel: {
        readOnly: true,
        foreignKey.association: null
      }
  key AccountText.revision       as BankAccountRevision,
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key AccountText.langu          as Language,             
      @ObjectModel: {
      //        readOnly:  'EXTERNAL_CALCULATION',

        enabled: 'EXTERNAL_CALCULATION',
        readOnly:  'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION',
        foreignKey.association: '_Language'
      }
      AccountText.langu          as LanguageForEdit,

      @ObjectModel: {
      //        readOnly:  'EXTERNAL_CALCULATION',

        mandatory: true
      }
      @Semantics.languageReference: 'LanguageForEdit'
      @Semantics.text: true
      AccountText.description    as BankAccountDescription,

      @ObjectModel: {
        readOnly: true
      }
      @Consumption: {
        hidden: true
      }
      AccountText.deleted_flag   as IsMarkedForDeletion,
      _Language,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _Account
}
where
      AccountText.langu <> '늑'
  and AccountText.langu <> '닱'
  and AccountText.langu <> ''
  and deleted_flag      <> 'X'
  and AccountText.langu <> $session.system_language

Learn More