I_ApplicationText

@EndUserText.label: 'Language-Dependent Description of Application'

@AbapCatalog:
{
  sqlViewName: 'IAPPLICT',
  compiler.compareFilter: true
}

--Access Control
// no authorization check required because view only reads customizing for which a check is not needed

@AccessControl.authorizationCheck: #NOT_REQUIRED

--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

--VDM Type
@VDM.viewType: #BASIC

@ObjectModel:
{
  usageType:
  {
    dataClass: #CUSTOMIZING,
    sizeCategory: #S,
    serviceQuality: #B
  },
  dataCategory: #TEXT,

  representativeKey: 'ChmlCmplncApplication'
}

define view I_ApplicationText
  --Select data from customizing table 'Language-dependent Description of Application'
  as select from ehfndc_applict as ApplicationText

  --Link to CDS view I_Language
  association [0..1] to I_Language as _Language on $projection.Language = _Language.Language
{
      --Application
  key cast( ApplicationText.application as ehfnd_cci_application_nce preserving type ) as ChmlCmplncApplication,

      --Language
      @Semantics.language: true
  key cast( ApplicationText.langu as spras )                                           as Language,

      --Description of Application
      @Semantics.text: true
      ApplicationText.application_description                                          as ChmlCmplncApplicationName,

      /* Associations */
      _Language

}