I_APS_COM_CA_Root_Core

@AbapCatalog.sqlViewName: 'APS_COM_CA_ROOTC'
@ObjectModel.compositionRoot: true
@ClientHandling.type: #CLIENT_DEPENDENT
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Communication Arrangement Root Node Core View'
define view I_APS_COM_CA_Root_Core
  as select from aps_ca_d_root

  association [0..*] to I_APS_COM_CA_APIKEY_C        as _API_Keys              on $projection.db_key = _API_Keys.parent_key and
                                                                                   _API_Keys.parent_prop_str_inst_key is not null

  association [0..*] to I_Aps_Com_Ca_Inb_Defaults_C  as _InboundDefaults       on $projection.db_key = _InboundDefaults.parent_key

  association [0..*] to I_APS_COM_CA_INB_SRV_C       as _InboundServices       on $projection.db_key = _InboundServices.parent_key

  association [0..*] to I_Aps_Com_Ca_Outb_Defaults_C as _OutboundDefaults      on $projection.db_key = _OutboundDefaults.parent_key

  association [0..*] to I_APS_COM_CA_OUT_SRV_C       as _OutboundServices      on $projection.db_key = _OutboundServices.parent_key

  // Communication Scenario

  association [0..1] to APS_COM_CSCN_API_ROOT        as _CommunicationScenario on $projection.CommunicationScenario = _CommunicationScenario.communication_scenario_id


{
  key db_key                                             as db_key,
      commsyst                                           as CommSyst,
      commarrgmtname                                     as CommArrgmtName,
      commarrgmtdescription                              as CommArrgmtDescription,
      communicationscenario                              as CommunicationScenario,
      commarrgmteditstatus                               as CommArrgmtEditStatus,
      creationdatetime                                   as CreationDateTime,
      createdbyuser                                      as CreatedByUser,
      lastchangedatetime                                 as LastChangeDateTime,
      lastchangedbyuser                                  as LastChangedByUser,
      oauth2profile                                      as OAuth2Profile,
      oauth2configurationid                              as OAuth2ConfigurationID,
      commscenariochangedate                             as CommScenarioChangeDate,

      @ObjectModel.readOnly: true
      _CommunicationScenario.communication_scenario_type as CommunicationScenarioType,

      @ObjectModel.readOnly: true
      cast (
      case
      when  _CommunicationScenario.communication_scenario_type = #APS_COM_CSCN_TYPE.'1'
      then ''
      else 'X'
      end  as boole_d )                                  as ScenarioIsManagedBySAP,

      @ObjectModel.readOnly: true
      _CommunicationScenario.description                 as CommScenarioDescription,

      /* Associations */
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _API_Keys,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _InboundDefaults,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _InboundServices,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _OutboundDefaults,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _OutboundServices
}