I_BPDataControllerGovernance

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'BP Data Controller Governance'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #XXL,
  dataClass: #TRANSACTIONAL
}
@VDM.viewType: #TRANSACTIONAL
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view entity I_BPDataControllerGovernance
  as select from I_BPDataControllerProcess
  association [1..1] to I_BusinessPartnerGov      as _BusinessPartnerGov      on  $projection.MasterDataChangeProcess = _BusinessPartnerGov.MasterDataChangeProcess
                                                                              and $projection.MDChgProcessStep        = _BusinessPartnerGov.MDChgProcessStep
                                                                              and $projection.MDChgProcessSrceSystem  = _BusinessPartnerGov.MDChgProcessSrceSystem
                                                                              and $projection.MDChgProcessSrceObject  = _BusinessPartnerGov.MDChgProcessSrceObject
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_MasterDataChangeProcess as _MasterDataChangeProcess on  $projection.MasterDataChangeProcess = _MasterDataChangeProcess.MasterDataChangeProcess
{
  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
  key DataController,
  key PurposeForPersonalData,
      @Semantics.booleanIndicator: true
      IsDerivationSet,
      DataControlAssignmentStatus,
      PurposeDerived,
      PurposeType,
      @Semantics.booleanIndicator: true
      IsBPBusinessPurposeCmpltd,
      cast(
        case when MDChgProcessStep = _MasterDataChangeProcess.MDChgProcessCurrentStepNumber and _MasterDataChangeProcess.MDChgProcessCurrentStepNumber <> '0000' or
                  MDChgProcessStep = '0001' and  _MasterDataChangeProcess.MDChgProcessCurrentStepNumber = '0000' then 'X'
             else ' '
        end as abap_boolean preserving type
      ) as MasterDataIsCurrent,

      _BusinessPartnerGov
}
where
  MDChgProcessSourceModified <> 'D'

union all

select from I_BPDataController
association [1..1] to I_BusinessPartnerGov as _BusinessPartnerGov on  $projection.MasterDataChangeProcess = _BusinessPartnerGov.MasterDataChangeProcess
                                                                  and $projection.MDChgProcessStep        = _BusinessPartnerGov.MDChgProcessStep
                                                                  and $projection.MDChgProcessSrceSystem  = _BusinessPartnerGov.MDChgProcessSrceSystem
                                                                  and $projection.MDChgProcessSrceObject  = _BusinessPartnerGov.MDChgProcessSrceObject
{
  key  '000000000000'                              as MasterDataChangeProcess,
  key  '0000'                                      as MDChgProcessStep,
  key  ''                                          as MDChgProcessSrceSystem,
  key  BusinessPartner                             as MDChgProcessSrceObject,
  key  DataControllerName                          as DataController,
  key  BPDataPurposeText                           as PurposeForPersonalData,
       BPDataControllerIsDerived                   as IsDerivationSet,
       DataControlAssignmentStatus,
       PurposeDerived,
       PurposeType,
       BusinessPurposeFlag                         as IsBPBusinessPurposeCmpltd,
       cast( 'X' as abap_boolean preserving type ) as MasterDataIsCurrent,

       _BusinessPartnerGov
}