FINS_IC_CONV_DATE

@AbapCatalog.sqlViewName: 'FINSV_IC_CONV_D'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XXL
@AbapCatalog.preserveKey: true
@EndUserText.label: 'IC: Conversion dates for ACDOCA entries'
define view FINS_IC_CONV_DATE
  as select from    acdoca                  as a
    left outer join bkpf                    as h on  h.mandt = a.rclnt
                                                 and h.bukrs = a.rbukrs
                                                 and h.gjahr = a.gjahr
                                                 and h.belnr = a.belnr                                               
    left outer join finsc_period            as p on  p.client              =  a.rclnt
                                                 and p.fiscal_year_variant =  a.periv
                                                 and p.fiscal_year         =  a.gjahr
                                                 and p.fiscal_period       =  a.poper
                                                 and a.poper               <> '000'
    left outer join FINS_IC_DATE_ZERO_POPER as b on  b.client              = a.rclnt
                                                 and b.fiscal_year_variant = a.periv
                                                 and b.fiscal_year         = a.gjahr
                                                 and b.fiscal_period       = a.poper
                                                 and a.poper               = '000'
{
  key a.rldnr,
  key a.rbukrs,
  key a.gjahr,
  key a.belnr,
  key a.docln,
      a.poper,
      a.buzei,
      a.rtcur,
      case when a.bstat = 'C' then a.rtcur --This is needed as BCF does not fill WSL correctly
           else a.rwcur 
      end as rwcur,
      a.rhcur,
      a.rkcur,
      a.rocur,
      a.rvcur,
      a.rbcur,
      a.rccur,
      a.rdcur,
      a.recur,
      a.rfcur,
      a.rgcur,
      a.tsl,
      @Semantics.amount.currencyCode: 'rwcur'
      case when a.bstat = 'C' then a.tsl --This is needed as BCF does not fill WSL correctly
           else a.wsl 
      end as wsl,
      a.hsl,
      a.ksl,
      a.osl,
      a.vsl,
      a.bsl,
      a.csl,
      a.dsl,
      a.esl,
      a.fsl,
      a.gsl,
      case when h.budat is not null and h.budat <> '00000000' then h.budat
           when a.budat is not null and a.budat <> '00000000' then a.budat
           when p.fiscal_period_start_date is not null then p.fiscal_period_start_date
           when b.fiscal_period_end_date is not null then b.fiscal_period_end_date
           else '00000000'
      end as budat,
      case when h.bldat is not null and h.bldat <> '00000000' then h.bldat
           when a.bldat is not null and a.bldat <> '00000000' then a.bldat
           when p.fiscal_period_start_date is not null then p.fiscal_period_start_date
           when b.fiscal_period_end_date is not null then b.fiscal_period_end_date
           else '00000000'
      end as bldat,
      case when h.wwert is not null and h.wwert <> '00000000' then h.wwert
           when p.fiscal_period_start_date is not null then p.fiscal_period_start_date
           when b.fiscal_period_end_date is not null then b.fiscal_period_end_date
           else '00000000'
      end as wwert
}