C_SlsOrdRefSalesQuotationItem

@AbapCatalog.viewEnhancementCategory: [#NONE]
@VDM.viewType: #CONSUMPTION
@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@Metadata: {
  allowExtensions: true,
  ignorePropagatedAnnotations: true
}
@ObjectModel: {
  updateEnabled,
  usageType: {
    dataClass:      #MIXED,
    serviceQuality: #C,
    sizeCategory:   #XL
  },
  supportedCapabilities: [ #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE ],
  modelingPattern: #NONE
}
@Search.searchable: true
@EndUserText.label: 'Sls Order Reference Sales Quotation Item'
define view entity C_SlsOrdRefSalesQuotationItem 
as select from I_SalesDocumentItemBasic               as SalesDocumentItemBasic
  inner join C_SlsOrdReferenceSlsQuotation            as ReferenceDocument           on SalesDocumentItemBasic.SalesDocument = ReferenceDocument.SalesQuotation
  association [0..*] to I_SalesDocumentRjcnReasonText as _RjcnReasonText             on $projection.SalesDocumentRjcnReason  = _RjcnReasonText.SalesDocumentRjcnReason
  association [0..*] to I_SDDocReferenceStatusText    as _SDDocReferenceStatusText   on $projection.SDDocReferenceStatus = _SDDocReferenceStatusText.SDDocReferenceStatus
  association [0..*] to I_ItemGenIncompletionStatusT  as _ItemGenIncompletionStatusT on $projection.ItemGeneralIncompletionStatus = _ItemGenIncompletionStatusT.ItemGeneralIncompletionStatus
{
      @Search.defaultSearchElement: true
  key SalesDocumentItemBasic.SalesDocument                                                                         as ReferenceDocument,
  
  key cast(SalesDocumentItemBasic.SalesDocumentItem as reference_doc_item)                                         as ReferenceSDDocumentItem, 
  
      SalesDocumentItemBasic.SalesDocument                                                                         as SalesQuotation,
      
      SalesDocumentItemBasic.SalesDocumentItem                                                                     as SalesQuotationItem,
  
      @Semantics.text: true
      SalesDocumentItemBasic.SalesDocumentItemText                                                                 as SalesQuotationItemText,

      ReferenceDocument.SDDocumentCategory,

      @ObjectModel.text.element: ['ProductName']
      SalesDocumentItemBasic.Product,
     
      @Semantics.text: true
      SalesDocumentItemBasic._ProductText[1: Language=$session.system_language].ProductName,
      
      @Semantics.valueRange.minimum: '0'
      @Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
      cast( 0 as reqd_qty )                                                                                        as RequestedQuantity,
      
      SalesDocumentItemBasic.RequestedQuantityUnit,
      
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      SalesDocumentItemBasic.NetAmount,
      
      SalesDocumentItemBasic.TransactionCurrency,
                
      SalesDocumentItemBasic.HigherLevelItem,
        
      @ObjectModel.text.element:  [ 'SalesDocumentRjcnReasonName' ]
      SalesDocumentItemBasic.SalesDocumentRjcnReason,

      @Semantics.text: true
      _RjcnReasonText[1: Language=$session.system_language].SalesDocumentRjcnReasonName,
      
      @ObjectModel.text.association: '_SDDocReferenceStatusText'
      SalesDocumentItemBasic.SDDocReferenceStatus,

      @ObjectModel.text.association: '_ItemGenIncompletionStatusT'
      cast(SalesDocumentItemBasic.ItemGeneralIncompletionStatus as item_general_incompletion_sts preserving type ) as ItemGeneralIncompletionStatus, 
      
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_QUOTATION_V4_UI_UTIL'
      cast ( 0 as int1 preserving type )                                                                           as ItmGenIncompltnStsCriticality,
        
      // ACL

      @UI.hidden: true
      ReferenceDocument.SalesDocumentType,
      @Consumption.hidden:true
      ReferenceDocument.OrganizationDivision,
      @Consumption.hidden:true
      ReferenceDocument.SalesOrganization,
      @Consumption.hidden:true
      ReferenceDocument.DistributionChannel,
      
      //Associations

      _SDDocReferenceStatusText,
      _ItemGenIncompletionStatusT
  
}