I_BPSupplierCompanyGov

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'BP Supplier Company Data Governance'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
@VDM.viewType: #COMPOSITE
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view entity I_BPSupplierCompanyGov
  as select from I_BPSupplierCompanyProcess

  association [1..1] to I_BusinessPartnerGov        as _BusinessPartner           on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                                                  and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                                                  and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                                                  and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject
  association [1..1] to I_BPSupplierGov             as _Supplier                  on  $projection.MasterDataChangeProcess = _Supplier.MasterDataChangeProcess
                                                                                  and $projection.MDChgProcessStep        = _Supplier.MDChgProcessStep
                                                                                  and $projection.MDChgProcessSrceSystem  = _Supplier.MDChgProcessSrceSystem
                                                                                  and $projection.MDChgProcessSrceObject  = _Supplier.MDChgProcessSrceObject


  association [0..1] to I_MasterDataChangeProcess   as _MasterDataChangeProcess   on  $projection.MasterDataChangeProcess = _MasterDataChangeProcess.MasterDataChangeProcess

  association [1..1] to I_SupplierToBusinessPartner as _SupplierToBusinessPartner on  $projection.Supplier = _SupplierToBusinessPartner.Supplier



{

  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
  key CompanyCode,
      BPAssignmentID,
      Supplier,
      PersonnelNumber,
      SupplierIsBlockedForPosting,
      DeletionIndicator,
      LayoutSortingRule,
      ReconciliationAccount,
      AuthorizationGroup,
      InterestCalculationCode,
      PaymentMethodsList,
      ClearCustomerSupplier,
      PaymentBlockingReason,
      PaymentTerms,
      SupplierClerkIDBySupplier,
      SupplierClerk,
      SupplierAccountNote,
      CashPlanningGroup,
      AccountingClerk,
      SupplierHeadOffice,
      AlternativePayee,
      InterestCalculationDate,
      IntrstCalcFrequencyInMonths,
      LastInterestCalcRunDate,
      IsToBeLocallyProcessed,
      Currency,
      @Semantics.amount.currencyCode: 'Currency'
      BillOfExchLmtAmtInCoCodeCrcy,
      CheckPaidDurationInDays,
      IsDoubleInvoice,
      APARToleranceGroup,
      HouseBank,
      ItemIsToBePaidSeparately,
      MinorityGroup,
      PreviousAccountNumber,
      PaymentMethodSupplement,
      WithholdingTaxCountry,
      PaymentIsToBeSentByEDI,
      SupplierReleaseGroup,
      SuplrInvcVerificatTolGroup,
      AccountingClerkFaxNumber,
      AccountingClerkInternetAddress,
      CreditMemoPaymentTerms,
      SupplierCertificationDate,
      DeletionIsBlocked,
      AccountingClerkPhoneNumber,
      cast(
      case when MDChgProcessStep = _MasterDataChangeProcess.MDChgProcessCurrentStepNumber and _MasterDataChangeProcess.MDChgProcessCurrentStepNumber <> '0000' or
          MDChgProcessStep = '0001' and  _MasterDataChangeProcess.MDChgProcessCurrentStepNumber = '0000' then 'X'
      else ' '
      end as abap_boolean preserving type
      )                           as MasterDataIsCurrent,

      cast( 'P' as abap.char(1) ) as Origin,
      /* Associations */
      _BusinessPartner,
      _CompanyCode,
      _Supplier,
      _SupplierToBusinessPartner
      //      _PaymentBlockingReason,

      //      _PaymentBlockingReasonText,

      //      _PaymentTermsText,

      //      _APARToleranceGroupName

}
where
  MDChgProcessSourceModified <> 'D'

union all

select from I_SupplierCompany
association [1..1] to I_BusinessPartnerGov        as _BusinessPartner           on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                                                and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                                                and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                                                and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject

association [1..1] to I_BPSupplierGov             as _Supplier                  on  $projection.MasterDataChangeProcess = _Supplier.MasterDataChangeProcess
                                                                                and $projection.MDChgProcessStep        = _Supplier.MDChgProcessStep
                                                                                and $projection.MDChgProcessSrceSystem  = _Supplier.MDChgProcessSrceSystem
                                                                                and $projection.MDChgProcessSrceObject  = _Supplier.MDChgProcessSrceObject

association [1..1] to I_SupplierToBusinessPartner as _SupplierToBusinessPartner on  $projection.Supplier = _SupplierToBusinessPartner.Supplier

{

  key  '000000000000'                                              as MasterDataChangeProcess,
  key  '0000'                                                      as MDChgProcessStep,
  key  ''                                                          as MDChgProcessSrceSystem,
  key  _SupplierToBusinessPartner._BusinessPartner.BusinessPartner as MDChgProcessSrceObject,
  key  CompanyCode,
       '000000000001'                                              as BPAssignmentID,
       Supplier,
       PersonnelNumber,
       SupplierIsBlockedForPosting,
       DeletionIndicator,
       LayoutSortingRule,
       ReconciliationAccount,
       AuthorizationGroup,
       InterestCalculationCode,
       PaymentMethodsList,
       ClearCustomerSupplier,
       PaymentBlockingReason,
       PaymentTerms,
       SupplierClerkIDBySupplier,
       SupplierClerk,
       SupplierAccountNote,
       CashPlanningGroup,
       AccountingClerk,
       SupplierHeadOffice,
       AlternativePayee,
       InterestCalculationDate,
       IntrstCalcFrequencyInMonths,
       LastInterestCalcRunDate,
       IsToBeLocallyProcessed,
       Currency,
       BillOfExchLmtAmtInCoCodeCrcy,
       CheckPaidDurationInDays,
       IsDoubleInvoice,
       APARToleranceGroup,
       HouseBank,
       ItemIsToBePaidSeparately,
       MinorityGroup,
       PreviousAccountNumber,
       PaymentMethodSupplement,
       WithholdingTaxCountry,
       PaymentIsToBeSentByEDI,
       SupplierReleaseGroup,
       SuplrInvcVerificatTolGroup,
       AccountingClerkFaxNumber,
       AccountingClerkInternetAddress,
       CreditMemoPaymentTerms,
       SupplierCertificationDate,
       DeletionIsBlocked,
       AccountingClerkPhoneNumber,

       cast( 'X' as abap_boolean preserving type )                 as MasterDataIsCurrent,

       cast( 'A' as abap.char(1) )                                 as Origin,
       /* Associations */
       _BusinessPartner,
       _CompanyCode,
       _Supplier,
       _SupplierToBusinessPartner
       //       _PaymentBlockingReason,

       //       _PaymentBlockingReasonText,

       //       _PaymentTermsText,

       //       _APARToleranceGroupName


}
where
  _SupplierToBusinessPartner._BusinessPartner.BusinessPartner is not initial