I_BOOMaterialAssignment

@AbapCatalog.sqlViewName: 'IBOOMATASSIGN'
@AccessControl.authorizationCheck: #MANDATORY
@VDM.viewType: #BASIC
@Analytics.dataCategory: #DIMENSION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'BOOToMaterialInternalID'
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Material assgmt to Bill of Operations'
@ObjectModel.usageType: { serviceQuality: #A, sizeCategory: #M, dataClass: #MASTER }
@Search.searchable: true
@Metadata.allowExtensions:true
//@AbapCatalog.preserveKey:true

@ObjectModel.supportedCapabilities:[#ANALYTICAL_DIMENSION,#CDS_MODELING_ASSOCIATION_TARGET]
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION

/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ] }*/
define view I_BOOMaterialAssignment
  as select distinct from mapl

  association [1..1] to I_BillOfOperationsType  as _BillOfOperationsType  on  $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType
  association [1..1] to I_BillOfOperationsGroup as _BillOfOperationsGroup on  $projection.BillOfOperationsType  = _BillOfOperationsGroup.BillOfOperationsType
                                                                          and $projection.BillOfOperationsGroup = _BillOfOperationsGroup.BillOfOperationsGroup
  association [1..1] to I_BillOfOperations      as _BillOfOperations      on  $projection.BillOfOperationsType    = _BillOfOperations.BillOfOperationsType
                                                                          and $projection.BillOfOperationsGroup   = _BillOfOperations.BillOfOperationsGroup
                                                                          and $projection.BillOfOperationsVariant = _BillOfOperations.BillOfOperationsVariant
  association [1..1] to I_Plant                 as _Plant                 on  $projection.Plant = _Plant.Plant
  association [1..1] to I_Material              as _Material              on  $projection.Material = _Material.Material
  association [1..1] to I_Product               as _Product               on  $projection.Material = _Product.Product

{
      //@Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]

      @ObjectModel.foreignKey.association: '_Product'
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
  key mapl.matnr as Material,
      @ObjectModel.foreignKey.association: '_Plant'
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
  key mapl.werks as Plant,
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key mapl.plnty as BillOfOperationsType,

      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
  key mapl.plnnr as BillOfOperationsGroup,
      //@Consumption.valueHelpDefinition: [ { entity: { name: 'I_BillOfOperationsStdVH', element: 'BillOfOperationsVariant' } } ]

      @ObjectModel.foreignKey.association: '_BillOfOperations'
  key mapl.plnal as BillOfOperationsVariant,
  key mapl.zkriz as BOOToMaterialInternalID,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor:    '_Product'
      _Material,
      _Product,
      _Plant,
      _BillOfOperationsType,
      _BillOfOperationsGroup,
      // !! DO NOT USE @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT ]

      _BillOfOperations
}