C_UnqPartFuncForSalesDocCatVH

DDL: C_UNQPARTFUNCFORSALESDOCCATVH SQL: CUNQPRTFNCSDOCVH Type: view CONSUMPTION Package: SD_CHANGE_COCKPIT_ODATA

Unique Partner Func for Sales Documents

C_UnqPartFuncForSalesDocCatVH is a Consumption CDS View that provides data about "Unique Partner Func for Sales Documents" in SAP S/4HANA. It reads from 1 data source (I_PartFuncByPartDetnProced) and exposes 4 fields with key field PartnerFunction. It has 1 association to related views. Part of development package SD_CHANGE_COCKPIT_ODATA.

1 data source(s) 4 fields

Data Sources (1)

SourceAliasJoin Type
I_PartFuncByPartDetnProced PartFuncByPartDetnProced inner

Associations (1)

CardinalityTargetAliasCondition
[0..1] C_PartnerFunctionUnconverted _PartnerFunction $projection.PartnerFunction = _PartnerFunction.PartnerFunction

Annotations (12)

NameValueLevelField
AbapCatalog.sqlViewName CUNQPRTFNCSDOCVH view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
EndUserText.label Unique Partner Func for Sales Documents view
ObjectModel.usageType.dataClass #CUSTOMIZING view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.dataCategory #VALUE_HELP view
ClientHandling.algorithm #SESSION_VARIABLE view
VDM.viewType #CONSUMPTION view
Search.searchable true view
AccessControl.authorizationCheck #NOT_REQUIRED view

Fields (4)

KeyFieldSource TableSource FieldDescription
KEY PartnerFunction I_PartFuncByPartDetnProced PartnerFunction
PartnerFunctionName
SDDocumentPartnerType _PartnerFunction SDDocumentPartnerType
PartnerIsNotChangeable I_PartFuncByPartDetnProced PartnerIsNotChangeable 
@AbapCatalog.sqlViewName: 'CUNQPRTFNCSDOCVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@EndUserText.label: 'Unique Partner Func for Sales Documents'

@ObjectModel:{
  usageType:{
    dataClass: #CUSTOMIZING,
    serviceQuality: #B,
    sizeCategory: #L
  },
  dataCategory: #VALUE_HELP
  //,

  //resultSet.sizeCategory: #XS

}

@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #CONSUMPTION
@Search: {
  searchable: true
}

@AccessControl.authorizationCheck: #NOT_REQUIRED

define view C_UnqPartFuncForSalesDocCatVH as select distinct from I_SalesDocumentType        as SalesDocumentType
    inner join            I_PartFuncByPartDetnProced as PartFuncByPartDetnProced on SalesDocumentType.PartnerDeterminationProcedure = PartFuncByPartDetnProced.PartnerDeterminationProcedure

  association [0..1] to C_PartnerFunctionUnconverted as _PartnerFunction on $projection.PartnerFunction = _PartnerFunction.PartnerFunction

 {
       @UI.hidden: true
      @ObjectModel.text.element: ['PartnerFunctionName']
      @UI.textArrangement: #TEXT_ONLY
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.9
  key PartFuncByPartDetnProced.PartnerFunction,

      @Semantics.text:true
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.9
      _PartnerFunction._Text[1: Language=$session.system_language].PartnerFunctionName,

      _PartnerFunction.SDDocumentPartnerType,

      @Semantics.booleanIndicator: true
      @Consumption.filter.hidden
      @UI.hidden: true
      cast(
        case
          when _PartnerFunction.SDDocumentPartnerType = 'KU'
          then ''
        else 'X'
        end as boole_d ) as UICT_Customer,

      @Semantics.booleanIndicator: true
      @Consumption.filter.hidden
      @UI.hidden: true
      cast(
        case
          when _PartnerFunction.SDDocumentPartnerType = 'AP'
          then ''
        else 'X'
        end as boole_d ) as UICT_ContactPerson,

      @Semantics.booleanIndicator: true
      @Consumption.filter.hidden
      @UI.hidden: true
      cast(
        case
          when _PartnerFunction.SDDocumentPartnerType = 'PE'
          then ''
        else 'X'
        end as boole_d ) as UICT_Personnel,

      @Semantics.booleanIndicator: true
      @Consumption.filter.hidden
      @UI.hidden: true
      cast(
        case
          when _PartnerFunction.SDDocumentPartnerType = 'LI'
          then ''
        else 'X'
        end as boole_d ) as UICT_Supplier,

      @Consumption.filter.hidden
      @UI.hidden: true
      @Semantics.booleanIndicator: true
      PartFuncByPartDetnProced.PartnerIsNotChangeable
}
//where

//  PartFuncByPartDetnProced.PartnerIsNotChangeable = ''

Learn More