I_BOOSubOperationChangeState

@AbapCatalog.sqlViewName: 'IPPBOOSUBOPERCS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true 
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Analytics.dataCategory: #DIMENSION
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.representativeKey: 'BOOOpInternalVersionCounter'
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED}
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Bill of Operations Operation Change State'
// This view selects Sub-Operations only -> for Operations refer to I_BOOOperationChangeState


define view I_BOOSubOperationChangeState
  as select from I_BillOfOperationsOpBasic     as plpo
    inner join   I_BOOSqncOperationAssgmtChgSt as plas on  plas.BillOfOperationsType   =  plpo.BillOfOperationsType
                                                       and plas.BillOfOperationsGroup  =  plpo.BillOfOperationsGroup
                                                       and plas.BOOOperationInternalID =  plpo.SuperiorOperationInternalID
                                                       and plas.ValidityStartDate      <= plpo.ValidityEndDate
                                                       and plas.ValidityEndDate        >= plpo.ValidityStartDate

  association [1..1] to I_BillOfOperationsType        as _BillOfOperationsType        on  $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType

  association [1..1] to I_BillOfOperationsGroup       as _BillOfOperationsGroup       on  $projection.BillOfOperationsType  = _BillOfOperationsGroup.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup = _BillOfOperationsGroup.BillOfOperationsGroup

  association [1..1] to I_BillOfOperations            as _BillOfOperations            on  $projection.BillOfOperationsType    = _BillOfOperations.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup   = _BillOfOperations.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant = _BillOfOperations.BillOfOperationsVariant

  association [1..1] to I_BOOOperationInternalID      as _BOOOperationInternalID      on  $projection.BillOfOperationsType   = _BOOOperationInternalID.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup  = _BOOOperationInternalID.BillOfOperationsGroup
                                                                                      and $projection.BOOOperationInternalID = _BOOOperationInternalID.BOOOperationInternalID

  association [1..1] to I_BillOfOperationsSequence    as _BillOfOperationsSequence    on  $projection.BillOfOperationsType     = _BillOfOperationsSequence.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup    = _BillOfOperationsSequence.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant  = _BillOfOperationsSequence.BillOfOperationsVariant
                                                                                      and $projection.BillOfOperationsSequence = _BillOfOperationsSequence.BillOfOperationsSequence

  association [1..1] to I_BillOfOperationsOperation   as _BillOfOperationsOperation   on  $projection.BillOfOperationsType        = _BillOfOperationsOperation.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup       = _BillOfOperationsOperation.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant     = _BillOfOperationsOperation.BillOfOperationsVariant
                                                                                      and $projection.BillOfOperationsSequence    = _BillOfOperationsOperation.BillOfOperationsSequence
                                                                                      and $projection.SuperiorOperationInternalID = _BillOfOperationsOperation.BOOOperationInternalID

  association [1..1] to I_BOOSqncOperationAssgmtChgSt as _BOOSqncOperationAssgmtChgSt on  $projection.BillOfOperationsType          = _BOOSqncOperationAssgmtChgSt.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup         = _BOOSqncOperationAssgmtChgSt.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant       = _BOOSqncOperationAssgmtChgSt.BillOfOperationsVariant
                                                                                      and $projection.BillOfOperationsSequence      = _BOOSqncOperationAssgmtChgSt.BillOfOperationsSequence
                                                                                      and $projection.BOOOperationInternalID        = _BOOSqncOperationAssgmtChgSt.BOOOperationInternalID
                                                                                      and $projection.BOOSqncOpAssgmtIntVersionCntr = _BOOSqncOperationAssgmtChgSt.BOOSqncOpAssgmtIntVersionCntr

  association [0..1] to I_StandardWorkFormulaParameter as _StandardWorkFormulaParameter1 on  $projection.standardworkformulaparam1 = _StandardWorkFormulaParameter1.StandardWorkFormulaParameter
  association [0..1] to I_StandardWorkFormulaParameter as _StandardWorkFormulaParameter2 on  $projection.standardworkformulaparam2 = _StandardWorkFormulaParameter2.StandardWorkFormulaParameter
  association [0..1] to I_StandardWorkFormulaParameter as _StandardWorkFormulaParameter3 on  $projection.standardworkformulaparam3 = _StandardWorkFormulaParameter3.StandardWorkFormulaParameter
  association [0..1] to I_StandardWorkFormulaParameter as _StandardWorkFormulaParameter4 on  $projection.standardworkformulaparam4 = _StandardWorkFormulaParameter4.StandardWorkFormulaParameter
  association [0..1] to I_StandardWorkFormulaParameter as _StandardWorkFormulaParameter5 on  $projection.standardworkformulaparam5 = _StandardWorkFormulaParameter5.StandardWorkFormulaParameter
  association [0..1] to I_StandardWorkFormulaParameter as _StandardWorkFormulaParameter6 on  $projection.standardworkformulaparam6 = _StandardWorkFormulaParameter6.StandardWorkFormulaParameter

  // built up again because of different origin of field in selection list....

  association [1..1] to I_OperationControlProfile      as _OperationControlProfile       on  $projection.OperationControlProfile = _OperationControlProfile.OperationControlProfile
  association [0..1] to I_OperationStandardText        as _OperationStandardText         on  $projection.OperationStandardTextCode = _OperationStandardText.OperationStandardTextCode
  association [0..1] to I_EmployeeWageGroup            as _EmployeeWageGroup             on  $projection.EmployeeWageGroup = _EmployeeWageGroup.EmployeeWageGroup
                                                                                         and $projection.Plant             = _EmployeeWageGroup.Plant
  association [0..1] to I_EmployeeSuitability          as _EmployeeSuitability           on  $projection.EmployeeSuitability = _EmployeeSuitability.EmployeeSuitability
                                                                                         and $projection.Plant               = _EmployeeSuitability.Plant
  association [0..1] to I_OperationSetupType           as _OperationSetupType            on  $projection.OperationSetupType = _OperationSetupType.OperationSetupType
                                                                                         and $projection.Plant              = _OperationSetupType.Plant
{
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key plpo.BillOfOperationsType,

      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
  key plpo.BillOfOperationsGroup,

      @ObjectModel.foreignKey.association: '_BillOfOperations'
  key plas.BillOfOperationsVariant,

      @ObjectModel.foreignKey.association: '_BillOfOperationsSequence'
  key plas.BillOfOperationsSequence,

      @ObjectModel.foreignKey.association: '_BOOOperationInternalID'
  key plpo.BOOOperationInternalID,

      @ObjectModel.foreignKey.association: '_BOOSqncOperationAssgmtChgSt'
  key plas.BOOSqncOpAssgmtIntVersionCntr,

      @ObjectModel.text.element: ['SubOperationText']
  key plpo.BOOOpInternalVersionCounter,

      plpo.BillOfOperationsVersion, // NOT a key field in THIS view !


      // ***************** Work Center *****************


      plpo.WorkCenterInternalID,
      plpo.WorkCenterTypeCode,

      // ***************** Indicators *****************


      case plpo.IsDeleted
        when ' ' then plas.IsDeleted
        else          plpo.IsDeleted 
      end as IsDeleted,
      case plpo.IsImplicitlyDeleted
        when ' ' then plas.IsImplicitlyDeleted
      else            plpo.IsImplicitlyDeleted
      end as IsImplicitlyDeleted,

      // ************************** Operation Header ***************************


--    plpo.OperationExternalID                          as SubOperationExternalID,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'SubOperation_2'
      cast(plpo.Operation   as pph_uvorn preserving type) as SubOperation,
      cast(plpo.Operation_2 as vdm_uvorn preserving type) as SubOperation_2,
      
      plpo.SuperiorOperationInternalID,
--    cast(sup.Operation as pph_vornr preserving type) as SuperiorOperation,

      // ************************** Operation General **************************


      -- Operation
      plpo.OperationText                                as SubOperationText,

      plpo.LongTextLanguageCode,

      plpo.Plant,

      case plpo._WorkCenter.OpControlProfileIsReferenced
        when 'X' then plpo._WorkCenter.OperationControlProfile
        else plpo.OperationControlProfile
      end                                               as OperationControlProfile,

      case plpo._WorkCenter.StandardTextIDIsReferenced
      when 'X' then plpo._WorkCenter.StandardTextInternalID
      else plpo.OperationStandardTextCode
      end                                               as OperationStandardTextCode,

      plpo.FactoryCalendar,

      -- Origin
      plpo.BillOfOperationsRefType,
      plpo.BillOfOperationsRefGroup,
      plpo.BillOfOperationsRefVariant,

      cast(plpo.CapacityCategoryCode as pph_kapart preserving type) as CapacityCategoryCode,

      -- Transfer to Orders     (-> Suboperations)
      plpo.OperationStdWorkQtyGrpgCat,

      // *************************** Administration ****************************


      -- Administrative Data
      plpo.CreationDate,
      plpo.CreatedByUser,

      plpo.LastChangeDate,
      plpo.LastChangedByUser,

      -- Validity
      plpo.ChangeNumber,

      cast(case when plpo.ValidityStartDate > plas.ValidityStartDate 
        then plpo.ValidityStartDate
        else plas.ValidityStartDate
      end as pph_begda preserving type) as ValidityStartDate,
      cast(case when plpo.ValidityEndDate < plas.ValidityEndDate 
        then plpo.ValidityEndDate
        else plas.ValidityEndDate
      end as pph_endda preserving type) as ValidityEndDate,

      // ************************** Processing Times ***************************


      -- Standard Values
      @Semantics.quantity.unitOfMeasure: 'OperationUnit' 
      @DefaultAggregation: #SUM
      plpo.OperationReferenceQuantity,
      @Semantics.unitOfMeasure: true
      plpo.OperationUnit,

      plpo.OpQtyToBaseQtyNmrtr,
      plpo.OpQtyToBaseQtyDnmntr,

      plpo.BillOfOperationsBreakDuration,
      @Semantics.unitOfMeasure: true
      plpo.BillOfOperationsBreakDurnUnit,

      plpo._WorkCenter._StandardWorkFmlaParamGroup.StandardWorkFormulaParam1,
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit1'
      @DefaultAggregation: #SUM
      plpo.StandardWorkQuantity1,
      @Semantics.unitOfMeasure: true
      plpo.StandardWorkQuantityUnit1,
      plpo.CostCtrActivityType1,
      plpo.PerfEfficiencyRatioCode1,

      plpo._WorkCenter._StandardWorkFmlaParamGroup.StandardWorkFormulaParam2,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit2'
      plpo.StandardWorkQuantity2,
      @Semantics.unitOfMeasure: true
      plpo.StandardWorkQuantityUnit2,
      plpo.CostCtrActivityType2,
      plpo.PerfEfficiencyRatioCode2,

      plpo._WorkCenter._StandardWorkFmlaParamGroup.StandardWorkFormulaParam3,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit3'
      plpo.StandardWorkQuantity3,
      @Semantics.unitOfMeasure: true
      plpo.StandardWorkQuantityUnit3,
      plpo.CostCtrActivityType3,
      plpo.PerfEfficiencyRatioCode3,

      plpo._WorkCenter._StandardWorkFmlaParamGroup.StandardWorkFormulaParam4,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit4'
      plpo.StandardWorkQuantity4,
      @Semantics.unitOfMeasure: true
      plpo.StandardWorkQuantityUnit4,
      plpo.CostCtrActivityType4,
      plpo.PerfEfficiencyRatioCode4,

      plpo._WorkCenter._StandardWorkFmlaParamGroup.StandardWorkFormulaParam5,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit5'
      plpo.StandardWorkQuantity5,
      @Semantics.unitOfMeasure: true
      plpo.StandardWorkQuantityUnit5,
      plpo.CostCtrActivityType5,
      plpo.PerfEfficiencyRatioCode5,

      plpo._WorkCenter._StandardWorkFmlaParamGroup.StandardWorkFormulaParam6,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit6'
      plpo.StandardWorkQuantity6,
      @Semantics.unitOfMeasure: true
      plpo.StandardWorkQuantityUnit6,
      plpo.CostCtrActivityType6,
      plpo.PerfEfficiencyRatioCode6,

      plpo.BusinessProcess,

      // ************************ Interoperation Times *************************


      -- Lead Time Reduction
      plpo.LeadTimeReductionStrategy,
      
      --- Offset (for sub-operations)
      plpo.StartDateOffsetDurationUnit,
      plpo.StartDateOffsetDuration,

      plpo.EndDateOffsetDurationUnit,
      plpo.EndDateOffsetDuration,

      // ********************* Additional Operation Data ***********************


      --- General Data
      plpo.OperationScrapPercent,

      case plpo._WorkCenter.NmbrOfTimeTicketsIsReferenced
        when 'X' then plpo._WorkCenter.NumberOfTimeTickets
        else plpo.NumberOfTimeTickets
      end                               as NumberOfTimeTickets,
      case plpo._WorkCenter.NumberOfConfSlipsIsReferenced
      when 'X' then plpo._WorkCenter.NumberOfConfirmationSlips
      else plpo.NumberOfConfirmationSlips
      end                               as NumberOfConfirmationSlips,

      cast(case plpo._WorkCenter.EmployeeWageGroupIsReferenced
        when 'X' then plpo._WorkCenter.EmployeeWageGroup
        else plpo.EmployeeWageGroup
      end as pph_logrp preserving type) as EmployeeWageGroup,
      cast(case plpo._WorkCenter.EmployeeWageTypeIsReferenced
        when 'X' then plpo._WorkCenter.EmployeeWageType
        else plpo.EmployeeWageType
      end as pph_loart preserving type) as EmployeeWageType,
      case plpo._WorkCenter.EmplSuitabilityIsReferenced
        when 'X' then plpo._WorkCenter.EmployeeSuitability
        else plpo.EmployeeSuitability
      end                               as EmployeeSuitability,
      plpo.NumberOfEmployees,

      -- Setup
      case plpo._WorkCenter.WorkCenterSetpTypeIsReferenced
        when 'X' then plpo._WorkCenter.WorkCenterSetupType
        else plpo.OperationSetupType 
      end                               as OperationSetupType,
      plpo.OperationSetupGroupCategory,
      plpo.OperationSetupGroup,

      // ************************* Process Control Data ************************


      plpo.ControlRecipeDestination,

      // ************************ External Processing **************************


      -- External Processing
      plpo.OpIsExtlyProcdWithSubcontrg,

      plpo.PurchasingInfoRecord,

      plpo.PurchasingOrganization,

      plpo.PurchaseContract,
      plpo.PurchaseContractItem,

      plpo.PurchasingInfoRecdAddlGrpgName,

      plpo.MaterialGroup,

      plpo.PurchasingGroup,

      plpo.Supplier,

      plpo.PlannedDeliveryDuration,

      plpo.NumberOfOperationPriceUnits,
      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'OpExternalProcessingCurrency'
      plpo.OpExternalProcessingPrice,
      @Semantics.currencyCode: true    
      plpo.OpExternalProcessingCurrency,

      plpo.InspectionLotType,

      plpo.CostElement,

      plpo.OperationCostingRelevancyType,   

      // **************************** Associations *****************************


      _BOOOperationInternalID,
      _BOOSqncOperationAssgmtChgSt,
      _BillOfOperations,
      _BillOfOperationsGroup,
      _BillOfOperationsOperation,
      _BillOfOperationsSequence,
      _BillOfOperationsType,
      plpo._BillOfOperationsBreakDurnUnit,
      plpo._CapacityCategory,
      plpo._ChangeMaster,
      plpo._ControlRecipeDestination,
      _EmployeeSuitability,
      _EmployeeWageGroup,
      plpo._EndDateOffsetDurnUnit,
      plpo._FactoryCalendar,
      plpo._InspectionLotType,
      plpo._LeadTimeReductionStrategy,
      plpo._LongTextLanguage,
      plpo._MaterialGroup,
      _OperationControlProfile,
      plpo._OperationSetupGroup,
      plpo._OperationSetupGroupCategory,
      _OperationSetupType,
      _OperationStandardText,
      plpo._OperationStdWorkQtyGrpgCat,
      plpo._OperationUnit,
      plpo._OpExternalProcessingCurrency,
      plpo._PerformanceEfficiencyRatio1,
      plpo._PerformanceEfficiencyRatio2,
      plpo._PerformanceEfficiencyRatio3,
      plpo._PerformanceEfficiencyRatio4,
      plpo._PerformanceEfficiencyRatio5,
      plpo._PerformanceEfficiencyRatio6,
      plpo._Plant,
      plpo._PurchaseContract,
      plpo._PurchaseContractItem,
      plpo._PurchasingGroup,
      plpo._PurchasingInfoRecord,
      plpo._PurchasingOrganization,
      _StandardWorkFormulaParameter1,
      _StandardWorkFormulaParameter2,
      _StandardWorkFormulaParameter3,
      _StandardWorkFormulaParameter4,
      _StandardWorkFormulaParameter5,
      _StandardWorkFormulaParameter6,
      plpo._StandardWorkQuantityUnit1,
      plpo._StandardWorkQuantityUnit2,
      plpo._StandardWorkQuantityUnit3,
      plpo._StandardWorkQuantityUnit4,
      plpo._StandardWorkQuantityUnit5,
      plpo._StandardWorkQuantityUnit6,
      plpo._StartDateOffsetDurnUnit,
      plpo._Supplier,
      plpo._WorkCenter,
      plpo._WorkCenterType
}
where
  plpo.SuperiorOperationInternalID > '00000000';