FINOC_RULE_NWA_BASE

@AbapCatalog.sqlViewName: 'FINOC_RULE_NWAB'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'O/C Rule: Network Activity Base'
// This view returns all network activities. A cross-join with all non-completed organizational changes is used to determine

// the profit center old, i.e. the profit center the network activity had before organizational change processing.

// Nevertheless, the organizational change runtime engine will always call the view with a restiction to organizational change,

// so that it won't return more than one org change per network activity.

define view FINOC_RULE_NWA_BASE
  as select from           afvc          as afvc
    inner join             afko          as afko    on afko.aufpl = afvc.aufpl
    inner join             aufk          as aufk    on aufk.aufnr = afko.aufnr
    inner join             finoc_orglchg as orglchg on orglchg.processing_status <> 'CMP'
    left outer to one join finoc_rt_nwa  as rt_nwa  on  rt_nwa.aufnr           = afko.aufnr
                                                    and rt_nwa.vornr           = afvc.vornr
                                                    and rt_nwa.orgl_change     = orglchg.orgl_change
                                                    and rt_nwa.reassgmt_status = 'DONE'
{
  key  afko.aufnr,
  key  afvc.vornr,
  key  orglchg.orgl_change,
       aufk.kokrs,
       afvc.bukrs,
       coalesce(rt_nwa.prctr_old, afvc.prctr)                      as prctr_old,
       cast( '          ' as finoc_prctr_new preserving type )     as prctr,
       cast('  ' as finoc_prctr_drvtn_source_type preserving type) as prctr_drvtn_source_type, // space = this is the root object

       cast('00000000' as finoc_srce_ps_psp_pnr preserving type)   as srce_ps_psp_pnr,
       cast('00000000' as finoc_srce_ps_prj_pnr preserving type)   as srce_ps_prj_pnr,
       cast('            ' as finoc_srce_aufnr preserving type)    as srce_aufnr,
       afvc.aufpl,
       afvc.aplzl,
       afvc.projn                                                  as ps_psp_pnr,
       afko.pronr                                                  as ps_prj_pnr
}
where
      aufk.autyp = '20' // Network activtiy