C_WorkAssignment_1

DDL: C_WORKASSIGNMENT_1 Type: view_entity CONSUMPTION Package: WFD_WORKER_FACTSHEET_BL

Work Assignment for Worker Factsheet

C_WorkAssignment_1 is a Consumption CDS View that provides data about "Work Assignment for Worker Factsheet" in SAP S/4HANA. It reads from 1 data source (R_WorkAssignment) and exposes 27 fields with key fields WorkAssignmentUUID, WorkAssignment. It is exposed through 1 OData service (UI_WORKER_FACTSHEET). Part of development package WFD_WORKER_FACTSHEET_BL.

1 data source(s) Exposed by 1 service(s) 27 fields

Data Sources (1)

SourceAliasJoin Type
R_WorkAssignment R_WorkAssignment projection

Annotations (8)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
EndUserText.label Work Assignment for Worker Factsheet view
VDM.viewType #CONSUMPTION view
VDM.lifecycle.contract.type #NONE view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #MASTER view
Metadata.allowExtensions true view

OData Services (1)

ServiceBindingVersionContractRelease
UI_WORKER_FACTSHEET UI_WORKER_FACTSHEET V4 C1 NOT_RELEASED

Fields (27)

KeyFieldSource TableSource FieldDescription
KEY WorkAssignmentUUID WorkAssignmentUUID
KEY WorkAssignment WorkAssignment
StartDate StartDate
EndDate EndDate
WorkforcePersonUserID WorkforcePersonUserID
WorkAssignmentBusinessPartner WorkAssignmentBusinessPartner
Person Person
PersonUUID PersonUUID
CompanyCode CompanyCode
CompanyCodeName _CompanyCodeText CompanyCodeName
WorkAssignmentCountryISOCode WorkAssignmentCountryISOCode
RoleCategory RoleCategory
BasicRoleCategory BasicRoleCategory
BusinessPartnerRoleShortName _BPUsrRoleText BusinessPartnerRoleShortName
BusinessPartnerRole BusinessPartnerRole
IsBusinessPurposeCompleted IsBusinessPurposeCompleted
IsBlocked IsBlocked
CreationDateTime CreationDateTime
EmploymentSituation EmploymentSituation
virtualEmploymentSituationTextval_text
Supplier Supplier
_AssignmentDetailsForKeyDate _AssignmentDetailsForKeyDate
_BPDataControllerUsage _BPDataControllerUsage
_BPUsrRoleText _BPUsrRoleText
_CompanyCodeText _CompanyCodeText
_WorkAssignmentBP _WorkAssignmentBP
_WorkforcePersonBP _WorkforcePersonBP 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Work Assignment for Worker Factsheet'
@VDM: {
  viewType: #CONSUMPTION,
  lifecycle.contract.type: #NONE
  //usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]

}
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XL,
  dataClass: #MASTER
}
@Metadata.allowExtensions: true
@ObjectModel.semanticKey: ['WorkforcePersonUserID','StartDate']
@Consumption.dbHints:[ 'USE_HEX_PLAN' ]
define view entity C_WorkAssignment_1
  //provider contract transactional_query

  as projection on R_WorkAssignment
{
  key                     WorkAssignmentUUID,
  key                     WorkAssignment,
                          //                          WorkAssignmentStartDate,

                          StartDate,
                          EndDate,
                          WorkforcePersonUserID,
                          WorkAssignmentBusinessPartner,
                          Person,
                          PersonUUID,
                          @ObjectModel.text.element: ['CompanyCodeName']
                          CompanyCode,
                          @Semantics.text: true
                          _CompanyCodeText.CompanyCodeName,
                          WorkAssignmentCountryISOCode,
                          //@ObjectModel.text.element: ['BusinessPartnerRoleShortName']

                          RoleCategory,
                          @ObjectModel.text.element: ['BusinessPartnerRoleShortName']
                          BasicRoleCategory,
                          @Semantics.text: true
                          _BPUsrRoleText.BusinessPartnerRoleShortName,
                          BusinessPartnerRole,
                          IsBusinessPurposeCompleted,
                          IsBlocked,
                          //                          BusPartRelshpSupplierIsVisible,

                          //                          @Semantics.text: true

                          @ObjectModel.virtualElement: true
                          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WFD_ASSIGNMENT_CALC_EXIT'
  virtual                 BusPartRelshpSupplierIsHidden : abap_boolean,
                          CreationDateTime,
                          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WFD_ASSIGNMENT_CALC_EXIT'
                          @ObjectModel.text.element: ['EmploymentSituationText']
                          EmploymentSituation,
                          @Semantics.text: true
                          @ObjectModel.virtualElement: true
                          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WFD_ASSIGNMENT_CALC_EXIT'
  virtual                 EmploymentSituationText       : val_text,
                          @Semantics.text: true
                          @ObjectModel.virtualElement: true
                          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WFD_ASSIGNMENT_CALC_EXIT'
  virtual                 CalculationResultHeaderTitle  : val_text,
                          //                          @Semantics.text: true

                          @ObjectModel.virtualElement: true
                          @Semantics.booleanIndicator: true
                          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WFD_ASSIGNMENT_CALC_EXIT'
  virtual                 CostAssignmentIsHidden        : abap_boolean,
                          @ObjectModel.virtualElement: true
                          @Semantics.booleanIndicator: true
                          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WFD_ASSIGNMENT_CALC_EXIT'
  virtual                 ServiceCostLevelIsHidden      : abap_boolean,
                          @ObjectModel.virtualElement: true
                          @Semantics.booleanIndicator: true
                          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WFD_ASSIGNMENT_CALC_EXIT'
  virtual                 PaymentApproverSecIsHidden    : abap_boolean,
                          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WFD_ASSIGNMENT_CALC_EXIT'
                          @ObjectModel.text.element: ['SupplierFullName']
                          Supplier,
                          @Semantics.text: true
                          @ObjectModel.virtualElement: true
                          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WFD_ASSIGNMENT_CALC_EXIT'
  virtual                 SupplierFullName              : md_supplier_full_name,

                          /* Associations */
                          _AssignmentDetailsForKeyDate,
                          _BPDataControllerUsage,
                          _BPUsrRoleText,
                          _CompanyCodeText,
                          _WorkAssignmentBP,
                          _WorkforcePersonBP,
                          _WorkAssignmentDetails    : redirected to composition child C_WorkAssignmentDetail_1,
                          _AlternateCostObject      : redirected to composition child C_WorkAssignmentAltCost,
                          _Payment                  : redirected to composition child C_WorkAssignmentPayment,
                          _BPRltnShipSupplier       : redirected to composition child C_SupplierDetail,
                          _Project                  : redirected to composition child C_WorkAssignmentProject,
                          _WorkAssgmtSrvcCostLvl    : redirected to composition child C_WrkAssgmtSrvcCostLvl_1,
                          _WorkAssgmtPrivateAddress : redirected to composition child C_WorkAssignmentPrvtAddress_1,
                          _WrkAssgmtPaymentMethod   : redirected to composition child C_WorkAgreementPaymentMethod,
                          _WorkforcePerson          : redirected to parent C_WorkforcePerson



}

Learn More