Ehenv_Sdef_Amns_At_Location_T

@ClientHandling.algorithm: #SESSION_VARIABLE //Inserted by VDM CDS Suite Plugin

@AbapCatalog.sqlViewName: 'EHENVV_SMAM4LOCT'
//Commented by VDM CDS Suite Plugin:@ClientDependent: true

@AccessControl.authorizationCheck: #NOT_REQUIRED
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Sampling Amounts at Location as Text'

//CDS View Performance annotation

@ObjectModel.usageType:{ serviceQuality: #P,        // < 15 msec

                         sizeCategory:  #L,         // < 10.000.000

                         dataClass: #MIXED }
                         
define view Ehenv_Sdef_Amns_At_Location_T with parameters p_def_langu : lang, 
                  p_initial_key:/bobf/conf_key,
                  p_loc_root_key:/bobf/conf_key,
                  p_sy_datlo : syst_datlo,
                  p_sy_langu : lang
                  
// IMPORTANT: ensure that parameters are alphabetically sorted in order for the View to work on HANA prior to SP10                  

  
as select from Ehenv_Sdef_Amns_At_Location (  p_def_langu:$parameters.p_def_langu,
                                                p_initial_key:$parameters.p_initial_key,
                                                p_loc_root_key:$parameters.p_loc_root_key,
                                                p_sy_datlo:$parameters.p_sy_datlo,
                                                p_sy_langu:$parameters.p_sy_langu ) as sdef_amns
                                                
left outer join dd07t as IType_txt on IType_txt.domname = 'EHFND_AMNS_ISSUE_TYPE' and IType_txt.ddlanguage = $parameters.p_sy_langu
                                 and IType_txt.domvalue_l = sdef_amns.issue_type
left outer join dd07t as DType_txt on DType_txt.domname = 'EHENV_SCEN_AMNS_SRC_TYPE' and DType_txt.ddlanguage = $parameters.p_sy_langu
                                 and DType_txt.domvalue_l = sdef_amns.sourcetype
{
  //Location Revision Fields  

    sdef_amns.location_text as location_text,
    sdef_amns.loc_auth_group as loc_auth_group,
    sdef_amns.plant_id as plant_id,
    sdef_amns.cost_center as cost_center,
    sdef_amns.company_code as company_code,
    sdef_amns.buss_area as buss_area,
    sdef_amns.type as type,
    sdef_amns.country as country,
    sdef_amns.region as region,
    sdef_amns.loc_status as loc_status,
//Amount fields

    
    sdef_amns.amount_key as amount_key,
    sdef_amns.amount_status as amount_status,
    sdef_amns.sourcetype as sourcetype, 
    sdef_amns.external_src as external_src, 
    sdef_amns.issue_type as issue_type,
    sdef_amns.issue_type_icon as issue_type_icon,
    
    IType_txt.ddtext as issue_type_txt,
    
    DType_txt.ddtext as data_type_txt,
    
    sdef_amns.deviation_id as deviation_id,
    sdef_amns.preliminary_ind as preliminary_ind,
    sdef_amns.value as value,
    sdef_amns.unit_text as unit_text,
    cast(substring(cast(sdef_amns.valuetimestamp as abap.char(17)), 1, 8) as abap.dats) as value_date,
    substring(cast(sdef_amns.valuetimestamp as abap.char(17)), 1, 4) as value_year,
    substring(cast(sdef_amns.valuetimestamp as abap.char(17)), 5, 2) as value_month,
    substring(cast(sdef_amns.valuetimestamp as abap.char(17)), 7, 2) as value_day,
    cast(substring(cast(sdef_amns.valuetimestamp as abap.char(17)), 9, 6) as abap.tims) as value_time,

    sdef_amns.value_month_txt as value_month_txt,
 
    sdef_amns.data_title as data_title
}