I_ARBankTransactionDocument

@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #MANDATORY
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Interface for Bank Statement Header'
@ObjectModel.usageType:{
  serviceQuality: #A,
  sizeCategory: #XL,
  dataClass: #TRANSACTIONAL
}
define view entity I_ARBankTransactionDocument 
  as select from febko
{
  key kukey                          as BankStatementShortID,

      anwnd                          as BankDataStorageApplication,
      absnd                          as SendingBank,
      azidt                          as BankStatementInternalID,
      emkey                          as BankStatementRecipientRefID,

      bukrs                          as CompanyCode,
      hbkid                          as HouseBank,
      hktid                          as HouseBankAccount,
      aznum                          as BankStatement,
      azdat                          as BankStatementDate,
      azdattim                       as BankStatementCreationDateTime,
      wvtim                          as BankStatementTime,
      // obsolete status values from old transaction FF67 will be mapped to harmonized status values

      case when astat = '3'  // Posted and Saved 3

            then '7'         // Not completed 7

           when astat = '5' or astat = '4'  // Unmarked for Deletion

            then '2'         // Saved

            else astat
      end                            as BankStatementStatus,
      waers                          as Currency,
      @Semantics.booleanIndicator:true 
      vb1ok                          as BankLedgerIsPosted,
      @Semantics.booleanIndicator:true 
      vb2ok                          as SubledgerIsPostedSuccessfully,
      @Semantics.booleanIndicator:true 
      kipre                          as BankStatementIsInterpreted,
      hkont                          as GLAccount,
      ktonr                          as BankAccount,
      ktoih                          as BankAccountHolderName,
      ktosb                          as BankAccountAdditionalName,
      azpgno                         as BankStatementPageNumber,
      ktopl                          as ChartOfAccounts,
      @Semantics.booleanIndicator:true 
      sstyp                          as OpeningBalanceIsInterim,
      @Semantics.amount.currencyCode: 'Currency'
      case when ssvoz = 'S'
            then - abs(ssbtr)
           else ssbtr
      end                            as OpeningBalanceAmtInTransCrcy,
      @Semantics.amount.currencyCode: 'Currency'
      sumso                          as TotalDebitAmountInTransCrcy,
      @Semantics.amount.currencyCode: 'Currency'
      sumha                          as TotalCreditAmountInTransCrcy,
      @Semantics.amount.currencyCode: 'Currency'
      case when esvoz = 'S'
            then - abs(esbtr)
           else esbtr
      end                            as ClosingBalanceAmtInTransCrcy,
      @Semantics.booleanIndicator:true 
      estyp                          as ClosingBalanceIsInterim,
      hzins                          as InterestRateInPercent,
//      bktoa                          as BankAccountType,

      anzes                          as NumberOfItems,
      vgtyp                          as PaymentTransactionTypeGroup,
      @Semantics.booleanIndicator:true 
      efart                          as BankStatementIsManuallyCreated,
//      xfdis                          as CashMgmtPaymtAdviceNoteCreated, 

//      xverd                          as SummarizeBankStatementItems, 

      input_format                   as BankStatementInputFormat,

      euser                          as CreatedByUser,
      edate                          as BankStatementImportDate,
      etime                          as BankStatementImportTime,
      bkref                          as BankAccountReferenceText,
      siban                          as IBAN,
      @Semantics.booleanIndicator:true 
      ''                             as IsReversed,
      @Semantics.booleanIndicator:true 
      cashupdok                      as CashPositionIsUpdated,
      cashupd                        as BkStmntIsCashUpdateRelevant,
      supfincor                      as BankStatementPostingType,
      refbyprocessingapplication     as RefByProcessingApplication,
      semobjbyprocessingapplication  as SemObjByProcessingApplication,
      bankstmntprocessingapplication as BankStmntProcessingApplication,
      bankstatementimportmessageuuid as BankStatementImportMessageUUID,
      bankstatementimportmessageid   as BankStatementImportMessageID

}

where
  // filter out statement with obsolete status (only used and needs to be further processed in old transaction FF67).

      astat <> '1' // being re-entered

  //  and astat <> '4' // being updated  -> 20190523 this will now be mapped to '2' (saved)

  and astat <> '9' // maked for deletion