I_BPFaxNumberTP

@AbapCatalog.sqlViewName: 'IBPFAXNUMBERTP'
@EndUserText.label: 'Business Partner Fax'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@VDM.viewType: #TRANSACTIONAL
@ObjectModel.writeEnabled: true
@ObjectModel.writeDraftPersistence: 'BUPA_FAXNO_D'
@ObjectModel.draftEnabled:true

@ObjectModel.semanticKey: ['BusinessPartner','AddressID','Person', 'OrdinalNumber' ] // Need to check

@ObjectModel.createEnabled
@ObjectModel.updateEnabled
@ObjectModel.deleteEnabled

@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER

@Search.searchable: true
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view I_BPFaxNumberTP as select from I_BPFaxNumber as BPFaxNumber 
  
association [1..1] to I_BusinessPartnerTP as _BusinessPartner on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
association [1..1] to I_BusinessPartnerAddressTP as _BusinessPartnerAddress on  $projection.AddressID = _BusinessPartnerAddress.AddressNumber
                                                                             and $projection.BusinessPartner = _BusinessPartnerAddress.BusinessPartner


{
   key BPFaxNumber.BusinessPartner, 
   
    key BPFaxNumber.AddressID, 
   key BPFaxNumber.Person, 
   key BPFaxNumber.OrdinalNumber, 
    BPFaxNumber.IsDefaultFaxNumber, 
    BPFaxNumber.FaxCountry, 
     @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
    @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
    BPFaxNumber.FaxNumber, 
    @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
    BPFaxNumber.FaxNumberExtension, 
    BPFaxNumber.InternationalFaxNumber,
  //  _AddressCommunicationRemark.AddressCommunicationRemarkText,

  // cast('' as ad_remark2 ) as AddressCommunicationRemarkText,

    BPFaxNumber._AddressCommunicationRemark.CommunicationRemarkText as AddressCommunicationRemarkText,
    @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT ]
    _BusinessPartner,
    @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT ]
    _BusinessPartnerAddress
}