C_SrlNmbrHistoryBPContactCard

DDL: C_SRLNMBRHISTORYBPCONTACTCARD Type: view_entity CONSUMPTION Package: ODATA_LO_SN_HISTORY

Business Partner Contact Card

C_SrlNmbrHistoryBPContactCard is a Consumption CDS View that provides data about "Business Partner Contact Card" in SAP S/4HANA. It reads from 1 data source (I_Customer) and exposes 8 fields with key field Customer. It is exposed through 1 OData service (UI_SERIALNUMBER_HISTORY_V4). Part of development package ODATA_LO_SN_HISTORY.

1 data source(s) Exposed by 1 service(s) 8 fields

Data Sources (1)

SourceAliasJoin Type
I_Customer I_Customer from

Annotations (10)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
AccessControl.personalData.blocking #REQUIRED view
EndUserText.label Business Partner Contact Card view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
VDM.viewType #CONSUMPTION view
VDM.lifecycle.contract.type #NONE view
ObjectModel.representativeKey Customer view

OData Services (1)

ServiceBindingVersionContractRelease
UI_SERIALNUMBER_HISTORY_V4 UI_SERIALNUMBER_HISTORY_V4 V4 C1 NOT_TO_BE_RELEASED_STABLE

Fields (8)

KeyFieldSource TableSource FieldDescription
KEY Customer
CustomerName BPCustomerFullName
StreetName
HouseNumber _AddressDefaultRepresentation HouseNumber
CityName _AddressDefaultRepresentation CityName
PostalCode _AddressDefaultRepresentation PostalCode
CountryName
TelephoneNumber1 TelephoneNumber1 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Business Partner Contact Card'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType: {
        dataClass:      #MIXED,
        serviceQuality: #C,
        sizeCategory:   #XL
                        }
@VDM.viewType: #CONSUMPTION
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]
@VDM.lifecycle.contract.type: #NONE
@ObjectModel.representativeKey: 'Customer'

define view entity C_SrlNmbrHistoryBPContactCard
  as select from I_Customer
{
      @Semantics.contact.type: #PERSON
      @ObjectModel.filter.enabled: false
  key ltrim(Customer,'0')                                                                                     as Customer,
      @Semantics.name.fullName: true
      @ObjectModel.filter.enabled: false
      BPCustomerFullName                                                                                      as CustomerName,
      @Semantics.address.street: true
      @ObjectModel.filter.enabled: false
      concat_with_space(_AddressDefaultRepresentation.StreetName,_AddressDefaultRepresentation.HouseNumber,1) as StreetName,
      @Semantics.address.streetNoNumber: true
      @ObjectModel.filter.enabled: false
      _AddressDefaultRepresentation.HouseNumber                                                               as HouseNumber,
      @Semantics.address.city: true
      @ObjectModel.filter.enabled: false
      _AddressDefaultRepresentation.CityName                                                                  as CityName,
      @Semantics.address.zipCode: true
      @ObjectModel.filter.enabled: false
      _AddressDefaultRepresentation.PostalCode                                                                as PostalCode,
      @Semantics.address.country: true
      @ObjectModel.filter.enabled: false
      _AddressDefaultRepresentation._Country._Text[1:Language=$session.system_language].CountryName           as CountryName,
      @Semantics.telephone.type: [ #WORK ]
      @ObjectModel.filter.enabled: false
      TelephoneNumber1
}

Learn More