FSH_V_Inforecord_Sos_B

@ClientDependent
@AbapCatalog.sqlViewName: 'FSH_V_IR_SOS_B'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType: {serviceQuality: #X, sizeCategory: #XXL, dataClass: #MIXED}
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'MM-PUR: Basic CDS View for SOS'
define view FSH_V_Inforecord_Sos_B
  as select from    eine  as eine
    inner join      eina  as eina  on eine.infnr = eina.infnr
    left outer join t001w as T001w on(
      T001w.werks    <> eine.werks
      and eine.werks =  ''
    )
    or T001w.werks   =  eine.werks
    inner join      lfa1  as lfa1  on eina.lifnr = lfa1.lifnr
    inner join      lfm1  as lfm1  on  eina.lifnr = lfm1.lifnr
                                   and eine.ekorg = lfm1.ekorg
{
  eina.matnr      as matnr,
  T001w.werks     as werks,
  eina.lifab      as vdatu,
  case eina.lifbi
    when '00000000' then '99991231'
    else eina.lifbi
  end             as bdatu,
  eina.lifnr      as lifnr,
  case eine.minbm
    when 0 then eine.minbm
    else
     case eina.umren
       when 0 then eine.minbm
       else division((eine.minbm * eina.umrez), eina.umren, 3)
     end
  end             as bstmi,
  case eine.bstma
    when 0 then cast('9999999999' as abap.dec(13,3))
    else
     case eina.umren
       when 0 then eine.bstma
       else division((eine.bstma * eina.umrez), eina.umren, 3)
     end
  end             as bstma,
  eine.aut_source as aut_source,
  eine.netpr      as netpr,
  eine.waers      as waers,
  eine.peinh      as peinh,
  eina.infnr      as infnr,
  eine.ekorg      as ekorg,
  eine.esokz      as esokz,
  eine.ekgrp      as ekgrp,
  eine.aplfz      as plifz,
  eine.verid      as verid,
  eine.rdprf      as rdprf,
  case eine.werks
    when '' then '2'
    else '1'
  end             as priority
}
where
      eina.loekz =  ''
  and eine.loekz =  ''
  and lfa1.loevm =  ''
  and lfm1.loevm =  ''
  and lfa1.sperm =  ''
  and lfm1.sperm =  ''
  and eina.matnr <> ''