C_SlsInqryForCreateWithRefVH

@VDM: {
  viewType: #CONSUMPTION
}

@ObjectModel: {
  representativeKey: 'SalesInquiry',
  dataCategory:#VALUE_HELP,
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory: #M
  }
}

@AccessControl.privilegedAssociations: ['_CreatedByUser']
@Search.searchable: true
@Consumption.ranked: true

@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@UI.presentationVariant: [{
  sortOrder: [{
    by: 'SalesInquiry',
    direction: #DESC
  }]
}]

@EndUserText.label: 'Sales Inquiry for Create with Reference'
define view entity C_SlsInqryForCreateWithRefVH
  as select from I_SalesInquiry as SalesInquiry

  association [0..*] to I_OverallSDProcessStatusText   as _OverallSDProcessStatusText   on $projection.OverallSDProcessStatus = _OverallSDProcessStatusText.OverallSDProcessStatus
  association [0..*] to I_OverallSDDocReferenceStatusT as _OverallSDDocReferenceStatusT on $projection.OverallSDDocReferenceStatus = _OverallSDDocReferenceStatusT.OverallSDDocReferenceStatus
  association [0..*] to I_SalesOrganizationText        as _SalesOrganizationText        on $projection.SalesOrganization = _SalesOrganizationText.SalesOrganization
  association [0..*] to I_DistributionChannelText      as _DistributionChannelText      on $projection.DistributionChannel = _DistributionChannelText.DistributionChannel
  association [0..*] to I_DivisionText                 as _DivisionText                 on $projection.OrganizationDivision = _DivisionText.Division
{
      @UI: {
        lineItem: [{ position: 10,  importance: #HIGH }],
        selectionField: [{ position: 10 }]
      }
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.9,
        ranking: #HIGH
      }
  key SalesInquiry.SalesInquiry,

      @UI: {
        lineItem: [ {position: 20, importance: #HIGH } ],
        selectionField: [{ position: 20 }],
        textArrangement: #TEXT_FIRST
      }
      @Consumption.valueHelpDefinition: [{
        label: 'Sales Organization',
        entity: { name:    'C_SalesDocSalesOrganizationVH',
                  element: 'SalesOrganization' }}]
      @ObjectModel.text.element: ['SalesOrganizationName']
      SalesInquiry.SalesOrganization,

      @UI.hidden: true
      @Semantics.text: true
      _SalesOrganizationText[1: Language=$session.system_language].SalesOrganizationName,

      @UI: {
        lineItem: [ {position: 30, importance: #HIGH } ],
        selectionField: [{ position: 30 }],
        textArrangement: #TEXT_FIRST
      }
      @Consumption.valueHelpDefinition: [{
        label: 'Distribution Channel',
        entity: { name:    'C_Dischannelvaluehelp',
                  element: 'DistributionChannel' },
        additionalBinding: [{element: 'SalesOrganization', localElement: 'SalesOrganization', usage: #FILTER_AND_RESULT}]
      }]
      @ObjectModel.text.element: ['DistributionChannelName']
      SalesInquiry.DistributionChannel,

      @UI.hidden: true
      @Semantics.text: true
      _DistributionChannelText[1: Language=$session.system_language].DistributionChannelName,

      @UI: {
        lineItem: [ {position: 40, importance: #HIGH } ],
        selectionField: [{ position: 40 }],
        textArrangement: #TEXT_FIRST
      }
      @Consumption.valueHelpDefinition: [{
        label: 'Division',
        entity: { name:    'C_OrgDivisionValueHelp',
                  element: 'Division' },
        additionalBinding: [{element: 'SalesOrganization', localElement: 'SalesOrganization', usage: #FILTER_AND_RESULT},
                            {element: 'DistributionChannel',localElement: 'DistributionChannel', usage: #FILTER_AND_RESULT}]
      }]
      @ObjectModel.text.element: ['DivisionName']
      SalesInquiry.OrganizationDivision,

      @UI.hidden: true
      @Semantics.text: true
      _DivisionText[1: Language=$session.system_language].DivisionName,

      @UI: {
        lineItem: [{ position: 50,  importance: #HIGH }],
        selectionField: [{ position: 50 }],
        textArrangement: #TEXT_FIRST
      }
      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'C_SoldToValueHelp',
          element: 'Customer'
        }
      }]
      @ObjectModel.text.element: ['SoldToPartyName']
      SalesInquiry.SoldToParty,

      @Semantics.text:true
      //      @EndUserText.label : 'Sold-to Party Name'

      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_SLSINQY_UI_PARTNER_UTIL'
      @UI.hidden: true
      _SoldToParty.CustomerName as SoldToPartyName,

      @UI: {
        selectionField: [{ position: 60 }],
        lineItem: [{ position: 60,  importance: #HIGH }]
      }
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.9,
        ranking: #MEDIUM
      }
      SalesInquiry.PurchaseOrderByCustomer,

      @UI: {
        lineItem: [{ position: 70,  importance: #HIGH }],
        selectionField: [{ position: 70 }],
        textArrangement: #TEXT_ONLY
      }
      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'I_OverallSDProcessStatus',
          element: 'OverallSDProcessStatus'
        }
      }]
      @ObjectModel.text.element: ['OverallSDProcessStatusDesc']
      SalesInquiry.OverallSDProcessStatus,

      @UI.hidden: true
      @Semantics.text: true
      _OverallSDProcessStatusText[1: Language=$session.system_language].OverallSDProcessStatusDesc,

      @UI: {
        textArrangement: #TEXT_ONLY,
        lineItem: [ {position: 80, importance: #HIGH } ]
      }
      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'I_OverallSDDocReferenceStatus',
          element: 'OverallSDDocReferenceStatus'
        }
      }]
      @ObjectModel.text.element: ['OverallSDDocRefStatusDesc']
      SalesInquiry.OverallSDDocReferenceStatus,

      @UI.hidden: true
      @Semantics.text: true
      _OverallSDDocReferenceStatusT[1: Language=$session.system_language].OverallSDDocRefStatusDesc,

      @UI: {
        textArrangement: #TEXT_ONLY,
        lineItem: [ {position: 90, importance: #HIGH } ]
      }
      @Consumption.valueHelpDefinition: [{
      label: 'Created By',
      entity: {
           name: 'C_SalesDocumentUserVH',
           element: 'UserID'
          }
      }]
      @ObjectModel.text.element: ['UserDescription']
      SalesInquiry.CreatedByUser,

      @UI.hidden: true
      @Semantics.text: true
      _CreatedByUser.UserDescription,

      //For DCL

      @UI.hidden: true
      SalesInquiry.SalesInquiryType,

      @UI.hidden: true
      _CreatedByUser

}