I_APS_COM_COMM_OUTB_SERVICE

@AbapCatalog.sqlViewName: 'APS_COM_OUTSRV'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED

@EndUserText.label: 'Outbound Service Definition'
define view I_APS_COM_COMM_OUTB_SERVICE
  as select from    APS_COM_CSCN_API_OUTB_SRV as outb
    left outer join sapcontargethead          as cota            on  cota.id       = outb.cota_id
                                                                 and cota.version  = 'A'
                                                                 and outb.obs_type = 'COTA'
    left outer join dd07t                     as _cota_http_text on  _cota_http_text.domname    = 'APS_COM_OBS_TYPE'
                                                                 and _cota_http_text.domvalue_l = 'REST'
                                                                 and _cota_http_text.ddlanguage = $session.system_language
    left outer join dd07t                     as _cota_rfc_text  on  _cota_rfc_text.domname    = 'APS_COM_OBS_TYPE'
                                                                 and _cota_rfc_text.domvalue_l = 'SRFC'
                                                                 and _cota_rfc_text.ddlanguage = $session.system_language

{
  key outb.communication_scenario_id                  as CommunicationScenarioID,
  key outb.outbound_id                                as OutboundID,

      outb.is_mandatory                               as IsMandatory,

      @EndUserText.label: 'Application Protocol'
      case
        when outb.obs_type = 'COTA' and cota.comm_type = 'H' then 'REST'
        when outb.obs_type = 'COTA' and cota.comm_type = 'R' then 'SRFC'
        else outb.obs_type
      end                                             as ApplicationProtocol,

      @EndUserText.label: 'Application Protocol'
      case
        when outb.obs_type = 'COTA' and cota.comm_type = 'H' then _cota_http_text.ddtext
        when outb.obs_type = 'COTA' and cota.comm_type = 'R' then _cota_rfc_text.ddtext
        else outb._obs_type_text.ddtext
      end                                             as ApplicationProtocolText,

      @EndUserText.label: 'Service Interface'
      outb.service_interface                          as ServiceInterface,
      outb.url_path                                   as DefaultURL,
      cast (outb.supports_ping as boole_d)            as SupportsPing,

      cast(
         case
           when outb.obs_type = #APS_COM_oBS_TYPE.'IDOC' then 'X'
           when outb.obs_type = #APS_COM_oBS_TYPE.'SPRX' then 'X' // SOAP

           else ' '
         end as boole_d )                             as HasOutboundWSDL,

      cast(
         case outb.job_def_name
           when '' then ' '
           else 'X'
           end as boole_d )                           as HasJobDefinition,

      outb.job_def_name                               as JobDefinitionName,

      @EndUserText.label: 'Service'
      outb.description                                as Description,
      outb.idoc_msg_type                              as Message_Type,
      case
        when cota.comm_type = 'H' then 'REST'
        when cota.comm_type = 'R' then 'SRFC'
        else ''
      end                                             as CommunicationTargetType,

      @EndUserText.label: 'Basic Type'
      outb.idoc_type                                  as Basic_Type,

      cast (outb.ui_system_allow_embedded as boole_d) as IsUilEmbeddedAllowed,

      outb.is_deprecated                              as Is_Deprecated,

      outb.is_deprecated_within_cscn                  as IsDeprecatedWithinCSCN,

      outb.deprecated_with_release                    as DeprecatedWithRelease,
      outb.obs_id                                     as OBSID

}