C_SlsDocItmNonStdPartner

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog: {
  sqlViewName: 'CSLSDOCITMNSPT',
  preserveKey: true,
  compiler.compareFilter: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations:  [ '_DfltAddrRprstn' ]
}
@VDM: {
  viewType: #CONSUMPTION,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@ObjectModel: {
   representativeKey: 'PartnerFunction',
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}
@Metadata.ignorePropagatedAnnotations:true
@EndUserText.label: 'Sls Doc Item Non Std Complete Partners'
@Consumption.dbHints: ['USE_HEX_PLAN']
define view C_SlsDocItmNonStdPartner
  as select from I_SalesDocItemCompletePartner as ItemPartner
  association [1] to I_PersonWorkAgreement_1 as _WorkAgreement on $projection.Personnel = _WorkAgreement.PersonWorkAgreement
  association [1] to I_ContactPerson         as _ContactPerson on $projection.ContactPerson = _ContactPerson.ContactPerson
{
      @ObjectModel.foreignKey.association: '_SalesDocument'
  key ItemPartner.SalesDocument,
      @ObjectModel.foreignKey.association: '_SalesDocumentItem'
  key ItemPartner.SalesDocumentItem,
      @ObjectModel.foreignKey.association: '_PartnerFunction'
  key cast(ItemPartner.PartnerFunction as parvw_unv preserving type )                     as PartnerFunction,

      _PartnerFunction._Text[1:Language =  $session.system_language ].PartnerFunctionName as PartnerFunctionName,

      _PartnerFunction.SDDocumentPartnerType,

      ItemPartner.Customer,

      ItemPartner.Supplier,

      ItemPartner.ContactPerson,

      ItemPartner.Personnel,

      ItemPartner.AddressID,
      ItemPartner.AddressPersonID,
      ItemPartner.AddressObjectType,

      ItemPartner.Partner                                                                 as BusinessPartner,
      @Semantics.name.fullName: true
      @Semantics.text: true
      ItemPartner.FullName                                                                as BusinessPartnerFullName,

      ItemPartner._DfltAddrRprstn,

      ItemPartner._SalesDocument,

      ItemPartner._SalesDocumentItem,

      ItemPartner._PartnerFunction,
      
      //added for 2202 release : Fetch address info

      @Semantics.text:true
      @Consumption.filter.hidden: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MCC_SLS_DOC_VE'
      cast( ' ' as ad_line_s )                                                            as FormattedPostalAddressDesc

}
where
      PartnerFunction != 'AG'
  and PartnerFunction != 'WE'
  and PartnerFunction != 'RE'
  and PartnerFunction != 'RG'
  and PartnerFunction != 'VE'
  and PartnerFunction != 'ZM'