I_AssetClassByCompanyCodeVH

@AbapCatalog.viewEnhancementCategory: [#NONE]
@EndUserText.label: 'Asset class by company code'
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #MANDATORY
@ObjectModel: { representativeKey: 'AssetClass',
                usageType.serviceQuality: #C,
                usageType.sizeCategory: #S,
                usageType.dataClass: #CUSTOMIZING }
@Metadata.allowExtensions: true
@ObjectModel.dataCategory:#VALUE_HELP
@Search.searchable: true

define view entity I_AssetClassByCompanyCodeVH 
as select from P_TF_AssetClassByCompanyCode( P_SAPClient: $session.client )

  association [0..1] to I_AssetClass     as _AssetClass  on $projection.AssetClass = _AssetClass.AssetClass
  association [1..1] to I_CompanyCode    as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..*] to I_AssetClassText as _Text        on $projection.AssetClass = _Text.AssetClass
  association [0..1] to I_Language       as _Language    on $projection.language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_CompanyCode'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } } ]
      @ObjectModel.text.element: ['CompanyCodeName']
  key CompanyCode,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.82
      @Search.ranking: #HIGH
  key AssetClass,

//      FixedAssetGroup, //Not supported with inactive BF

//      AssetScreenLayout, //Not supported with inactive BF

//      AssetClassDownPaymentIsAllowed, //Not supported with inactive BF

//      AssetClassIsBlocked, //Not supported with inactive BF

//      InventoryIsCounted, //Not supported with inactive BF

//      FixedAssetPropertyType, //Not supported with inactive BF

//      PropertyClass, //Not supported with inactive BF

//      AreaSizeUnit, //Not supported with inactive BF


      @Semantics.text
      _AssetClass._Text[1:Language = $session.system_language].AssetClassName,
      @ObjectModel.foreignKey.association: '_Language'
      @Consumption: {filter.hidden: true, hidden: true}
      _AssetClass._Text[1:Language = $session.system_language].Language,
      
      
      @Semantics.text: true
      _CompanyCode.CompanyCodeName,

      _CompanyCode,
      _AssetClass,
      _Text,
      _Language
}