FINS_REV_REC_ACDOCA_API

@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'View on ACDOCA for new project invoicing'

@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MIXED

//Rev. Rec postings  of projects

//Used for new project invoicing - api repricing

//Selects from ACDOCA


define view entity FINS_REV_REC_ACDOCA_API 
with parameters
    P_Budat : budat
as select 


    
from acdoca
{
rldnr,
ps_psp_pnr,
pernr,
slalittype,
runit,
racct as hkont,
rsrce,
matnr,

rwcur,
rhcur,
rkcur,
rocur,
rvcur,
rbcur,
rccur,
rdcur,
recur,
rfcur,
rgcur,
rco_ocur,

@Semantics.quantity.unitOfMeasure: 'runit'
sum(msl) as msl,
@Semantics.amount.currencyCode: 'rwcur'
sum(wsl) as wsl,
@Semantics.amount.currencyCode: 'rhcur'
sum(hsl) as hsl,
@Semantics.amount.currencyCode: 'rkcur'
sum(ksl) as ksl,
@Semantics.amount.currencyCode: 'rkcur'
sum(kfsl) as kfsl,
@Semantics.amount.currencyCode: 'rocur'
sum(osl) as osl,
@Semantics.amount.currencyCode: 'rvcur'
sum(vsl) as vsl,
@Semantics.amount.currencyCode: 'rbcur'
sum(bsl) as bsl,
@Semantics.amount.currencyCode: 'rccur'
sum(csl) as csl,
@Semantics.amount.currencyCode: 'rdcur'
sum(dsl) as dsl,
@Semantics.amount.currencyCode: 'recur'
sum(esl) as esl,
@Semantics.amount.currencyCode: 'rfcur'
sum(fsl) as fsl,
@Semantics.amount.currencyCode: 'rgcur'
sum(gsl) as gsl,
@Semantics.amount.currencyCode: 'rco_ocur'
sum(co_osl) as co_osl
}  
where   vorgn     = 'TBRR'
    and accasty = 'PR'
    and   not( bstat     = 'C'
           and poper = '000'
      )
   and budat <= $parameters.P_Budat   
   
group by 
ps_psp_pnr,
pernr,
rldnr,
slalittype,
runit,
racct,
rsrce,
matnr,

rwcur,
rhcur,
rkcur,
rocur,
rvcur,
rbcur,
rccur,
rdcur,
recur,
rfcur,
rgcur,
rco_ocur;