I_BOOOperationChangeState

@AbapCatalog.sqlViewName: 'IPPBOOOPERCS'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@Analytics.dataCategory: #DIMENSION
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions:true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.representativeKey: 'BOOOpInternalVersionCounter'
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED}
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Bill of Operations Operation Change State'
// This view selects Operations only -> for suboperations refer to I_BOOSubOperationChangeState


define view I_BOOOperationChangeState
  as select from P_BOOOperationChangeState

  association [1..1] to I_BillOfOperationsType        as _BillOfOperationsType        on  $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType

  association [1..1] to I_BillOfOperationsGroup       as _BillOfOperationsGroup       on  $projection.BillOfOperationsType  = _BillOfOperationsGroup.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup = _BillOfOperationsGroup.BillOfOperationsGroup

  association [1..1] to I_BillOfOperations            as _BillOfOperations            on  $projection.BillOfOperationsType    = _BillOfOperations.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup   = _BillOfOperations.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant = _BillOfOperations.BillOfOperationsVariant

  association [1..1] to I_BOOOperationInternalID      as _BOOOperationInternalID      on  $projection.BillOfOperationsType   = _BOOOperationInternalID.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup  = _BOOOperationInternalID.BillOfOperationsGroup
                                                                                      and $projection.BOOOperationInternalID = _BOOOperationInternalID.BOOOperationInternalID

  association [1..1] to I_BillOfOperationsSequence    as _BillOfOperationsSequence    on  $projection.BillOfOperationsType     = _BillOfOperationsSequence.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup    = _BillOfOperationsSequence.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant  = _BillOfOperationsSequence.BillOfOperationsVariant
                                                                                      and $projection.BillOfOperationsSequence = _BillOfOperationsSequence.BillOfOperationsSequence

  association [1..1] to I_BOOSqncOperationAssgmtChgSt as _BOOSqncOperationAssgmtChgSt on  $projection.BillOfOperationsType          = _BOOSqncOperationAssgmtChgSt.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup         = _BOOSqncOperationAssgmtChgSt.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant       = _BOOSqncOperationAssgmtChgSt.BillOfOperationsVariant
                                                                                      and $projection.BillOfOperationsSequence      = _BOOSqncOperationAssgmtChgSt.BillOfOperationsSequence
                                                                                      and $projection.BOOOperationInternalID        = _BOOSqncOperationAssgmtChgSt.BOOOperationInternalID
                                                                                      and $projection.BOOSqncOpAssgmtIntVersionCntr = _BOOSqncOperationAssgmtChgSt.BOOSqncOpAssgmtIntVersionCntr

{
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key BillOfOperationsType,

      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
  key BillOfOperationsGroup,

      @ObjectModel.foreignKey.association: '_BillOfOperations'
  key BillOfOperationsVariant,

      @ObjectModel.foreignKey.association: '_BillOfOperationsSequence'
  key BillOfOperationsSequence,

      @ObjectModel.foreignKey.association: '_BOOOperationInternalID'
  key BOOOperationInternalID,

      @ObjectModel.foreignKey.association: '_BOOSqncOperationAssgmtChgSt'
  key BOOSqncOpAssgmtIntVersionCntr,

      @ObjectModel.text.element: ['OperationText']
  key BOOOpInternalVersionCounter,

      BillOfOperationsVersion, // NOT a key field in THIS view !


      // ***************** Technical fields not on the CEWB-UI *****************


      WorkCenterInternalID,
      WorkCenterTypeCode,

      IsDeleted,
      IsImplicitlyDeleted,

      // ************************** Operation Header ***************************


      OperationExternalID,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'Operation_2'
      Operation,         // with conv. exit NUMCV

      Operation_2,       // w/o conversion exit


      // ************************** Operation General **************************


      -- Operation
      OperationText,

      LongTextLanguageCode,

      Plant,

      OperationControlProfile,

      OperationStandardTextCode,
      
      FactoryCalendar,

      -- Origin
      BillOfOperationsRefType,
      BillOfOperationsRefGroup,
      BillOfOperationsRefVariant,

      -- Production Line
      LineSegmentTakt,

      -- Transfer to Orders     (-> Suboperations)
      OperationStdWorkQtyGrpgCat,

      OrderHasNoSubOperations,

      // ************************** Processing Times ***************************


      -- Standard Values
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      @Aggregation.default: #SUM
      OperationReferenceQuantity,
      @Semantics.unitOfMeasure: true
      OperationUnit,

      OpQtyToBaseQtyNmrtr,
      OpQtyToBaseQtyDnmntr,

      BillOfOperationsBreakDuration,
      @Semantics.unitOfMeasure: true
      BillOfOperationsBreakDurnUnit,

      StandardWorkFormulaParam1,
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit1'
      @Aggregation.default: #SUM
      StandardWorkQuantity1,
      @Semantics.unitOfMeasure: true
      StandardWorkQuantityUnit1,
      CostCtrActivityType1,
      PerfEfficiencyRatioCode1,

      StandardWorkFormulaParam2,
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit2'
      @Aggregation.default: #SUM
      StandardWorkQuantity2,
      @Semantics.unitOfMeasure: true
      StandardWorkQuantityUnit2,
      CostCtrActivityType2,
      PerfEfficiencyRatioCode2,

      StandardWorkFormulaParam3,
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit3'
      @Aggregation.default: #SUM
      StandardWorkQuantity3,
      @Semantics.unitOfMeasure: true
      StandardWorkQuantityUnit3,
      CostCtrActivityType3,
      PerfEfficiencyRatioCode3,

      StandardWorkFormulaParam4,
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit4'
      @Aggregation.default: #SUM
      StandardWorkQuantity4,
      @Semantics.unitOfMeasure: true
      StandardWorkQuantityUnit4,
      CostCtrActivityType4,
      PerfEfficiencyRatioCode4,

      StandardWorkFormulaParam5,
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit5'
      @Aggregation.default: #SUM
      StandardWorkQuantity5,
      @Semantics.unitOfMeasure: true
      StandardWorkQuantityUnit5,
      CostCtrActivityType5,
      PerfEfficiencyRatioCode5,

      StandardWorkFormulaParam6,
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit6'
      @Aggregation.default: #SUM
      StandardWorkQuantity6,
      @Semantics.unitOfMeasure: true
      StandardWorkQuantityUnit6,
      CostCtrActivityType6,
      PerfEfficiencyRatioCode6,

      BusinessProcess,

      // ************************ Interoperation Times *************************


      -- Interoperation Times
      LeadTimeReductionStrategy,

      TeardownAndWaitIsParallel,

      MaximumWaitDuration,
      @Semantics.unitOfMeasure: true
      MaximumWaitDurationUnit,

      MinimumWaitDuration,
      @Semantics.unitOfMeasure: true
      MinimumWaitDurationUnit,

      StandardQueueDuration,
      @Semantics.unitOfMeasure: true
      StandardQueueDurationUnit,

      MinimumQueueDuration,
      @Semantics.unitOfMeasure: true
      MinimumQueueDurationUnit,

      StandardMoveDuration,
      @Semantics.unitOfMeasure: true
      StandardMoveDurationUnit,

      MinimumMoveDuration,
      @Semantics.unitOfMeasure: true
      MinimumMoveDurationUnit,

      // **************************** Control Data *****************************


      --- Splitting
      OperationSplitIsRequired,

      MaximumNumberOfSplits,

      MinProcessingDurationPerSplit,
      @Semantics.unitOfMeasure: true
      MinProcessingDurnPerSplitUnit,

      --- Overlapping
      OperationOverlappingIsRequired,
      OperationOverlappingIsPossible,
      OperationsIsAlwaysOverlapping,

      OverlapMinimumDuration,
      @Semantics.unitOfMeasure: true
      OverlapMinimumDurationUnit,

      @Semantics.quantity.unitOfMeasure: 'OverlapMinimumTransferQtyUnit'
      @Aggregation.default: #SUM
      OverlapMinimumTransferQty,
      @Semantics.unitOfMeasure: true
      OverlapMinimumTransferQtyUnit,

      // ********************* Additional Operation Data ***********************


      --- General Data
      OperationScrapPercent,

      NumberOfTimeTickets,
      NumberOfConfirmationSlips,

      EmployeeWageGroup,
      EmployeeWageType,

      EmployeeSuitability,

      NumberOfEmployees,

      -- Setup
      OperationSetupType,

      OperationSetupGroupCategory,
      OperationSetupGroup,

      OperationCostingRelevancyType,

      IsNonValueAddedOperation, //visible only in CA02


      // ************************ External Processing **************************


      -- External Processing
      OpIsExtlyProcdWithSubcontrg,

      PurchasingInfoRecord,

      PurchasingOrganization,

      PurchaseContract,
      PurchaseContractItem,

      PurchasingInfoRecdAddlGrpgName,

      MaterialGroup,

      PurchasingGroup,

      Supplier,

      PlannedDeliveryDuration,

      NumberOfOperationPriceUnits,

      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'OpExternalProcessingCurrency'
      OpExternalProcessingPrice,

      @Semantics.currencyCode: true
      OpExternalProcessingCurrency,

      InspectionLotType,

      CostElement,
      
      CompanyCode,


      // ************************* Process Control Data ************************


      BOOOperationIsPhase,
      BOOPhaseSuperiorOpInternalID,

      ControlRecipeDestination,

      // ************************* Qualification Data **************************


      CapacityCategoryCode,

      // ************************* Quality Management **************************


      -- Quality management: general
      InspResultRecordingView,

      -- Quality management: inspection points
      InspSbstCompletionConfirmation,
      InspSbstHasNoTimeOrQuantity,

      // ***************************** User Fields *****************************


      FreeDefinedTableFieldSemantic,
      FreeDefinedAttribute01,
      FreeDefinedAttribute02,
      FreeDefinedAttribute03,
      FreeDefinedAttribute04,
      @Aggregation.default: #SUM
      @Semantics.quantity.unitOfMeasure: 'FreeDefinedQuantity1Unit'
      FreeDefinedQuantity1,
      @Semantics.unitOfMeasure: true
      FreeDefinedQuantity1Unit,
      @Aggregation.default: #SUM
      @Semantics.quantity.unitOfMeasure: 'FreeDefinedQuantity2Unit'
      FreeDefinedQuantity2,
      @Semantics.unitOfMeasure: true
      FreeDefinedQuantity2Unit,
      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'FreeDefinedAmount1Currency'
      FreeDefinedAmount1,
      @Semantics.currencyCode: true
      FreeDefinedAmount1Currency,
      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'FreeDefinedAmount2Currency'
      FreeDefinedAmount2,
      @Semantics.currencyCode: true
      FreeDefinedAmount2Currency,
      FreeDefinedDate1,
      FreeDefinedDate2,
      FreeDefinedIndicator1,
      FreeDefinedIndicator2,

      // *************************** Administration ****************************


      -- Administrative Data
      CreationDate,
      CreatedByUser,

      LastChangeDate,
      LastChangedByUser,

      -- Validity
      ChangeNumber,

      ValidityStartDate,
      ValidityEndDate,

      // **************************** Associations *****************************


      _BOOOperationInternalID,
      _BOOSqncOperationAssgmtChgSt,
      _BillOfOperations,
      _BillOfOperationsBreakDurnUnit,
      _BillOfOperationsGroup,
      _BillOfOperationsSequence,
      _BillOfOperationsType,
      _CapacityCategory,
      _ChangeMaster,
      _ControlRecipeDestination,
      _EmployeeSuitability,
      _EmployeeWageGroup,
      _FactoryCalendar,
      _FreeDefinedAmount1Currency,
      _FreeDefinedAmount2Currency,
      _FreeDfndTableFieldSemantic,
      _InspResultRecordingView,
      _InspectionLotType,
      _LeadTimeReductionStrategy,
      _LongTextLanguage,
      _MaterialGroup,
      _MaximumWaitDurationUnit,
      _MinProcessingDurnPerSplitUnit,
      _MinimumMoveDurationUnit,
      _MinimumQueueDurationUnit,
      _MinimumWaitDurationUnit,
      _OpExternalProcessingCurrency,
      _OperationControlProfile,
      _OperationSetupGroup,
      _OperationSetupGroupCategory,
      _OperationSetupType,
      _OperationStandardText,
      _OperationStdWorkQtyGrpgCat,
      _OperationUnit,
      _OverlapMinimumDurationUnit,
      _OverlapMinimumTransferQtyUnit,
      _PerformanceEfficiencyRatio1,
      _PerformanceEfficiencyRatio2,
      _PerformanceEfficiencyRatio3,
      _PerformanceEfficiencyRatio4,
      _PerformanceEfficiencyRatio5,
      _PerformanceEfficiencyRatio6,
      _Plant,
      _PurchaseContract,
      _PurchaseContractItem,
      _PurchasingGroup,
      _PurchasingInfoRecord,
      _PurchasingOrganization,
      _StandardMoveDurationUnit,
      _StandardQueueDurationUnit,
      _StandardWorkFormulaParameter1,
      _StandardWorkFormulaParameter2,
      _StandardWorkFormulaParameter3,
      _StandardWorkFormulaParameter4,
      _StandardWorkFormulaParameter5,
      _StandardWorkFormulaParameter6,
      _StandardWorkQuantityUnit1,
      _StandardWorkQuantityUnit2,
      _StandardWorkQuantityUnit3,
      _StandardWorkQuantityUnit4,
      _StandardWorkQuantityUnit5,
      _StandardWorkQuantityUnit6,
      _Supplier,
      _WorkCenter,
      _WorkCenterType
};