FINS_REV_REC_COS_ACT_DIST_REF

@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Distinct AWREF for data with CO objects'

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MIXED

//ACDOCA view which selects distinct awref, awtyp, aworg, awsys, but without revenue recognition documents 

//Selects from ACDOCA


define view entity FINS_REV_REC_COS_ACT_DIST_REF
  as select distinct
    
  from         acdoca       as a
    inner join finsc_ld_cmp as v on  a.rbukrs = v.bukrs
                                 and a.rldnr  = v.rldnr   --- Ledger space is obsolete     or a.rldnr = '' )        
{
    a.rldnr                  as rldnr,
    a.awref,
    a.awtyp,
    a.aworg,
    a.awsys,
    a.awitem,
    a.objnr,
    a.ps_posid,
    a.ps_psp_pnr,
    a.paobjnr,
    a.aufnr,
    a.kdauf,
    a.kdpos,
    a.service_doc_id,
    a.service_doc_item_id,    
    a.service_contract_id,
    a.service_contract_item_id,
    a.vtkey,
    a.vtpos,
    a.ryear as gjahr,
    a.poper,
    a.fiscyearper,
    a.budat, 
    a.accasty,
    a.bttype,
    cast( case a.bttype when 'RFCV' then a.bttype else ( case a.vrgng when '' then a.vorgn when 'COIE' then a.vorgn when 'COIN' then a.vorgn else a.vrgng end ) end as fins_trr_bttype ) as bttype_tec
}
  
  where
    (
          a.objnr          <> '' 
      and a.glaccount_type <> 'X'
      and     not(
            a.accasty        is null
            or    a.accasty  =  ''
          )
      or(
              a.mig_source   =  'C'
        and   a.bstat        =  'C'
      )
      or(
              a.mig_source   =  ' '
        and   a.bstat        =  'C'
      )
    )
     and       a.vorgn        <> 'TBRR'
    //  and not (a.bstat = 'C' and a.poper = '000')

    and(
              a.mig_source <> ' '
      or(
              a.mig_source =  ' '
        and   not(
            a.bstat        =  'C'
            and a.poper    =  '000'
          )
      )
    )
  group by
    a.rldnr,
    a.awref,
    a.awtyp,
    a.aworg,
    a.awsys,
    a.awitem,
    a.objnr,
    a.ps_posid,
    a.ps_psp_pnr,
    a.paobjnr,
    a.aufnr,
    a.kdauf,
    a.kdpos,
    a.service_doc_id,
    a.service_doc_item_id,    
    a.service_contract_id,
    a.service_contract_item_id,
    a.vtkey,
    a.vtpos,
    a.ryear,
    a.poper,
    a.fiscyearper,
    a.budat,
    a.racct,
    a.gkont,
    a.slalittype,
    a.rbukrs,
    a.accasty,
    a.bttype,
    a.vorgn,
    a.vrgng
;