C_UnqNonStdPartFuncForSlsDocVH

@AbapCatalog.sqlViewName: 'CUNQNSTDPFNSDVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@EndUserText.label: 'Unique Non Std Partner Func for Sales Documents'

@ObjectModel:{
  usageType:{
    dataClass: #CUSTOMIZING,
    serviceQuality: #B,
    sizeCategory: #L
  },
  dataCategory: #VALUE_HELP
  //,

  //resultSet.sizeCategory: #XS

}

@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #CONSUMPTION
@Search: {
  searchable: true
}

@AccessControl.authorizationCheck: #NOT_REQUIRED

define view C_UnqNonStdPartFuncForSlsDocVH as select distinct from I_SalesDocumentType        as SalesDocumentType
    inner join            I_PartFuncByPartDetnProced as PartFuncByPartDetnProced on SalesDocumentType.PartnerDeterminationProcedure = PartFuncByPartDetnProced.PartnerDeterminationProcedure

  association [0..1] to C_PartnerFunctionUnconverted as _PartnerFunction on $projection.PartnerFunction = _PartnerFunction.PartnerFunction

 {
      @UI.hidden: true
      @ObjectModel.text.element: ['PartnerFunctionName']
      @UI.textArrangement: #TEXT_ONLY
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.9
  key PartFuncByPartDetnProced.PartnerFunction,

      @Semantics.text:true
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.9
      _PartnerFunction._Text[1: Language=$session.system_language].PartnerFunctionName,

      _PartnerFunction.SDDocumentPartnerType,

      @Semantics.booleanIndicator: true
      @Consumption.filter.hidden
      @UI.hidden: true
      cast(
        case
          when _PartnerFunction.SDDocumentPartnerType = 'KU'
          then ''
        else 'X'
        end as boole_d ) as UICT_Customer,

      @Semantics.booleanIndicator: true
      @Consumption.filter.hidden
      @UI.hidden: true
      cast(
        case
          when _PartnerFunction.SDDocumentPartnerType = 'AP'
          then ''
        else 'X'
        end as boole_d ) as UICT_ContactPerson,

      @Semantics.booleanIndicator: true
      @Consumption.filter.hidden
      @UI.hidden: true
      cast(
        case
          when _PartnerFunction.SDDocumentPartnerType = 'PE'
          then ''
        else 'X'
        end as boole_d ) as UICT_Personnel,

      @Semantics.booleanIndicator: true
      @Consumption.filter.hidden
      @UI.hidden: true
      cast(
        case
          when _PartnerFunction.SDDocumentPartnerType = 'LI'
          then ''
        else 'X'
        end as boole_d ) as UICT_Supplier,

      @Consumption.filter.hidden
      @UI.hidden: true
      PartFuncByPartDetnProced.PartnerIsNotChangeable
}
where
//  SalesDocumentType.SDDocumentCategory     = 'E'

//  or SalesDocumentType.SDDocumentCategory  = 'F'

//  or SalesDocumentType.SDDocumentCategory  = 'C'

//  or SalesDocumentType.SDDocumentCategory  = 'G'

//  or SalesDocumentType.SDDocumentCategory  = 'K'

//  or SalesDocumentType.SDDocumentCategory  = 'L'

//  or SalesDocumentType.SDDocumentCategory  = 'H'

//  or SalesDocumentType.SDDocumentCategory  = 'I'

//  or SalesDocumentType.SDDocumentCategory  = 'B'

//  and 

  PartFuncByPartDetnProced.PartnerIsNotChangeable = ''
  and PartFuncByPartDetnProced.PartnerFunction != 'WE'
  and PartFuncByPartDetnProced.PartnerFunction != 'RE'
  and PartFuncByPartDetnProced.PartnerFunction != 'RG'
  and PartFuncByPartDetnProced.PartnerFunction != 'VE'
  and PartFuncByPartDetnProced.PartnerFunction != 'ZM'
  and PartFuncByPartDetnProced.PartnerFunction != 'AG'