I_BOOPlngBOMAssignment

DDL: I_BOOPLNGBOMASSIGNMENT SQL: ICHGIMPLNGROUMBM Type: view BASIC Package: MPE_PLAN_CIMA

PBOM assigned to Planning Routing

I_BOOPlngBOMAssignment is a Basic CDS View that provides data about "PBOM assigned to Planning Routing" in SAP S/4HANA. It reads from 4 data sources (stko, I_BOOMaterialAssgmtChangeState, mast, I_ProdnBOMChgImpactObjMappg) and exposes 19 fields with key fields BillOfOperationsType, BillOfOperationsGroup, BillOfOperationsVariant, BOOToMaterialInternalID, BOOMatlInternalVersionCounter. Part of development package MPE_PLAN_CIMA.

4 data source(s) 19 fields

Data Sources (4)

SourceAliasJoin Type
stko BOMHeader inner
I_BOOMaterialAssgmtChangeState BOP_TO_MatAssgmnt from
mast MaterialToBOM inner
I_ProdnBOMChgImpactObjMappg ProdBOMUsage inner

Annotations (10)

NameValueLevelField
AbapCatalog.sqlViewName ICHGIMPLNGROUMBM view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #CHECK view
ClientHandling.algorithm #SESSION_VARIABLE view
VDM.viewType #BASIC view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #MIXED view
EndUserText.label PBOM assigned to Planning Routing view

Fields (19)

KeyFieldSource TableSource FieldDescription
KEY BillOfOperationsType I_BOOMaterialAssgmtChangeState BillOfOperationsType
KEY BillOfOperationsGroup I_BOOMaterialAssgmtChangeState BillOfOperationsGroup
KEY BillOfOperationsVariant I_BOOMaterialAssgmtChangeState BillOfOperationsVariant
KEY BOOToMaterialInternalID I_BOOMaterialAssgmtChangeState BOOToMaterialInternalID
KEY BOOMatlInternalVersionCounter I_BOOMaterialAssgmtChangeState BOOMatlInternalVersionCounter
KEY BillOfMaterial
KEY BillOfMaterialVariant mast stlal
KEY Plant I_BOOMaterialAssgmtChangeState Plant
Material I_BOOMaterialAssgmtChangeState Material
ChangeNumber I_BOOMaterialAssgmtChangeState ChangeNumber
IsDeleted I_BOOMaterialAssgmtChangeState IsDeleted
ValidityStartDate I_BOOMaterialAssgmtChangeState ValidityStartDate
ValidityEndDate I_BOOMaterialAssgmtChangeState ValidityEndDate
BillOfMaterialVariantUsage mast stlan
ProdnRlvnce I_ProdnBOMChgImpactObjMappg ProdnRlvnce
BillOfMaterialVersion stko bom_versn
BOMVersionStatus stko versnst
BillOfMaterialStatus stko stlst
BillOfMaterialCategory stko stlty 
@AbapCatalog.sqlViewName: 'ICHGIMPLNGROUMBM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED}
@EndUserText.label: 'PBOM assigned to Planning Routing'
define view I_BOOPlngBOMAssignment
  as select from I_BOOMaterialAssgmtChangeState as BOP_TO_MatAssgmnt
    inner join   mast                           as MaterialToBOM on  MaterialToBOM.matnr = BOP_TO_MatAssgmnt.Material
                                                                 and MaterialToBOM.werks = BOP_TO_MatAssgmnt.Plant

    inner join   stko                           as BOMHeader     on  BOMHeader.stlnr = MaterialToBOM.stlnr
                                                                 and BOMHeader.stlal = MaterialToBOM.stlal
                                                                 and BOMHeader.stlty = 'M'

    inner join   I_ProdnBOMChgImpactObjMappg    as ProdBOMUsage  on  ProdBOMUsage.BillOfMaterialVariantUsage = MaterialToBOM.stlan
                                                                 and ProdBOMUsage.ProdnRlvnce                = 'P'

{

       /*I_BOOMaterialAssgmtChangeState Fields*/
  key  BOP_TO_MatAssgmnt.BillOfOperationsType              as BillOfOperationsType,
  key  BOP_TO_MatAssgmnt.BillOfOperationsGroup             as BillOfOperationsGroup,
  key  BOP_TO_MatAssgmnt.BillOfOperationsVariant           as BillOfOperationsVariant,
  key  BOP_TO_MatAssgmnt.BOOToMaterialInternalID           as BOOToMaterialInternalID,
  key  BOP_TO_MatAssgmnt.BOOMatlInternalVersionCounter     as BOOMatlInternalVersionCounter,
  key  cast( MaterialToBOM.stlnr as char8 preserving type) as BillOfMaterial,
  key  MaterialToBOM.stlal                                 as BillOfMaterialVariant,
  key  BOP_TO_MatAssgmnt.Plant                             as Plant,


       BOP_TO_MatAssgmnt.Material,
       BOP_TO_MatAssgmnt.ChangeNumber,
       BOP_TO_MatAssgmnt.IsDeleted,
       BOP_TO_MatAssgmnt.ValidityStartDate,
       BOP_TO_MatAssgmnt.ValidityEndDate,


       /*MAST Table fields - Material to BOM Linkage fields*/
       MaterialToBOM.stlan                                 as BillOfMaterialVariantUsage,
       ProdBOMUsage.ProdnRlvnce                            as ProdnRlvnce,

       /*STKO fields - BOM Header Fields*/
       BOMHeader.bom_versn                                 as BillOfMaterialVersion,
       BOMHeader.versnst                                   as BOMVersionStatus,
       BOMHeader.stlst                                     as BillOfMaterialStatus,
       BOMHeader.stlty                                     as BillOfMaterialCategory


}
//group by Material

where
  BOP_TO_MatAssgmnt.BillOfOperationsType = 'P';

Learn More