FINOC_CHECK_REC_01_REC_TO_ALL

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Org. Change: From RE Contract to All'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}

define view entity FINOC_CHECK_REC_01_REC_TO_ALL
  as select from    vicncn        as rec

    inner join      vicerule      as val  on val.intreno  = rec.intreno
                                          and(
                                            val.acctobjnr is not initial
                                            or val.objnr  is not initial
                                          )

    left outer join csks          as ccr1 on  ccr1.objnr    = val.acctobjnr
                                          and val.acctobjnr is not initial

    left outer join prps          as wbs1 on  wbs1.objnr    = val.acctobjnr
                                          and val.acctobjnr is not initial

    left outer join aufk          as ord1 on  ord1.objnr    = val.acctobjnr
                                          and val.acctobjnr is not initial

    left outer join vibdcnsubject as sbj  on  sbj.intreno   = val.objnr
                                          and val.objnr     is not initial
                                          and sbj.acctobjnr is not initial

    left outer join csks          as ccr2 on ccr2.objnr = sbj.acctobjnr

    left outer join prps          as wbs2 on wbs2.objnr = sbj.acctobjnr

    left outer join aufk          as ord2 on ord2.objnr = sbj.acctobjnr
{
  key rec.intreno                                               as intreno,
      rec.bukrs                                                 as bukrs,
      rec.recnnr                                                as recnnr,
      val.validfrom                                             as val_validfrom,
      case when ( val.validfrom is initial or
                  val.validfrom is null )
        then '00000000' else val.validfrom end                  as val_validfrom_x,
      val.validto                                               as val_valid_to,
      case when ( val.validto is initial or
                  val.validto is null )
        then '99991231' else val.validto end                    as val_validto_x,
      ccr1.kokrs                                                as ccr_val_kokrs,
      ccr1.kostl                                                as ccr_val_kostl,
      ccr1.datab                                                as ccr_val_validfrom,
      ccr1.datbi                                                as ccr_val_validto,
      wbs1.pspnr                                                as wbs_val_pspnr,
      wbs1.posid                                                as wbs_val_posid,
      ord1.aufnr                                                as ord_val_aufnr,
      ccr2.kokrs                                                as ccr_sbj_kokrs,
      ccr2.kostl                                                as ccr_sbj_kostl,
      ccr2.datab                                                as ccr_sbj_validfrom,
      ccr2.datbi                                                as ccr_sbj_validto,
      wbs2.pspnr                                                as wbs_sbj_pspnr,
      wbs2.posid                                                as wbs_sbj_posid,
      ord2.aufnr                                                as ord_sbj_aufnr,
      case when ccr1.kostl is not initial then 'X' else ' ' end as ccr_val,
      case when ord1.aufnr is not initial then 'X' else ' ' end as ord_val,
      case when wbs1.pspnr is not initial then 'X' else ' ' end as wbs_val,
      case when ccr2.kostl is not initial then 'X' else ' ' end as ccr_sbj,
      case when ord2.aufnr is not initial then 'X' else ' ' end as ord_sbj,
      case when wbs2.pspnr is not initial then 'X' else ' ' end as wbs_sbj
}