C_SlsDocSchedLineDeliveryBlkd

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.semanticKey: ['SalesDocument', 'SalesDocumentItem', 'ScheduleLine']
@ObjectModel.representativeKey: 'ScheduleLine'

@EndUserText.label: 'Sales Doc Schedule Line Delivery Blocked'
@VDM.viewType: #CONSUMPTION
@AbapCatalog.compiler.compareFilter: true
@Search.searchable: false
@AccessControl.authorizationCheck: #CHECK
@Metadata.allowExtensions: true
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'CSLSDOCSCHDLSO02'

define view C_SlsDocSchedLineDeliveryBlkd

as select from I_SalesDocumentScheduleLine as ScheduleLine
  
left outer to one join I_SalesOrderDeliveryBlkd as DeliveryBlockedIssue
     on  ScheduleLine.SalesDocument     = DeliveryBlockedIssue.SalesOrder  
     and ScheduleLine.SalesDocumentItem = DeliveryBlockedIssue.SalesOrderItem  
 
association [1..1] to I_Purchaserequisition as _PurchaseRequisition  on  $projection.PurchaseRequisition = _PurchaseRequisition.PurchaseRequisition    
 
{

      //Key

      @ObjectModel.foreignKey.association: '_SalesDocument'
  key ScheduleLine.SalesDocument,

      @ObjectModel.foreignKey.association: '_SalesDocumentItem'
  key ScheduleLine.SalesDocumentItem,

  key ScheduleLine.ScheduleLine,

      ScheduleLine.IsRequestedDelivSchedLine,

      ScheduleLine.IsConfirmedDelivSchedLine,

      ScheduleLine.DeliveryDate,

      @ObjectModel.foreignKey.association: '_DelivBlockReasonForSchedLine'
      ScheduleLine.DelivBlockReasonForSchedLine,
      
      // Criticality   

      @UI.hidden: true   
      cast( 
          case
              when ScheduleLine.DelivBlockReasonForSchedLine <> '' and DeliveryBlockedIssue.DueDays > 0   then 2
              when ScheduleLine.DelivBlockReasonForSchedLine <> '' and DeliveryBlockedIssue.DueDays <= 0  then 1
                                                                                                          else 9
          end as abap.int1
      ) as DeliveryBlockReasonCriticality,
      
      // DueDays

      @UI.hidden: true
      @DefaultAggregation: #NONE
      DeliveryBlockedIssue.DueDays,
      
      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      ScheduleLine.ConfdOrderQtyByMatlAvailCheck,

      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      ScheduleLine.ScheduleLineOrderQuantity,

      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      ScheduleLine.DeliveredQtyInOrderQtyUnit,

      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_OrderQuantityUnit'
      ScheduleLine.OrderQuantityUnit,

      ScheduleLine.ProductAvailabilityDate,
      
       //Purchasing

      @Consumption.semanticObject: 'PurchaseRequisition'
      @ObjectModel.foreignKey.association: '_PurchaseRequisition'
      cast (PurchaseRequisition as vdm_purchaserequisition preserving type ) as PurchaseRequisition,
      
      ScheduleLine._SalesDocument,
      ScheduleLine._SalesDocumentItem,
      ScheduleLine._DelivBlockReasonForSchedLine,
      ScheduleLine._OrderQuantityUnit,
      _PurchaseRequisition   

}