I_ARBankTransactionDocumentItm

@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Interface for Bank Statement Items'
@ObjectModel.usageType:{
  serviceQuality: #A,
  sizeCategory: #XL,
  dataClass: #TRANSACTIONAL
}

define view entity I_ARBankTransactionDocumentItm 
 as select from febep

{

  key kukey                                                              as BankStatementShortID,
  key esnum                                                              as BankStatementItem,
      @Semantics.booleanIndicator:true
      vb1ok                                                              as BankLedgerIsPosted,
      @Semantics.booleanIndicator:true
      vb2ok                                                              as SubledgerIsPostedSuccessfully,
      epvoz                                                              as DebitCreditCode,
      @Semantics.amount.currencyCode: 'TransactionCurrency' 
      kwbtr                                                              as AmountInAccountCurrency,
      grpnr                                                              as BankStatementItemGroup,
      vgint                                                              as BankStatementPostingRule,
      vorgc                                                              as PaymentTransaction,
      intag                                                              as InterpretationAlgorithm,
      valut                                                              as ValueDate,
      avkoa                                                              as PaymentAdviceAccountType,
      avkon                                                              as PaymentAdviceAccount,
      @Semantics.booleanIndicator:true
      case when svavs = ''  then ''
           else 'X'      
           end                                                           as IsInProcess,
      @Semantics.booleanIndicator:true 
      n2pch                                                              as MemoLineIsChanged,
      kwaer                                                              as TransactionCurrency,
      fwaer                                                              as OriginalCurrency,
      @Semantics.amount.currencyCode: 'OriginalCurrency'
      cast( case epvoz
           when 'D' then - abs(fwbtr)
           when 'S' then - abs(fwbtr)
           else fwbtr
           end        as  farp_fwbtr )                                   as AmountInOriginalCurrency,
 
      cast(curr_rate as fac_kursf_ext )                                  as ExchangeRate, 
      partn                                                              as BusinessPartnerName,
      vgman                                                              as PaymentManualTransacType,
      avsid                                                              as PaymentAdvice,
      bvdat                                                              as BankPostingDate,
      budat                                                              as PostingDate,
      @Semantics.dateTime:true 
      butim                                                              as  ValueDateTime,
      case vgext when '' then vorgc
                 else vgext
                 end                                                     as PaymentExternalTransacType,
      butxt                                                              as PaymentTransactionDescription,
      busab                                                              as AccountingClerk,
      kostl                                                              as CostCenter,   
      gsber                                                              as BusinessArea,
      prctr                                                              as ProfitCenter,
      vertn                                                              as TreasuryContract,
      vertt                                                              as TreasuryContractType,
      pnota                                                              as DaybookEntry,
      
      @Semantics.booleanIndicator:true 
      pipre                                                              as BankStatementItemIsInterpreted,
      estat                                                              as PostingErrorStatus,
      belnr                                                              as BankLedgerDocument,
      cast( gjahr           as fis_gjahr_no_conv  preserving type )      as FiscalYear,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      spesk                                                              as FeeAmountInTransactionCrcy,
      @Semantics.amount.currencyCode: 'OriginalCurrency'
      spesf                                                              as FeeAmountInOriginalCrcy,
      texts                                                              as BankPostingKey,
      kfmod                                                              as AcctDetnFreeDefinedAttribute,
      xblnr                                                              as DocumentReferenceID,
      zuonr                                                              as AssignmentReference,
      pabks                                                              as PartnerBankCountry,
      pablz                                                              as PartnerBank,
      paswi                                                              as PartnerBankSWIFTCode,
      pakto                                                              as PartnerBankAccount,
      stavv                                                              as AssetManagementStatus,
      txtvv                                                              as AssetManagementText,
      info1                                                              as BankStatementItemDescription1,
      info2                                                              as BankStatementItemDescription2,
      nbbln                                                              as SubledgerDocument,
      ak1bl                                                              as BankLedgerOnAccountDocument,
      akbln                                                              as SubledgerOnAccountDocument,
      knrza                                                              as PayerParty,
      batch                                                              as LockboxBatch,
      abs(kursf)                                                         as AccountingExchangeRate,
      sgtxt                                                              as DocumentItemText,
      jpdat                                                              as BillOfExchangeFailureDate,
      posag                                                              as LockboxPostingAlgorithm,
      sdoc2                                                              as LockboxSubledgerDocument,
      vgref                                                              as BankReference,
      xbenr                                                              as OriginalReferenceDocument, 
      xbtyp                                                              as ReferenceDocumentType,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      arrsk                                                              as OverdueChargeAmtInTransacCrcy,
      pform                                                              as BankStmntItemProcessingType,
      kidno                                                              as PaymentReference,
      kkref                                                              as BankStatementItemReturnReason,
      mansp                                                              as DunningBlockingReason,
      idenr                                                              as BankStatementByCashManagement,
      b1app                                                              as BankLedgerExternalApplication,
      b1std                                                              as BankLedgerPostingIsSuppressed,
      b1err                                                              as BankLedgerExtPostgErrorStatus,
      b1doc                                                              as BankLedgerExtPostingDocument,
      b1typ                                                              as BankLedgerExtPostingRefDocType,
      b2app                                                              as SubledgerExtPostingApplication,
      b2std                                                              as SubledgerPostingIsSuppressed,
      b2err                                                              as SubledgerExtPostingErrorStatus,
      b2doc                                                              as SubledgerExtPostingDocument,
      b2typ                                                              as SubledgerExtPostingRefDocType,
      piban                                                              as PartnerBankIBAN,
      reprocreasoncode                                                   as BankStmntItemReprocessReason,
      @Semantics.booleanIndicator:true
      case when x_fwbtr_chg = '' then ''
           else 'X'
           end                                                           as BankStmntItemIsReprocessed,
      tatyp                                                              as PaymentTransactionCategory,

      @Semantics.booleanIndicator:true 
      eperl                                                              as IsCompleted,
      // Check related additional fileds

      case when chect_type = 'C'        and chect_orig is not initial then chect_orig
           when chect_type = 'C'        and chect_orig is initial     then chect
           else ''
           end                                                           as Cheque,

      cast ( case when chect_type = 'D' and chect_orig is not initial then chect_orig
                  when chect_type = 'D' and chect_orig is initial     then chect
                  else ''
                  end    as far_chect )                                 as BankStmntItemPaymentMediumRef,

      cast ( case when chect_type = ''  and chect_orig is not initial then chect_orig
                  when chect_type = ''  and chect_orig is initial     then chect
                  else ''
                  end    as far_chect_orig )                             as BankStmntItemCustomerRefNumber,

      ml_status                                                          as MachineLrngBankStmntItemStatus,
      belnr_gjahr                                                        as BankLedgerAcctgDocFiscalYear,
      nbbln_gjahr                                                        as SubledgerAcctgDocFiscalYear,
      accdoc_tmp_doc_id                                                  as TemporaryAccountingDocument,
      bp_id_category                                                     as BPIdentificationCategory,
      bp_id_number                                                       as BPIdentificationNumber,
      additional_info                                                    as LockboxBatchItmAdditionalInfo,
      bankstmntprocessingapplication                                     as BankStmntProcessingApplication,
      accountservicerreference                                           as AccountServicerReference,
      bank_status_code                                                   as BankStatementItemStatusByBank,
      bankstmntitmprocessingcategory                                     as BankStmntItmProcessingCategory
}