C_TransportationOrderNoteFDP

DDL: C_TRANSPORTATIONORDERNOTEFDP Type: view_entity CONSUMPTION Package: CLTM_TOR_PRINTING_REUSE

Transp Order Note Form Data Provider

C_TransportationOrderNoteFDP is a Consumption CDS View that provides data about "Transp Order Note Form Data Provider" in SAP S/4HANA. It reads from 1 data source (I_TextCollection) and exposes 8 fields with key field TextCollectionContentUUID. It has 1 association to related views. Part of development package CLTM_TOR_PRINTING_REUSE.

1 data source(s) 8 fields

Data Sources (1)

SourceAliasJoin Type
I_TextCollection TextCollectionRoot from

Associations (1)

CardinalityTargetAliasCondition
[1..1] I_TransportationOrder_2 _TransportationOrder $projection.TransportationOrderUUID = _TransportationOrder.TransportationOrderUUID

Annotations (8)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
AccessControl.personalData.blocking #NOT_REQUIRED view
EndUserText.label Transp Order Note Form Data Provider view
Metadata.ignorePropagatedAnnotations true view
VDM.viewType #CONSUMPTION view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #TRANSACTIONAL view

Fields (8)

KeyFieldSource TableSource FieldDescription
KEY TextCollectionContentUUID _TextCollectionContent TextCollectionContentUUID
TransportationOrderUUID I_TextCollection HostDocumentUUID
TextCollectionType _TextCollectionType TextCollectionType
TextCollectionTextCrtedDteTime _TextCollectionType TextCollectionTextCrtedDteTime
TextCollectionTextChgdDateTime _TextCollectionType TextCollectionTextChgdDateTime
Language _TextCollectionType Language
TextCollectionContentText _TextCollectionContent TextCollectionContentText
_TransportationOrder _TransportationOrder 
@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]
@AccessControl: {
                  authorizationCheck: #MANDATORY,
                  personalData.blocking: #NOT_REQUIRED
                 }

@EndUserText.label: 'Transp Order Note Form Data Provider'
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #CONSUMPTION
@ObjectModel:{
                usageType:{
                  serviceQuality: #C,
                  sizeCategory: #L,
                  dataClass: #TRANSACTIONAL
                },
                supportedCapabilities: [ #OUTPUT_FORM_DATA_PROVIDER ]
              }

define view entity C_TransportationOrderNoteFDP
  as select from            I_TextCollection        as TextCollectionRoot
    left outer to many join I_TextCollectionType    as _TextCollectionType    on TextCollectionRoot.TextCollectionUUID = _TextCollectionType.TextCollectionUUID
    left outer to one join  I_TextCollectionContent as _TextCollectionContent on _TextCollectionType.TextCollectionTypeUUID = _TextCollectionContent.TextCollectionTypeUUID

  association [1..1] to I_TransportationOrder_2 as _TransportationOrder on $projection.TransportationOrderUUID = _TransportationOrder.TransportationOrderUUID

{
  key _TextCollectionContent.TextCollectionContentUUID   as TextCollectionContentUUID,
      TextCollectionRoot.HostDocumentUUID                as TransportationOrderUUID,

      _TextCollectionType.TextCollectionType             as TextCollectionType,
      @Semantics.systemDate.createdAt: true
      @Semantics.dateTime: true
      _TextCollectionType.TextCollectionTextCrtedDteTime as TextCollectionTextCrtedDteTime,
      @Semantics.systemDate.lastChangedAt: true
      @Semantics.dateTime: true
      _TextCollectionType.TextCollectionTextChgdDateTime as TextCollectionTextChgdDateTime,
      _TextCollectionType.Language                       as Language,
      _TextCollectionContent.TextCollectionContentText   as TextCollectionContentText,

      /* Associations */
      _TransportationOrder

}
where
      TextCollectionRoot.DocumentHasText                = 'X'
  and _TextCollectionType.TextCollectionTypeIsInternal  = ' '
  and TextCollectionRoot.HostDocumentBusinessObjectUUID = hextobin('80E0ED0A0C021DEE8CE07DB4266D17C4') //BO: TOR

  and TextCollectionRoot.HostDocumentBusObjNodeUUID     = hextobin('80E0ED0A0C021DDE8CE07DB5DFAD0818') //Node: Root

Learn More