I_BPContactWbsteURLTP

@AbapCatalog.sqlViewName: 'IBPCPWBSTEURLTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm : #SESSION_VARIABLE
@EndUserText.label: 'BO view for BP contact Website URL'

@Search.searchable: true
@VDM.viewType: #TRANSACTIONAL

@ObjectModel.writeEnabled: true
@ObjectModel.writeDraftPersistence: 'BPCP_WBSTE_D'

@ObjectModel.createEnabled
@ObjectModel.deleteEnabled
@ObjectModel.updateEnabled

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view I_BPContactWbsteURLTP as select from I_BpContactToAddress as ContactPerson
    inner join I_AddressHomepageURL as Website on  ContactPerson.AddressID    = Website.AddressID
                                               and ContactPerson.PersonNumber = Website.Person
                                                     
   association [1..1] to I_BusinessPartnerTP as _BusinessPartner on  $projection.BusinessPartner1 = _BusinessPartner.BusinessPartner
 
   association [1..1] to I_BPContactAddressTP as _BPContactAddress on  $projection.BusinessPartner1     = _BPContactAddress.BusinessPartner1
                                                                   and $projection.BusinessPartner2     = _BPContactAddress.BusinessPartner2
                                                                   and $projection.RelationshipNumber   = _BPContactAddress.RelationshipNumber
                                                                   and $projection.ValidityEndDate      = _BPContactAddress.ValidityEndDate
                                                                   and $projection.AddressID            = _BPContactAddress.AddressID                                                    
{
      @Search.defaultSearchElement: true
  key ContactPerson.BusinessPartnerCompany    as BusinessPartner1,
      @Search.defaultSearchElement: true
  key ContactPerson.BusinessPartnerPerson     as BusinessPartner2,
//  key _BusPartRelationship.RelationshipCategory,

  key ContactPerson.RelationshipNumber,
  key ContactPerson.ValidityEndDate,
  key ContactPerson.AddressID,
  key Website.OrdinalNumber,
  
   ContactPerson.BusinessPartnerCompany  as BusinessPartner1ForEdit,
   ContactPerson.BusinessPartnerPerson   as BusinessPartner2ForEdit,  
   ContactPerson.ValidityEndDate as ValidityEndDateForEdit,
   ContactPerson.AddressID as AddressIDForEdit,
   Website.OrdinalNumber as OrdinalNumberForEdit,
   ContactPerson.RelationshipNumber as RelationshipNumberForEdit,  
      
      Website.IsDefaultURLAddress,
      Website.CommNumberIsNotUsed,
      Website._AddressCommunicationRemark.AddressCommunicationRemarkText,
      Website.UniformResourceIdentifierType,
      cast(Website.URLFieldLength as abap.int4) as URLFieldLength,
      Website.WebsiteURL as CorporateWebsiteURL,

      /* Associations */
      _BusinessPartnerCompany   as _BusinessPartner1,
      _BusinessPartnerPerson    as _BusinessPartner2,
      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT ]
      _BusinessPartner,
      @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT ]
      _BPContactAddress
}