I_BPCustomerProcessChanges

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'BP Customer Process Changes'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #XXL,
  dataClass: #TRANSACTIONAL
}
@VDM.viewType: #TRANSACTIONAL
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view entity I_BPCustomerProcessChanges
  as select from           I_BPCustomerProcess         as Current
    left outer to one join I_MDChangeProcessModelTable as ModelTable on  ModelTable.MDChgProcessModelTableName     = 'KNA1'
                                                                      and ModelTable.MDChgProcessSrceObjectTypeCode = '147'
  association [1..1] to I_BPCustomerProcess as _Customer on  $projection.MasterDataChangeProcess = _Customer.MasterDataChangeProcess
                                                         and $projection.MDChgProcessStep        = _Customer.MDChgProcessStep
                                                         and $projection.MDChgProcessSrceSystem  = _Customer.MDChgProcessSrceSystem
                                                         and $projection.MDChgProcessSrceObject  = _Customer.MDChgProcessSrceObject

{
  key Current.MasterDataChangeProcess,
  key Current.MDChgProcessStep,
  key Current.MDChgProcessSrceSystem,
  key Current.MDChgProcessSrceObject,
  key ModelTable.MDChgProcessModelTableName,
  key cast ( '' as fieldname )                       as MDChangeProcessModelFieldName,
  key cast( concat(
              concat( Current.MDChgProcessSrceSystem, concat( '%%', Current.MDChgProcessSrceObject )),
            concat( '%%', Current.BPAssignmentID ))
      as abap.char(1000) )                           as MDChgProcessRecordObjectID,
      ModelTable.MDChangeProcModelTableDesc,
      cast ('' as as4text  )                         as MDChangeProcessModelFieldDesc,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      cast( 'BusinessPartnerCustomer' as fieldname ) as MDChgProcModelNodeExternalName,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      cast( 'I_BPCustomerProcessTP' as fieldname )   as MDChgProcModTableExternalName,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_CUST_PROCTP_CALC_EXIT'
      cast( '' as fieldname )                        as MDChgProcModFieldExternalName,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_CUST_PROCTP_CALC_EXIT'
      cast( '' as abap.char( 260 ) )                 as MDChgProcCurrentAttributeValue,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_CUST_PROCTP_CALC_EXIT'
      cast( '' as abap.char( 260 ) )                 as MDChgProcPrevAttributeValue,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_CUST_PROCTP_CALC_EXIT'
      cast( '' as boolean )                          as MDChgProcessAttributeIsChanged,
      Current.MDChgProcessSourceModified,
      cast( '' as abap.char( 260 ) )                 as MDChgProcessRecordObjectText,
      _Customer
}
where
     Current.MDChgProcessSourceModified = 'I'
  or Current.MDChgProcessSourceModified = 'D'

union all select from     I_BPCustomerProcess         as Current
  left outer to many join I_MDChangeProcessModelField as ModelField on  ModelField.MDChgProcessModelTableName     = 'KNA1'
                                                                     and ModelField.MDChgProcessSrceObjectTypeCode = '147'
association [1..1] to I_BPCustomerProcess as _Customer on  $projection.MasterDataChangeProcess = _Customer.MasterDataChangeProcess
                                                       and $projection.MDChgProcessStep        = _Customer.MDChgProcessStep
                                                       and $projection.MDChgProcessSrceSystem  = _Customer.MDChgProcessSrceSystem
                                                       and $projection.MDChgProcessSrceObject  = _Customer.MDChgProcessSrceObject

{
  key Current.MasterDataChangeProcess,
  key Current.MDChgProcessStep,
  key Current.MDChgProcessSrceSystem,
  key Current.MDChgProcessSrceObject,
  key ModelField.MDChgProcessModelTableName,
  key ModelField.MDChangeProcessModelFieldName,
  key cast( concat(
              concat( Current.MDChgProcessSrceSystem, concat( '%%', Current.MDChgProcessSrceObject )),
            concat( '%%', Current.BPAssignmentID ))
      as abap.char(1000) )                           as MDChgProcessRecordObjectID,
      ModelField.MDChangeProcModelTableDesc,
      ModelField.MDChangeProcessModelFieldDesc,
      cast( 'BusinessPartnerCustomer' as fieldname ) as MDChgProcModelNodeExternalName,
      cast( 'I_BPCustomerProcessTP' as fieldname )   as MDChgProcModTableExternalName,
      cast( '' as fieldname )                        as MDChgProcModFieldExternalName,
      cast( '' as abap.char( 260 ) )                 as MDChgProcCurrentAttributeValue,
      cast( '' as abap.char( 260 ) )                 as MDChgProcPrevAttributeValue,
      cast( '' as boolean )                          as MDChgProcessAttributeIsChanged,
      Current.MDChgProcessSourceModified,
      cast( '' as abap.char( 260 ) )                 as MDChgProcessRecordObjectText,
      _Customer

}
where
  Current.MDChgProcessSourceModified = 'X'