I_BPDataControllerTP

@AbapCatalog.sqlViewName: 'IBPDATACTRLRTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'TP view for BP Data Controller'
@AccessControl.personalData.blocking: #REQUIRED
@VDM.viewType: #TRANSACTIONAL
@ClientHandling.algorithm : #SESSION_VARIABLE
@ObjectModel.writeDraftPersistence: 'BUT_DC_LINK_D'
@ObjectModel.semanticKey: [ 'BusinessPartner','DataControllerName', 'BPDataPurposeText' ]
@ObjectModel.draftEnabled:true
@ObjectModel.createEnabled
@ObjectModel.deleteEnabled: #( EXTERNAL_CALCULATION )
@ObjectModel.updateEnabled
@Search.searchable: true

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
define view I_BPDataControllerTP
  as select from I_BPDataController as _BPDataController
  association [1..1] to I_BusinessPartnerTP as _BusinessPartner on $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association [1..1] to I_DC_DATA_CTRL      as _DataController  on $projection.DataControllerName = _DataController.DataCtrlName
  
{
  key    _BPDataController.DataControllerName,
  key    _BPDataController.BusinessPartner,
  key    _BPDataController.BPDataPurposeText,
         _BPDataController.BusinessPartner    as BusinessPartnerForEdit,
         @Search.defaultSearchElement: true
         _BPDataController.DataControllerName as DataControllerNameForEdit,
         _BPDataController.BPDataPurposeText as BPDataPurposeTextForEdit,
         BPDataControllerIsDerived            as IsDerivationSet,
         @ObjectModel.readOnly: 'true'
         _DataController.DataCtrlDescription  as DataControllerDescription,
         _BusinessPartner.AuthorizationGroup  as AuthorizationGroup,
         case DataControlAssignmentStatus 
         when 'I' then cast ( 'X' as boole_d )
         else cast( '' as boole_d )
         end as DataControlAssignmentStatus,
         PurposeDerived,
         PurposeType,
         BusinessPurposeFlag,
         @ObjectModel.association.type: [#TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT]
         _BusinessPartner,
         _DataController

}