I_BPIndepCommMethodProcChanges

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Address Indep Comm Method Changes'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view entity I_BPIndepCommMethodProcChanges
  as select from           I_BPIndepCommMethodProcess  as _Current
    left outer to one join I_MDChangeProcessModelTable as _ModelTable on  _ModelTable.MDChgProcessModelTableName     = 'ADRC_IN'
                                                                      and _ModelTable.MDChgProcessSrceObjectTypeCode = '147'

  association [1..1] to I_BusinessPartnerProcess as _BusinessPartner on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                                     and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                                     and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                                     and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject

{

  key _Current.MasterDataChangeProcess,
  key _Current.MDChgProcessStep,
  key _Current.MDChgProcessSrceSystem,
  key _Current.MDChgProcessSrceObject,
  key _Current.AddressNumber,
  key _ModelTable.MDChgProcessModelTableName,
  key cast ( '' as fieldname )                            as MDChangeProcessModelFieldName,
  key cast( concat(_Current.MDChgProcessSrceSystem, concat( '%%', _Current.MDChgProcessSrceObject))
           as abap.char(1000) )                           as MDChgProcessRecordObjectID,
      _ModelTable.MDChangeProcModelTableDesc,
      cast ('' as as4text )                               as MDChangeProcessModelFieldDesc,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      cast( 'BPIndepCommunicationMethod' as fieldname )   as MDChgProcModelNodeExternalName,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      cast( 'I_BPIndepCommMethodProcessTP' as fieldname ) as MDChgProcModTableExternalName,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPAPROCTP2_CALC_EXIT'
      cast( '' as fieldname )                             as MDChgProcModFieldExternalName,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPAPROCTP2_CALC_EXIT'
      cast( '' as abap.char( 260 ) )                      as MDChgProcCurrentAttributeValue,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPAPROCTP2_CALC_EXIT'
      cast( '' as abap.char( 260 ) )                      as MDChgProcPrevAttributeValue,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPAPROCTP2_CALC_EXIT'
      cast( '' as boolean )                               as MDChgProcessAttributeIsChanged,
      _Current.MDChgProcessSourceModified,
      _Current.PrfrdCommMediumType                        as MDChgProcessRecordObjectText,

      _BusinessPartner
}
where
     _Current.MDChgProcessSourceModified = 'I'
  or _Current.MDChgProcessSourceModified = 'D'

union all select from     I_BPIndepCommMethodProcess  as _Current
  left outer to many join I_MDChangeProcessModelField as _ModelField on  _ModelField.MDChgProcessModelTableName     = 'ADRC_IN'
                                                                     and _ModelField.MDChgProcessSrceObjectTypeCode = '147'
association [1..1] to I_BusinessPartnerProcess as _BusinessPartner on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                                   and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                                   and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                                   and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject

{
      //I_BusinessPartnerProcess

  key _Current.MasterDataChangeProcess,
  key _Current.MDChgProcessStep,
  key _Current.MDChgProcessSrceSystem,
  key _Current.MDChgProcessSrceObject,
  key _Current.AddressNumber,
  key _ModelField.MDChgProcessModelTableName,
  key _ModelField.MDChangeProcessModelFieldName,
  key cast( concat(_Current.MDChgProcessSrceSystem, concat( '%%', _Current.MDChgProcessSrceObject))
          as abap.char(1000) )                            as MDChgProcessRecordObjectID,
      _ModelField.MDChangeProcModelTableDesc,
      _ModelField.MDChangeProcessModelFieldDesc,
      cast( 'BPIndepCommunicationMethod' as fieldname )   as MDChgProcModelNodeExternalName,
      cast( 'I_BPIndepCommMethodProcessTP' as fieldname ) as MDChgProcModTableExternalName,
      cast( '' as fieldname )                             as MDChgProcModFieldExternalName,
      cast( '' as abap.char( 260 ) )                      as MDChgProcCurrentAttributeValue,
      cast( '' as abap.char( 260 ) )                      as MDChgProcPrevAttributeValue,
      cast( '' as boolean )                               as MDChgProcessAttributeIsChanged,
      _Current.MDChgProcessSourceModified,
      _Current.PrfrdCommMediumType                        as MDChgProcessRecordObjectText,

      _BusinessPartner
}
where
  _Current.MDChgProcessSourceModified = 'X'