C_SrvcQtanEmailDataProvider

@EndUserText.label: 'Email Data Provider for Service Quotation'
@VDM: {
  viewType: #CONSUMPTION
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
  semanticKey: ['ServiceQuotation'],
  representativeKey: 'ServiceQuotation',
  usageType: {serviceQuality: #C, sizeCategory: #XXL, dataClass: #TRANSACTIONAL}
}
@Analytics.technicalName: 'CSRVCQTANEMAILDP'
define root view entity C_SrvcQtanEmailDataProvider
  as select from I_ServiceDocumentEnhcd   

  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_ServiceDocumentRefObject as _ServiceDocMainRefObj on  _ServiceDocMainRefObj.ServiceObjectType      = $projection.ServiceObjectType
                                                                            and _ServiceDocMainRefObj.ServiceDocument        = $projection.ServiceQuotation
                                                                            and _ServiceDocMainRefObj.ServiceDocumentItem    is initial
                                                                            and _ServiceDocMainRefObj.SrvcRefObjIsMainObject is not initial

{
  key cast(I_ServiceDocumentEnhcd.ServiceDocument as crms4_qtan_id preserving type)                     as ServiceQuotation,
      cast(I_ServiceDocumentEnhcd.ServiceDocumentDescription as crms4_qtan_description preserving type) as ServiceQuotationDescription,
      cast(I_ServiceDocumentEnhcd._SoldToParty.BusinessPartnerName as vdm_sold_to_name)                 as SoldToPartyName,
      cast(I_ServiceDocumentEnhcd._ContactPerson.BusinessPartnerName as crms4_contact_person_name)      as ContactPersonName,
      cast(I_ServiceDocumentEnhcd._ShipToParty.BusinessPartnerName as ship_to_name)                     as ShipToPartyName,
      cast(I_ServiceDocumentEnhcd._RespEmployee.BusinessPartnerName as resp_empl_name)                  as ResponsibleEmployeeName,
     
      cast(tstmp_to_dats( I_ServiceDocumentEnhcd.SrvcQtanValidityStartDateTime,
                          abap_system_timezone( $session.client,'NULL' ),
                          $session.client,
                          'NULL' ) as crms4_qtan_val_start_date preserving type )                         as SrvcQuotationValidityStartDate,
                          
      cast(tstmp_to_dats( I_ServiceDocumentEnhcd.SrvcQtanValidityEndDateTime,
                          abap_system_timezone( $session.client,'NULL' ),
                          $session.client,
                          'NULL' ) as crms4_qtan_val_end_date preserving type )                         as SrvcQuotationValidityEndDate,
      I_ServiceDocumentEnhcd.RequestedServiceStartDate,
      @Semantics.amount.currencyCode: 'TRANSACTIONCURRENCY' 
I_ServiceDocumentEnhcd.ServiceDocNetAmount,
      @Semantics.amount.currencyCode: 'TRANSACTIONCURRENCY' 
I_ServiceDocumentEnhcd.ServiceDocGrossAmount,
      I_ServiceDocumentEnhcd.TransactionCurrency,
      _ServiceDocMainRefObj.Equipment,
      cast( case  when _ServiceDocMainRefObj.ProductID is not initial
                    then _ServiceDocMainRefObj.ProductID
                    else _ServiceDocMainRefObj._Equipment.Material
            end as productnumber preserving type )                                                      as ProductID,

      case when _ServiceDocMainRefObj.SerialNumber is not initial
             then _ServiceDocMainRefObj.SerialNumber
             else _ServiceDocMainRefObj._Equipment.SerialNumber
      end                                                                                               as SerialNumber,

      // The following fields are required for authorization checks

      @Consumption.hidden: true
      I_ServiceDocumentEnhcd.ServiceObjectType,
      @Consumption.hidden: true
      I_ServiceDocumentEnhcd.ServiceDocumentType,
      @Consumption.hidden: true
      I_ServiceDocumentEnhcd.SalesOrganization,
      @Consumption.hidden: true
      I_ServiceDocumentEnhcd.SalesOffice,
      @Consumption.hidden: true
      I_ServiceDocumentEnhcd.SalesGroup,
      @Consumption.hidden: true
      I_ServiceDocumentEnhcd.DistributionChannel,
      @Consumption.hidden: true
      I_ServiceDocumentEnhcd.Division,
      @Consumption.hidden: true
      I_ServiceDocumentEnhcd.ResponsibleEmployee,
      @Consumption.hidden: true
      I_ServiceDocumentEnhcd.SalesOrganizationOrgUnitID,
      @Consumption.hidden: true
      I_ServiceDocumentEnhcd.SalesOfficeOrgUnitID,
      @Consumption.hidden: true
      I_ServiceDocumentEnhcd.SalesGroupOrgUnitID,
      @Consumption.hidden: true
      I_ServiceDocumentEnhcd.ServiceOrganization
}

where
      I_ServiceDocumentEnhcd.ServiceObjectType          = 'BUS2000116'
  and I_ServiceDocumentEnhcd.ServiceDocumentIsQuotation = 'X'