C_StoreAssgblToExplctAsstmtMdl

DDL: C_STOREASSGBLTOEXPLCTASSTMTMDL Type: view_entity CONSUMPTION Package: RFM_ASSIGN_ASM_USR_TO_EXPL_ASM

Store Assignable to Assortment Module

C_StoreAssgblToExplctAsstmtMdl is a Consumption CDS View that provides data about "Store Assignable to Assortment Module" in SAP S/4HANA. It reads from 1 data source (I_StoreAssgblToExplctModuleTP) and exposes 12 fields with key field Site. It is exposed through 1 OData service (UI_RFM_USER_ASSIGN_EXPL_ASM). Part of development package RFM_ASSIGN_ASM_USR_TO_EXPL_ASM.

1 data source(s) Exposed by 1 service(s) 12 fields

Data Sources (1)

SourceAliasJoin Type
I_StoreAssgblToExplctModuleTP I_StoreAssgblToExplctModuleTP projection

Annotations (11)

NameValueLevelField
EndUserText.label Store Assignable to Assortment Module view
Metadata.allowExtensions true view
Metadata.ignorePropagatedAnnotations true view
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #BLOCKED_DATA_EXCLUDED view
VDM.viewType #CONSUMPTION view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.sapObjectNodeType.name RetailSite view

OData Services (1)

ServiceBindingVersionContractRelease
UI_RFM_USER_ASSIGN_EXPL_ASM UI_RFM_USR_ASSIGN_EXPL_ASM V2 C1 NOT_RELEASED

Fields (12)

KeyFieldSource TableSource FieldDescription
KEY Site
StoreName SiteName
SiteCustomer
StoreIsAssignedToAnyModule StoreIsAssignedToAnyModule
SalesOrganization SalesOrganization
DistributionChannel DistributionChannel
PostalCode PostalCode
Country
CountryName CountryName
_Customer _Customer
_SalesOrganization _SalesOrganization
_DistributionChannel _DistributionChannel 
@EndUserText.label: 'Store Assignable to Assortment Module'

@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations:true

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #BLOCKED_DATA_EXCLUDED
}

@VDM: {
  viewType: #CONSUMPTION,
  usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE],

  lifecycle: {
    contract: {
      type: #PUBLIC_LOCAL_API
    }
  }
}
@ObjectModel: {
    usageType: {
        serviceQuality: #C,
        sizeCategory: #L,
        dataClass: #MASTER
   },
   sapObjectNodeType.name: 'RetailSite'
}

define root view entity C_StoreAssgblToExplctAsstmtMdl
  provider contract transactional_query
  as projection on I_StoreAssgblToExplctModuleTP
{
      @ObjectModel.text.element: ['StoreName']
      @Consumption: { semanticObject: 'Site' }
      @Consumption.valueHelpDefinition: [ {  entity: { name: 'I_StoreValueHelp' , element: 'Site'  } } ]
//      @EndUserText.quickInfo: 'Store'

  key cast ( Site as rfm_asm_store preserving type )        as Site,
      @Semantics.text: true
      SiteName                                              as StoreName,
      @Consumption.filter.hidden: true
      cast ( SiteCustomer as rfm_asm_store_customer preserving type ) as SiteCustomer,
      StoreIsAssignedToAnyModule,
      @Consumption.valueHelpDefinition: [ {  entity: { name: 'C_SalesOrganizationValueHelp' , element: 'SalesOrganization'  }} ]
      SalesOrganization,
      @Consumption.valueHelpDefinition: [ {  entity: { name: 'C_SalesOrganizationDistrChnlVH' , element: 'DistributionChannel'  },
                                             additionalBinding: [{ element: 'SalesOrganization', localElement: 'SalesOrganization' } ] } ] 
      DistributionChannel,
      PostalCode,
      @ObjectModel.text.element: ['CountryName']
      @Consumption.valueHelpDefinition: [ {  entity: { name: 'I_CountryVH' , element: 'Country'  } } ]
      cast ( Country as rfm_asm_country preserving type )   as Country,
      @Semantics.text: true
      CountryName,

      //  Foreign Key Associations

      _Customer,
      _SalesOrganization,
      _DistributionChannel,
      _UsrToExplctAsstmtMdlAssgmt : redirected to C_UserToExplicitAsstmtMdl
} where SiteCustomer is not initial

Learn More