C_SustDeliveryDocumentDEX

@EndUserText.label: 'Delivery Documents Extractor'

@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #NOT_REQUIRED
}

@Metadata: {
  ignorePropagatedAnnotations: true
}

@ObjectModel: {
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory: #XL
  },
  sapObjectNodeType.name: 'DeliveryDocument',
  supportedCapabilities: [#EXTRACTION_DATA_SOURCE],
  modelingPattern: #NONE
}

@VDM: {
      viewType: #CONSUMPTION,
      lifecycle.contract.type: #PUBLIC_LOCAL_API
}

@Analytics: {
  dataCategory: #FACT,
  internalName:#LOCAL,
  technicalName: 'CSUSTDLVRYDOCDEX',
  dataExtraction: {
      enabled: true,
      delta.changeDataCapture:
        { mapping:
        [
          { role: #MAIN, table: 'likp', tableElement: ['vbeln'], viewElement: ['DeliveryDocument'] },
          { role: #LEFT_OUTER_TO_ONE_JOIN, table: 'vbpa', tableElement: ['vbeln'], viewElement: ['DeliveryDocument'] },
          { role: #LEFT_OUTER_TO_ONE_JOIN, table: 'adrc', tableElement: ['addrnumber'], viewElement: ['ShipToPartyAddressID'] },
          { role: #LEFT_OUTER_TO_ONE_JOIN, table: 'adrc', tableElement: ['addrnumber'], viewElement: ['SoldToPartyAddressID'] }
        ]
      }
    }
}

define view entity C_SustDeliveryDocumentDEX
  as select from I_DeliveryDocument

  //Associations

  association [0..1] to I_SDDocumentPartner as _SDDocumentCompletePartners on  $projection.DeliveryDocument                             = _SDDocumentCompletePartners.SDDocument
                                                                                    and _SDDocumentCompletePartners.PartnerFunction              = 'WE'
                                                                                    and (
                                                                                       _SDDocumentCompletePartners.SDDocPartnerAddressRefType    = 'D'
                                                                                       or _SDDocumentCompletePartners.SDDocPartnerAddressRefType = 'E'
                                                                                       or _SDDocumentCompletePartners.SDDocPartnerAddressRefType = 'F'
                                                                                     )


{
  key DeliveryDocument,
      DeliveryDocumentType,
      SalesOrganization,
      ShippingPoint,

      //Ship to party

      ShipToParty,
      _SDDocumentCompletePartners.AddressID               as ShipToPartyAddressID, //necessary for delta CDC only

      _SDDocumentCompletePartners._DfltAddrRprstn.Country as ShipToPartyCountry,
      _SDDocumentCompletePartners._DfltAddrRprstn.Region  as ShipToPartyRegion,

      //Sold to party

      SoldToParty,
      _SoldToParty.AddressID as SoldToPartyAddressID, //necessary for delta CDC only

      _SoldToParty.Country   as SoldToPartyCountry,
      _SoldToParty.Region    as SoldToPartyRegion,

      //Goods movement

      ActualGoodsMovementDate,
      IncotermsClassification,
      

      //Status

      OverallSDProcessStatus,
      OverallGoodsMovementStatus,

      //Admin

      CreatedByUser,
      CreationDate,
      CreationTime,
      LastChangedByUser,
      LastChangeDate,
      DeletionIndicator
};