FAA_CFG_CMP_LEDGER

@AbapCatalog.sqlViewName: 'FAAV_CFG_CMP_LD'
@ClientHandling.algorithm: #SESSION_VARIABLE
--@VDM.private: true
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_ALLOWED
@AbapCatalog.buffering.status: #ACTIVE
--@AbapCatalog.buffering.type: #FULL
@AbapCatalog.buffering.type: #GENERIC
@AbapCatalog.buffering.numberOfKeyFields: 1
@AbapCatalog.preserveKey: true
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.sizeCategory: #S
@EndUserText.label: 'Configuration Data of CompCodes and Ledger'
define view FAA_CFG_CMP_LEDGER

as 

select from         faat_cmp_ledger    as aa_cmp_ld

    inner join      finsc_ld_cmp       as gl_cmp_ld      on  gl_cmp_ld.rldnr            = aa_cmp_ld.ledger
                                                        and  gl_cmp_ld.bukrs            = aa_cmp_ld.comp_code
    inner join      finsc_ledger       as finsc_ld       on  finsc_ld.rldnr             = aa_cmp_ld.ledger
--    inner join      tacc_trgt_ldgr     as accpr_ldgrp    on  accpr_ldgrp.acc_principle  = gl_cmp_ld.acc_principle

--    inner join      fagl_tldgrp_map    as fagl_tldgrp     on  fagl_tldgrp.ldgrp           = accpr_ldgrp.ldgrp_gl
--                                                         and  fagl_tldgrp.rldnr           = aa_cmp_ld.ledger
                                                         
    left outer join faac_ap0           as ap_generic      on  ap_generic.acc_principle  = gl_cmp_ld.acc_principle
                                                         and  ap_generic.comp_code      = '*   '
    left outer join faac_ap0           as ap_specific     on  ap_specific.acc_principle = gl_cmp_ld.acc_principle
                                                         and  ap_specific.comp_code     = aa_cmp_ld.comp_code

{    
    key aa_cmp_ld.comp_code                                                    as comp_code,
    key aa_cmp_ld.ledger                                                       as ledger,
    
    
        --- FINSC_LD_CMP ---
        gl_cmp_ld.periv                                                        as fisc_year_var,
        gl_cmp_ld.acc_principle                                                as acc_principle,
        finsc_ld.xleading                                                      as is_leading_ledger,
        
        --- TACC_TRGT_LDGR and FAGL_TLDGRP_MAP ---
        -- Because of Group Valuation: ledger group will not be retrieved from accpr_ldgrp
        --fagl_tldgrp.ldgrp                                                      as ldgrp,
        --fagl_tldgrp.represent                                                  as represent,
        cast(aa_cmp_ld.ledger as fagl_target_ldgrp)                            as ldgrp,// will be obsolete

        'X'                                                                    as represent,
        
        --- Master Data from FAAT_CMP_LEDGER
        aa_cmp_ld.current_fisc_year                                            as current_fisc_year,
        aa_cmp_ld.plan_horizon                                                 as plan_horizon,
        
        --- Chart of depreciation assigned for Acc.Principle ---
        case ap_specific.comp_code
        when aa_cmp_ld.comp_code then ap_specific.depr_chart         //- specific entry found!

                                 else ap_generic.depr_chart                end as depr_chart_accpr,
        --- Accounting Principle Settings
        case ap_specific.comp_code
        when aa_cmp_ld.comp_code then ap_specific.use_gross_trans
                                 else ap_generic.use_gross_trans           end as use_gross_trans,
        case ap_specific.comp_code
        when aa_cmp_ld.comp_code then ap_specific.auc_version
                                 else ap_generic.auc_version               end as auc_version,
        case ap_specific.comp_code
        when aa_cmp_ld.comp_code then ap_specific.trans_downpayment
                                 else ap_generic.trans_downpayment         end as trans_downpayment,
        case ap_specific.comp_code
        when aa_cmp_ld.comp_code then ap_specific.use_group_asset
                                 else ap_generic.use_group_asset           end as use_group_asset,
        case ap_specific.comp_code
        when aa_cmp_ld.comp_code then ap_specific.depr_doc_type
                                 else ap_generic.depr_doc_type             end as depr_doc_type,
        case ap_specific.comp_code
        when aa_cmp_ld.comp_code then ap_specific.post_nbv_retirement
                                 else ap_generic.post_nbv_retirement       end as post_nbv_retirement,
        case ap_specific.comp_code
        when aa_cmp_ld.comp_code then ap_specific.revenue_distribute_method
                                 else ap_generic.revenue_distribute_method end as revenue_distribute_method,
                                 
        --- currency fields (needed for Compat-Mapping of parallel currencies) --
        gl_cmp_ld.curtph                                                       as curtph,
        #FINS_CUR_POS.'1'                                                      as curposh,
        gl_cmp_ld.curtpk                                                       as curtpk,
        gl_cmp_ld.curposk                                                      as curposk,
        gl_cmp_ld.curtpo                                                       as curtpo,
        gl_cmp_ld.curposo                                                      as curposo,
        gl_cmp_ld.curtpv                                                       as curtpv,
        gl_cmp_ld.curposv                                                      as curposv,
        gl_cmp_ld.curtpb                                                       as curtpb,
        gl_cmp_ld.curposb                                                      as curposb,
        gl_cmp_ld.curtpc                                                       as curtpc,
        gl_cmp_ld.curposc                                                      as curposc,
        gl_cmp_ld.curtpd                                                       as curtpd,
        gl_cmp_ld.curposd                                                      as curposd,
        gl_cmp_ld.curtpe                                                       as curtpe,
        gl_cmp_ld.curpose                                                      as curpose,
        gl_cmp_ld.curtpf                                                       as curtpf,
        gl_cmp_ld.curposf                                                      as curposf,
        gl_cmp_ld.curtpg                                                       as curtpg,
        gl_cmp_ld.curposg                                                      as curposg
}