I_AllRepairObjectSituation

@AccessControl: {
    personalData.blocking: #('TRANSACTIONAL_DATA'),
    authorizationCheck: #MANDATORY
    }
@EndUserText.label: 'Anchor for Repair Object Situations'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
    semanticKey:  [ 'InHouseRepair', 'RepairObject' ] ,
    uniqueIdField: 'InHouseRepairItemUUID',
    usageType: {
          serviceQuality: #D,
          sizeCategory: #XL,
          dataClass: #MIXED
        }
  }
@ObjectModel.supportedCapabilities:[ #SITUATION_ANCHOR ]
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
define view entity I_AllRepairObjectSituation
  as select from           I_InHouseRepairItem           as InhRepItem
    inner join             I_InHouseRepair               as InHRepair           on  InHRepair.CustMgmtObjectType = InhRepItem.CustMgmtObjectType
                                                                                and InHRepair.InHouseRepair      = InhRepItem.InHouseRepair
    left outer to one join I_BusinessUserBasic           as RespEmployeeUser    on InHRepair.ResponsibleEmployee = RespEmployeeUser.BusinessPartner

    left outer to one join I_CustMgmtTransactionRelation as TransRelation       on  TransRelation.CustMgmtPrdcssrTransactionUUID = InhRepItem.InHouseRepairItemUUID
                                                                                and TransRelation.CustMgmtTransacRelationType    = 'IHR1'
                                                                                and TransRelation.CustMgmtPrdcssrTransacObjType  = 'BUS2000257'

    left outer to one join P_InHouseRepairItemStatusHist as StatusChangeHistory on StatusChangeHistory.InHouseRepairItemUUID = InhRepItem.InHouseRepairItemUUID

  association [0..1] to E_InHouseRepairItem            as _RepairObjectExtension        on  $projection.CustMgmtObjectType = _RepairObjectExtension.CustMgmtObjectType
                                                                                        and $projection.InHouseRepair      = _RepairObjectExtension.InHouseRepair
                                                                                        and $projection.RepairObject       = _RepairObjectExtension.InHouseRepairItem

  association [0..1] to R_InhRepairItmNrOfOpnMaintOrds as _InhReprItmNrOfOpnMaintOrd    on  $projection.InHouseRepairItemUUID = _InhReprItmNrOfOpnMaintOrd.InHouseRepairItemUUID

  association [0..1] to P_InhRepairItmNrOfBillgRdyItms as _InhRepairItmNrOfBillgRdyItms on  $projection.InHouseRepairItemUUID = _InhRepairItmNrOfBillgRdyItms.InHouseRepairItemUUID
{

         @UI.hidden: true
  key    InhRepItem.CustMgmtObjectType,

  key    InhRepItem.InHouseRepair                                                                                                   as InHouseRepair,

  key    InhRepItem.InHouseRepairItem                                                                                               as RepairObject,

         @UI.hidden:true
         InhRepItem.InHouseRepairItemUUID,

         @Consumption.valueHelpDefinition: [{ entity: { name: 'I_InHouseRepairStatusVH', element: 'InhRepairStatus' }}]
         cast(InHRepair.InhRepairStatus as crms4_inhrepair_status preserving type)                                                  as InhRepairStatus,


         @Consumption.valueHelpDefinition: [{ entity: { name: 'I_InhRepairItemStatusVH', element: 'InhRepairItemStatus' }}]
         cast(InhRepItem.InhRepairItemStatus as crms4_repair_obj_status preserving type)                                            as RepairObjectStatus,

         @UI.hidden:true
         RespEmployeeUser.UserID                                                                                                    as ResponsibleEmployeeUserID,

         @UI.hidden:true
         InhRepItem.InHouseRepairUUID,

         @UI.hidden:true
         InhRepItem.CreatedByUser,

         @UI.hidden: true
         InhRepItem.InhRepairItemCategory,

         /* Due to DCL Inheritence, below fields are needed */
         //required for authorization check

         @UI.hidden: true
         InHRepair.SalesOrganization,
         //required for authorization check

         @UI.hidden: true
         InHRepair.DistributionChannel,
         //required for authorization check

         @UI.hidden: true
         InHRepair.Division,
         //required for authorization check

         @UI.hidden: true
         InHRepair.SalesOffice,
         //required for authorization check

         @UI.hidden: true
         InHRepair.SalesGroup,
         @UI.hidden: true
         InhRepItem.InhRepairType,

         InhRepItem.InhRepairItemAvailyStatus,
         @Semantics.booleanIndicator: true
         cast(InhRepItem._RepairOrder._SuccessorServiceTransaction.ServiceDocumentIsOpen as crms4_serv_doc_is_open preserving type) as ServiceDocumentIsOpen,
         _InhReprItmNrOfOpnMaintOrd.NumberOfOpenMaintenanceOrders,
         _InhRepairItmNrOfBillgRdyItms.NrOfSrvcDocItmsReadyForBilling,


         //Associations

         InhRepItem._InHouseRepair,
         InHRepair._SalesOrganization,
         InHRepair._DistributionChannel,
         InHRepair._Division,
         InHRepair._SalesOffice,
         InHRepair._SalesGroup,
         InhRepItem._CustMgmtObjectType,
         InhRepItem._InhRepairItemCategory
}