I_AstAcqnAndRtrmtOverview

DDL: I_ASTACQNANDRTRMTOVERVIEW SQL: IASTACQRETOV Type: view COMPOSITE Package: ODATA_AA_ASSET_OVERVIEWPAGE

Asset Acquisitions and Retirements Overview

I_AstAcqnAndRtrmtOverview is a Composite CDS View that provides data about "Asset Acquisitions and Retirements Overview" in SAP S/4HANA. It reads from 1 data source (I_FixedAssetTransaction) and exposes 37 fields with key fields CompanyCode, AssetDepreciationArea, MasterFixedAsset, FixedAsset, Ledger. It has 1 association to related views. Part of development package ODATA_AA_ASSET_OVERVIEWPAGE.

1 data source(s) 37 fields

Data Sources (1)

SourceAliasJoin Type
I_FixedAssetTransaction I_FixedAssetTransaction from

Parameters (2)

NameTypeDefault
P_KeyDate fagl_keydate
P_AssetAccountingKeyFigureSet faa_key_figure_set

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_FixedAssetForLedger _FixedAssetForLedger _FixedAssetForLedger.CompanyCode = $projection.CompanyCode and _FixedAssetForLedger.MasterFixedAsset = $projection.MasterFixedAsset and _FixedAssetForLedger.FixedAsset = $projection.FixedAsset and _FixedAssetForLedger.Ledger = $projection.Ledger

Annotations (10)

NameValueLevelField
AbapCatalog.sqlViewName IASTACQRETOV view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #REQUIRED view
ClientHandling.algorithm #SESSION_VARIABLE view
EndUserText.label Asset Acquisitions and Retirements Overview view
ObjectModel.usageType.sizeCategory #XXL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.dataClass #MIXED view
VDM.viewType #COMPOSITE view

Fields (37)

KeyFieldSource TableSource FieldDescription
KEY CompanyCode CompanyCode
KEY AssetDepreciationArea AssetDepreciationArea
KEY MasterFixedAsset MasterFixedAsset
KEY FixedAsset FixedAsset
KEY Ledger Ledger
KEY LedgerFiscalYear LedgerFiscalYear
KEY FiscalYear FiscalYear
KEY FiscalPeriod FiscalPeriod
KEY SubLedgerAcctLineItemType SubLedgerAcctLineItemType
KEY AssetAcctTransClassfctn AssetAcctTransClassfctn
KEY AssetAccountingKeyFigure AssetAccountingKeyFigure
KEY AssetAccountingKeyFigureSet AssetAccountingKeyFigureSet
KEY AccountingDocument AccountingDocument
KEY TransactionSubitem TransactionSubitem
KEY DebitCreditCode DebitCreditCode
KEY CurrencyRole CurrencyRole
PostingDate PostingDate
AssetClass AssetClass
AssetAccountDetermination AssetAccountDetermination
AssetCapitalizationDate _FixedAssetForLedger AssetCapitalizationDate
AssetDeactivationDate _FixedAssetForLedger AssetDeactivationDate
AssetCountryOfOrigin
AssetSupplier _FixedAsset Supplier
SupplierAccountGroup
SupplierBasicAuthorizationGrp
AssetCostCenter AssetCostCenter
AssetPlant AssetPlant
AssetProfitCenter AssetProfitCenter
AssetSegment AssetSegment
CompanyCodeName CompanyCodeName
FixedAssetDescription FixedAssetDescription
SelectedCurrencyBranch SelectedCurrencyBranch
DisplayCurrency DisplayCurrency
AcqnProdnAmtInDspCrcy AcqnProdnAmtInDspCrcy
RtrmtNetBookValueAmtInDspCrcy RtrmtNetBookValueAmtInDspCrcy
_FixedAsset _FixedAsset
_AssetClassText _AssetClassText 
@AbapCatalog.sqlViewName: 'IASTACQRETOV'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Asset Acquisitions and Retirements Overview'
@ObjectModel.usageType: {
  sizeCategory: #XXL,
  serviceQuality: #C,
  dataClass: #MIXED
}
@VDM.viewType: #COMPOSITE
define view I_AstAcqnAndRtrmtOverview
  with parameters
    P_KeyDate                     : fagl_keydate,
    P_AssetAccountingKeyFigureSet : faa_key_figure_set
  as select from I_FixedAssetTransaction(P_KeyDate                    : :P_KeyDate,
                                         P_AssetAccountingKeyFigureSet: :P_AssetAccountingKeyFigureSet)
  association [0..1] to I_FixedAssetForLedger as _FixedAssetForLedger on  _FixedAssetForLedger.CompanyCode      = $projection.CompanyCode
                                                                      and _FixedAssetForLedger.MasterFixedAsset = $projection.MasterFixedAsset
                                                                      and _FixedAssetForLedger.FixedAsset       = $projection.FixedAsset
                                                                      and _FixedAssetForLedger.Ledger           = $projection.Ledger
{
  key    CompanyCode,
  key    AssetDepreciationArea,
  key    MasterFixedAsset,
  key    FixedAsset,
  key    Ledger,
  key    LedgerFiscalYear,
  key    FiscalYear,
  key    FiscalPeriod,
  key    SubLedgerAcctLineItemType,
  key    AssetAcctTransClassfctn,
  key    AssetAccountingKeyFigure,
  key    AssetAccountingKeyFigureSet,
  key    AccountingDocument,
  key    TransactionSubitem,
  key    DebitCreditCode,
  key    CurrencyRole,

         PostingDate,

         /* Fields from Fixed Asset */
         AssetClass,
         AssetAccountDetermination,
         _FixedAssetForLedger.AssetCapitalizationDate,
         _FixedAssetForLedger.AssetDeactivationDate,
         cast(_FixedAsset.AssetCountryOfOrigin as faa_asset_cntry_of_origin) as AssetCountryOfOrigin,
         _FixedAsset.Supplier                                                as AssetSupplier,
         _FixedAsset._Supplier.SupplierAccountGroup,
         _FixedAsset._Supplier.AuthorizationGroup                            as SupplierBasicAuthorizationGrp,

         /* Fields from Fixed Asset (Time-Dependent Data) */
         AssetCostCenter,
         AssetPlant,
         AssetProfitCenter,
         AssetSegment,

         /* Text Fields */
         CompanyCodeName,
         FixedAssetDescription,

         @Environment.sql.passValue: true
         SelectedCurrencyBranch,

         /* Amounts */
         @Semantics.currencyCode:true
         DisplayCurrency,

         @Semantics.amount.currencyCode: 'DisplayCurrency'
         AcqnProdnAmtInDspCrcy,
         @Semantics.amount.currencyCode: 'DisplayCurrency'
         RtrmtNetBookValueAmtInDspCrcy,

         /* Associations */
         _FixedAsset,
         _AssetClassText
}

Learn More