I_BPCustUnloadingPointProcTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'BP Customer Partner Unloading Point Data Process - TP'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #S,
  dataClass: #MIXED
}
@VDM.viewType: #TRANSACTIONAL
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view entity I_BPCustUnloadingPointProcTP
  as select from I_BPCustomerUnloadingPointProc
  association        to parent I_BPCustomerProcessTP as _Customer             on  $projection.MasterDataChangeProcess = _Customer.MasterDataChangeProcess
                                                                              and $projection.MDChgProcessStep        = _Customer.MDChgProcessStep
                                                                              and $projection.MDChgProcessSrceSystem  = _Customer.MDChgProcessSrceSystem
                                                                              and $projection.MDChgProcessSrceObject  = _Customer.MDChgProcessSrceObject
                                                                              and $projection.BPAssignmentID          = _Customer.BPAssignmentID
  association        to I_BusinessPartnerProcessTP   as _BusinessPartner      on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                                              and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                                              and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                                              and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject
  association [0..1] to I_BPProcessKPIRecordType     as _RecordType           on  $projection.MasterDataChangeProcess = _RecordType.MasterDataChangeProcess
                                                                              and $projection.MDChgProcessStep        = _RecordType.MDChgProcessStep
                                                                              and $projection.MDChgProcessSrceSystem  = _RecordType.MDChgProcessSrceSystem
                                                                              and $projection.MDChgProcessSrceObject  = _RecordType.MDChgProcessSrceObject
  association [0..*] to I_MDChgProcRecordMessages    as _RecordMessages       on  $projection.MasterDataChangeProcess = _RecordMessages.MasterDataChangeProcess
                                                                              and $projection.MDChgProcessStep        = _RecordMessages.MDChgProcessStep
                                                                              and $projection.MDChgProcessSrceSystem  = _RecordMessages.MDChgProcessSrceSystem
                                                                              and $projection.MDChgProcessSrceObject  = _RecordMessages.MDChgProcessSrceObject
  association [0..1] to I_MDChangeProcessKPIRowVH    as _KPIUpdateStatusText  on  $projection.MDChgProcKPIUpdateStatus = _KPIUpdateStatusText.MDChgProcKPIUpdateStatus
  association [0..1] to I_FactoryCalendar            as _FactoryCalendar      on  $projection.CustomerFactoryCalenderCode = _FactoryCalendar.FactoryCalendar
  association [0..1] to I_BPGoodsReceivingHour       as _BPGoodsReceivingHour on  $projection.BPGoodsReceivingHoursCode = _BPGoodsReceivingHour.BPGoodsReceivingHoursCode
{
  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
  key UnloadingPointName,
  key BPAssignmentID,
      CustomerFactoryCalenderCode,
      BPGoodsReceivingHoursCode,
      IsDfltBPUnloadingPoint,
      Customer,
      MondayMorningOpeningTime,
      MondayMorningClosingTime,
      MondayAfternoonOpeningTime,
      MondayAfternoonClosingTime,
      TuesdayMorningOpeningTime,
      TuesdayMorningClosingTime,
      TuesdayAfternoonOpeningTime,
      TuesdayAfternoonClosingTime,
      WednesdayMorningOpeningTime,
      WednesdayMorningClosingTime,
      WednesdayAfternoonOpeningTime,
      WednesdayAfternoonClosingTime,
      ThursdayMorningOpeningTime,
      ThursdayMorningClosingTime,
      ThursdayAfternoonOpeningTime,
      ThursdayAfternoonClosingTime,
      FridayMorningOpeningTime,
      FridayMorningClosingTime,
      FridayAfternoonOpeningTime,
      FridayAfternoonClosingTime,
      SaturdayMorningOpeningTime,
      SaturdayMorningClosingTime,
      SaturdayAfternoonOpeningTime,
      SaturdayAfternoonClosingTime,
      SundayMorningOpeningTime,
      SundayMorningClosingTime,
      SundayAfternoonOpeningTime,
      SundayAfternoonClosingTime,
      MDChgProcSrceLastChgdDateTime,
      MDChgProcessSourceModified,
      MDChgProcessSourceModifBinary,
      cast(
        case
          when MDChgProcessSourceModified = '' then 'N'
          when MDChgProcessSourceModified = 'X' then 'M'
        else MDChgProcessSourceModified end as mdc_source_modified
      ) as MDChgProcKPIUpdateStatus,

      _Customer,
      _BusinessPartner,
      _RecordType,
      _RecordMessages,
      _KPIUpdateStatusText,
      _FactoryCalendar,
      _BPGoodsReceivingHour
}