FINOC_CHECK_REC_01_ORD_TO_REC

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Org. Change: From Order to RE Contract'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}

define view entity FINOC_CHECK_REC_01_ORD_TO_REC
  as select from vicncn   as rec
    inner join   vicerule as val on val.intreno = rec.intreno
    inner join   aufk     as ord on ord.objnr = val.acctobjnr
{
  key rec.bukrs,
  key rec.recnnr,
  key ord.aufnr,
      val.validfrom,
      case when ( val.validfrom is initial or
                  val.validfrom is null )
        then '00000000' else val.validfrom end as validfrom_x,
      val.validto,
      case when ( val.validto is initial or
                  val.validto is null )
        then '99991231' else val.validto end   as validto_x,
      rec.intreno,
      rec.objnr                                as rec_objnr,
      'VAL_ORD'                                as kind
}
union select from vicncn        as rec
  inner join      vicerule      as val on val.intreno = rec.intreno
  inner join      vibdcnsubject as sbj on sbj.intreno = val.objnr
  inner join      aufk          as ord on ord.objnr = sbj.acctobjnr
{
  key rec.bukrs,
  key rec.recnnr,
  key ord.aufnr,
      val.validfrom,
      case when ( val.validfrom is initial or
                  val.validfrom is null )
        then '00000000' else val.validfrom end as validfrom_x,
      val.validto,
      case when ( val.validto is initial or
                  val.validto is null )
        then '99991231' else val.validto end   as validto_x,
      rec.intreno,
      rec.objnr                                as rec_objnr,
      'SBJ_ORD'                                as kind
}